[gentoo-commits] gentoo-x86 commit in app-shells/dash: ChangeLog dash-0.5.4.9.ebuild

[gentoo-commits] gentoo-x86 commit in app-shells/dash: ChangeLog dash-0.5.4.9.ebuild

[Mike Frysinger (vapier)]

vapier      08/05/31 07:33:12

  Modified:             ChangeLog
  Added:                dash-0.5.4.9.ebuild
  Log:
  Version bump #223679 by Peter Alfredsen.
  (Portage version: 2.2_pre5.spank.spunk)

Revision  Changes    Path
1.57                 app-shells/dash/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-shells/dash/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	6 May 2008 15:49:12 -0000	1.56
+++ ChangeLog	31 May 2008 07:33:11 -0000	1.57
@@ -1,6 +1,11 @@
 # ChangeLog for app-shells/dash
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
 
+*dash-0.5.4.9 (31 May 2008)
+
+  31 May 2008; Mike Frysinger <vapier@gentoo.org> +dash-0.5.4.9.ebuild:
+  Version bump #223679 by Peter Alfredsen.
+
   06 May 2008; Jeroen Roovers <jer@gentoo.org> dash-0.5.4.6-r1.ebuild:
   Stable for HPPA (bug #219871).
 



1.1                  app-shells/dash/dash-0.5.4.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/dash-0.5.4.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/dash-0.5.4.9.ebuild?rev=1.1&content-type=text/plain

Index: dash-0.5.4.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/dash-0.5.4.9.ebuild,v 1.1 2008/05/31 07:33:11 vapier Exp $

inherit autotools eutils flag-o-matic

DEB_PV=${PV%.*}
DEB_PATCH=${PV##*.}
DEB_PF="${PN}_${DEB_PV}-${DEB_PATCH}"
MY_P="${PN}-${DEB_PV}"

DESCRIPTION="DASH is a direct descendant of the NetBSD version of ash (the Almquist SHell) and is POSIX compliant"
HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${PN}-${DEB_PV}.tar.gz
	mirror://debian/pool/main/d/dash/${DEB_PF}.diff.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="libedit static"

DEPEND="libedit? ( dev-libs/libedit )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	epatch "${WORKDIR}"/${DEB_PF}.diff
	cd "${S}"
	epatch debian/diff/*

	# Fix the invalid sort
	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins

	# Always statically link libedit in to ensure we always boot if it changes
	# which it has done in the past.
	local s="s/-ledit/-Wl,-Bstatic -ledit -Wl,-Bdynamic -lcurses/g"
	use static && s="s/-ledit/-ledit -lcurses/g"
	sed -i -e "${s}" configure.ac || die "Failed to sed configure.ac"

	# May as well, as the debian patches force this anyway
	eautoreconf
}

src_compile() {
	use static && append-ldflags -static
	econf \
		--bindir=/bin \
		$(use_with libedit) \
		|| die "econf failed"
	emake || die
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc ChangeLog debian/changelog
}



-- 
gentoo-commits@lists.gentoo.org mailing list