[gentoo-commits] gentoo-x86 commit in sys-process/audit: ChangeLog audit-1.7.4.ebuild

[gentoo-commits] gentoo-x86 commit in sys-process/audit: ChangeLog audit-1.7.4.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/05/25 04:35:41

  Modified:             ChangeLog
  Added:                audit-1.7.4.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.5.2)

Revision  Changes    Path
1.48                 sys-process/audit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -p -w -b -B -u -u -r1.47 -r1.48
--- ChangeLog	24 May 2008 15:10:48 -0000	1.47
+++ ChangeLog	25 May 2008 04:35:40 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for sys-process/audit
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v 1.47 2008/05/24 15:10:48 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v 1.48 2008/05/25 04:35:40 robbat2 Exp $
+
+*audit-1.7.4 (25 May 2008)
+
+  25 May 2008; Robin H. Johnson <robbat2@gentoo.org> +audit-1.7.4.ebuild:
+  Version bump.
 
   24 May 2008; Christian Faulhammer <opfer@gentoo.org> audit-1.7.3.ebuild:
   stable x86, security bug 215705



1.1                  sys-process/audit/audit-1.7.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/audit-1.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/audit-1.7.4.ebuild?rev=1.1&content-type=text/plain

Index: audit-1.7.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/audit-1.7.4.ebuild,v 1.1 2008/05/25 04:35:40 robbat2 Exp $

inherit autotools multilib toolchain-funcs python

DESCRIPTION="Userspace utilities for storing and processing auditing records"
HOMEPAGE="http://people.redhat.com/sgrubb/audit/"
SRC_URI="http://people.redhat.com/sgrubb/audit/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="ldap"
# Testcases are pretty useless as they are built for RedHat users/groups and
# kernels.
RESTRICT="test"

RDEPEND=">=dev-lang/python-2.4
		ldap? ( net-nds/openldap )"
DEPEND="${RDEPEND}
	dev-lang/swig
	>=sys-kernel/linux-headers-2.6.23"
# Do not use os-headers as this is linux specific

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Old patch applies fine
	#EPATCH_OPTS="-p0 -d${S}" epatch "${FILESDIR}"/${PN}-1.5.4-build.patch

	# Applied by upstream
	#EPATCH_OPTS="-p1 -d${S}" epatch "${FILESDIR}"/${PN}-1.5.4-swig-gcc-attribute.patch

	# Do not build GUI tools
	sed -i \
		-e '/AC_CONFIG_SUBDIRS.*system-config-audit/d' \
		"${S}"/configure.ac
	sed -i \
		-e 's,system-config-audit,,g' \
		-e '/^SUBDIRS/s,\\$,,g' \
		"${S}"/Makefile.am
	rm -rf "${S}"/system-config-audit

	# Probably goes away in 1.6.9
	EPATCH_OPTS="-p1 -d${S}" epatch "${FILESDIR}"/audit-1.6.8-subdirs-fix.patch

	if ! use ldap; then
		sed -i \
			-e '/^AC_OUTPUT/s,audisp/plugins/zos-remote/Makefile,,g' \
			"${S}"/configure.ac
		sed -i \
			-e '/^SUBDIRS/s,zos-remote,,g' \
			"${S}"/audisp/plugins/Makefile.am
	fi

	# Regenerate autotooling
	eautoreconf
}

src_compile() {
	#append-flags -D'__attribute__(x)='
	econf --sbindir=/sbin --without-prelude || die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README* THANKS TODO
	docinto contrib
	dodoc contrib/*
	docinto contrib/plugin
	dodoc contrib/plugin/*

	newinitd "${FILESDIR}"/auditd-init.d-1.2.3 auditd
	newconfd "${FILESDIR}"/auditd-conf.d-1.2.3 auditd

	# things like shadow use this so we need to be in /
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/lib*.so* "${D}"/$(get_libdir)/ || die
	gen_usr_ldscript libaudit.so libauparse.so

	# remove RedHat garbage
	rm -r "${D}"/etc/{rc.d,sysconfig} || die

	# Gentoo rules
	insinto /etc/audit/
	doins "${FILESDIR}"/audit.rules*

	# audit logs go here
	keepdir /var/log/audit/

	# Security
	lockdown_perms "${D}"
}

pkg_postinst() {
	lockdown_perms "${ROOT}"
	python_mod_optimize
}

pkg_postrm() {
	python_mod_cleanup
}

lockdown_perms() {
	# upstream wants these to have restrictive perms
	basedir="$1"
	chmod 0750 "${basedir}"/sbin/au{ditctl,report,dispd,ditd,search,trace} 2>/dev/null
	chmod 0750 "${basedir}"/var/log/audit/ 2>/dev/null
	chmod 0640 "${basedir}"/etc/{audit/,}{auditd.conf,audit.rules*} 2>/dev/null
}



-- 
gentoo-commits@lists.gentoo.org mailing list