[gentoo-commits] gentoo-x86 commit in app-text/bibus: ChangeLog bibus-1.4.3.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/bibus: ChangeLog bibus-1.4.3.ebuild

[Markus Dittrich (markusle)]

markusle    08/05/22 14:18:46

  Modified:             ChangeLog
  Added:                bibus-1.4.3.ebuild
  Log:
  Version bump and added fixed desktop entry file (fixes bugs #223173 and #168037).
  (Portage version: 2.1.5.2)

Revision  Changes    Path
1.6                  app-text/bibus/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/bibus/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/bibus/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/bibus/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/bibus/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	8 Feb 2008 14:16:37 -0000	1.5
+++ ChangeLog	22 May 2008 14:18:45 -0000	1.6
@@ -1,6 +1,14 @@
 # ChangeLog for app-text/bibus
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/bibus/ChangeLog,v 1.5 2008/02/08 14:16:37 markusle Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/bibus/ChangeLog,v 1.6 2008/05/22 14:18:45 markusle Exp $
+
+*bibus-1.4.3 (22 May 2008)
+
+  22 May 2008; Markus Dittrich <markusle@gentoo.org>
+  +files/bibus-1.4.3-install.patch, +bibus-1.4.3.ebuild:
+  Version bump and added fixed desktop entry file (fixes bugs #223173 and
+  #168037). Thanks much to Attila Tóth <atoth@atoth.sote.hu> for his
+  patches.
 
 *bibus-1.4.0_rc2 (08 Feb 2008)
 



1.1                  app-text/bibus/bibus-1.4.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/bibus/bibus-1.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/bibus/bibus-1.4.3.ebuild?rev=1.1&content-type=text/plain

Index: bibus-1.4.3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/bibus/bibus-1.4.3.ebuild,v 1.1 2008/05/22 14:18:45 markusle Exp $

inherit python multilib eutils

MY_PV="1.4.3"

DESCRIPTION="Bibliographic and reference management software, integrates with OO.o and MS Word"
HOMEPAGE="http://bibus-biblio.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}-biblio/${PN}_${MY_PV}-1.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86 ~amd64"
IUSE="mysql sqlite"
# Most of this mess is designed to give the choice of sqlite or mysql
# but prefer sqlite. We also need to default to sqlite if neither is requested.
RDEPEND="virtual/ooo
	=dev-python/wxpython-2.6*
	sqlite? (
		dev-python/pysqlite
		dev-db/sqliteodbc
	)
	!sqlite? (
		mysql? (
			dev-python/mysql-python
			dev-db/myodbc
		)
		!mysql? (
			dev-python/pysqlite
			dev-db/sqliteodbc
		)
	)
	dev-db/unixODBC"
DEPEND="${RDEPEND}
	app-arch/unzip"

S="${WORKDIR}/${PN}${MY_PV}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-install.patch
	sed -e "s:GENTOO-PF:${P}:g" \
		-e "69aall:\n" \
		-e "s:\$\(compile\)::" \
		-i Makefile || die "Failed to patch makefile"
	sed -e "s:/usr/lib/:/usr/$(get_libdir)/:" \
		-i Setup/bibus.sh Makefile || die "Failed to fix bibus wrapper"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		oopath="/usr/$(get_libdir)/openoffice/program" \
		prefix='$(DESTDIR)/usr' \
		sysconfdir='$(DESTDIR)/etc' \
		install || die "emake install failed"
	emake \
		DESTDIR="${D}" \
		oopath="/usr/$(get_libdir)/openoffice/program" \
		prefix='$(DESTDIR)/usr' \
		sysconfdir='$(DESTDIR)/etc' \
		install-doc-en || die "emake install failed"

	insinto /usr/share/applications/
	doins Setup/bibus.desktop
	insinto /usr/share/icons/hicolor/48x48/apps/
	doins Pixmaps/bibus.png

	dodoc Docs/installation.txt
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"usr/share/bibus
}

pkg_postrm() {
	python_mod_cleanup "${ROOT}"usr/share/bibus
}



-- 
gentoo-commits@lists.gentoo.org mailing list