[gentoo-commits] gentoo-x86 commit in net-misc/wget: ChangeLog wget-1.11.2.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/wget: ChangeLog wget-1.11.2.ebuild

[Mike Frysinger (vapier)]

vapier      08/05/06 11:40:30

  Modified:             ChangeLog
  Added:                wget-1.11.2.ebuild
  Log:
  Version bump #220439 by Petr Pisar.
  (Portage version: 2.2_pre5)

Revision  Changes    Path
1.94                 net-misc/wget/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wget/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wget/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wget/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	26 Mar 2008 20:57:24 -0000	1.93
+++ ChangeLog	6 May 2008 11:40:30 -0000	1.94
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/wget
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.93 2008/03/26 20:57:24 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.94 2008/05/06 11:40:30 vapier Exp $
+
+*wget-1.11.2 (06 May 2008)
+
+  06 May 2008; Mike Frysinger <vapier@gentoo.org> +wget-1.11.2.ebuild:
+  Version bump #220439 by Petr Pisar.
 
 *wget-1.11.1 (26 Mar 2008)
 



1.1                  net-misc/wget/wget-1.11.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wget/wget-1.11.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wget/wget-1.11.2.ebuild?rev=1.1&content-type=text/plain

Index: wget-1.11.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/wget-1.11.2.ebuild,v 1.1 2008/05/06 11:40:30 vapier Exp $

inherit eutils flag-o-matic

DESCRIPTION="Network utility to retrieve files from the WWW"
HOMEPAGE="http://www.gnu.org/software/wget/"
SRC_URI="mirror://gnu/wget/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug ipv6 nls socks5 ssl static"

RDEPEND="ssl? ( >=dev-libs/openssl-0.9.6b )
	socks5? ( net-proxy/dante )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.11-linking.patch
}

src_compile() {
	# openssl-0.9.8 now builds with -pthread on the BSD's
	use elibc_FreeBSD && use ssl && append-ldflags -pthread

	use static && append-ldflags -static
	econf \
		$(use_with ssl) $(use_enable ssl opie) $(use_enable ssl digest) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_enable debug) \
		$(use_with socks5 socks) \
		|| die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog* MAILING-LIST NEWS README
	dodoc doc/sample.wgetrc

	use ipv6 && cat "${FILESDIR}"/wgetrc-ipv6 >> "${D}"/etc/wgetrc

	sed -i \
		-e 's:/usr/local/etc:/etc:g' \
		"${D}"/etc/wgetrc \
		"${D}"/usr/share/man/man1/wget.1 \
		"${D}"/usr/share/info/wget.info
}

pkg_preinst() {
	ewarn "The /etc/wget/wgetrc file has been relocated to /etc/wgetrc"
	if [[ -e ${ROOT}/etc/wget/wgetrc ]] ; then
		if [[ -e ${ROOT}/etc/wgetrc ]] ; then
			ewarn "You have both /etc/wget/wgetrc and /etc/wgetrc ... you should delete the former"
		else
			einfo "Moving /etc/wget/wgetrc to /etc/wgetrc for you"
			mv "${ROOT}"/etc/wget/wgetrc "${ROOT}"/etc/wgetrc
			rmdir "${ROOT}"/etc/wget 2>/dev/null
		fi
	fi
}



-- 
gentoo-commits@lists.gentoo.org mailing list