[gentoo-commits] gentoo-x86 commit in app-misc/emelfm2: ChangeLog emelfm2-0.4.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/emelfm2: ChangeLog emelfm2-0.4.ebuild

[Samuli Suominen (drac)]

drac        08/04/20 16:49:51

  Modified:             ChangeLog
  Added:                emelfm2-0.4.ebuild
  Log:
  Version bump and ~amd64 keyword wrt #217039, thanks to Tobias Jakobi.
  (Portage version: 2.1.5_rc4)

Revision  Changes    Path
1.19                 app-misc/emelfm2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	7 Sep 2007 19:12:16 -0000	1.18
+++ ChangeLog	20 Apr 2008 16:49:51 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/emelfm2
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v 1.18 2007/09/07 19:12:16 josejx Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v 1.19 2008/04/20 16:49:51 drac Exp $
+
+*emelfm2-0.4 (20 Apr 2008)
+
+  20 Apr 2008; Samuli Suominen <drac@gentoo.org> +emelfm2-0.4.ebuild:
+  Version bump and ~amd64 keyword wrt #217039, thanks to Tobias Jakobi.
 
   07 Sep 2007; Joseph Jezak <josejx@gentoo.org> emelfm2-0.3.5.ebuild:
   Marked ~ppc for bug #186562.



1.1                  app-misc/emelfm2/emelfm2-0.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.ebuild?rev=1.1&content-type=text/plain

Index: emelfm2-0.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.ebuild,v 1.1 2008/04/20 16:49:51 drac Exp $

inherit eutils toolchain-funcs multilib

DESCRIPTION="A file manager that implements the popular two-pane design"
HOMEPAGE="http://emelfm2.net"
SRC_URI="http://${PN}.net/rel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="acl unicode fam"

RESTRICT="test"

DEPEND=">=x11-libs/gtk+-2.12
	fam? ( virtual/fam )
	acl? ( sys-apps/acl )"
RDEPEND="${DEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:${PN}/${PN}_48.png:${PN}:" \
		docs/desktop_environment/${PN}.desktop || die "sed failed."
	sed -i -e "s:(PREFIX)/lib:(PREFIX)/$(get_libdir):" \
		Makefile || die "sed failed."
}

src_compile() {
	# These options need >=x11-libs/gtk-2.12 which we depend upon
	local myconf="USE_LATEST=1 WITH_TRANSPARENCY=1"

	if use acl; then
		myconf="${myconf} WITH_ACL=1"
	fi

	if use unicode; then
		myconf="${myconf} FILES_UTF8ONLY=1"
	fi

	if use fam; then
		if has_version "app-admin/gamin"; then
			myconf="${myconf} USE_GAMIN=1"
		else
			myconf="${myconf} USE_FAM=1"
		fi
	else
		myconf="${myconf} USE_FAM=0"
	fi

	tc-export CC
	emake ICON_DIR="/usr/share/pixmaps/${PN}" ${myconf} || die "emake failed."
}

src_install() {
	emake PREFIX="${D}/usr" install || die "emake install failed."
	newicon icons/${PN}_48.png ${PN}.png
	prepalldocs
}



-- 
gentoo-commits@lists.gentoo.org mailing list