[gentoo-commits] gentoo-x86 commit in sci-electronics/kicad: ChangeLog kicad-20080320.918.ebuild

[gentoo-commits] gentoo-x86 commit in sci-electronics/kicad: ChangeLog kicad-20080320.918.ebuild

[Denis Dupeyron (calchan)]

calchan     08/03/23 17:40:34

  Modified:             ChangeLog
  Added:                kicad-20080320.918.ebuild
  Log:
  Version bump, many thanks to Igor Plyatov (bug #214096).
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.32                 sci-electronics/kicad/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/kicad/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/kicad/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/kicad/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/kicad/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	29 Feb 2008 20:39:59 -0000	1.31
+++ ChangeLog	23 Mar 2008 17:40:34 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for sci-electronics/kicad
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/ChangeLog,v 1.31 2008/02/29 20:39:59 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/ChangeLog,v 1.32 2008/03/23 17:40:34 calchan Exp $
+
+*kicad-20080320.918 (23 Mar 2008)
+
+  23 Mar 2008; Denis Dupeyron <calchan@gentoo.org>
+  +kicad-20080320.918.ebuild:
+  Version bump, many thanks to Igor Plyatov (bug #214096).
 
   29 Feb 2008; Carsten Lohrke <carlo@gentoo.org> kicad-20070115.ebuild,
   kicad-20070525.ebuild, kicad-20070702.ebuild:



1.1                  sci-electronics/kicad/kicad-20080320.918.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/kicad/kicad-20080320.918.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/kicad/kicad-20080320.918.ebuild?rev=1.1&content-type=text/plain

Index: kicad-20080320.918.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/kicad-20080320.918.ebuild,v 1.1 2008/03/23 17:40:34 calchan Exp $

inherit versionator wxwidgets cmake-utils flag-o-matic

MY_PV="$(get_major_version)-r$(get_after_major_version)"
LIB_VERSION="1.0"
DOC_VERSION="1.0"

DESCRIPTION="Electronic Schematic and PCB design tools."
HOMEPAGE="http://kicad.sourceforge.net"
SRC_URI="mirror://sourceforge/kicad/${PN}-${MY_PV}.tar.bz2
	!minimal? ( mirror://sourceforge/kicad/${PN}-library-${LIB_VERSION}.tbz2 )
	doc? ( mirror://sourceforge/kicad/${PN}-doc-${DOC_VERSION}.tbz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc debug examples minimal"

DEPEND="=x11-libs/wxGTK-2.8*
	dev-libs/boost"

S="${WORKDIR}/${PN}"
DOCS="change_log.txt todo.txt"

pkg_setup() {
	WX_GTK_VER="2.8"
	need-wxwidgets unicode
	check_wxuse opengl
}

src_unpack() {
	unpack ${A}
	if ! use examples ; then
		sed -i -e "s:^add_subdirectory(demos):#add_subdirectory(demos):" "${S}"/CMakeLists.txt || die "sed failed"
	fi
	sed -i -e "s:^install(FILES \${CMAKE_CURRENT_SOURCE_DIR}/install\.txt:#install(FILES \${CMAKE_CURRENT_SOURCE_DIR}/install\.txt:" \
		"${S}"/CMakeLists.txt || die "sed failed"
}

src_install() {
	cmake-utils_src_install
	[[ -d "${WORKDIR}/usr" ]] && doins -r "${WORKDIR}/usr"
}

pkg_postinst() {
	if use minimal ; then
		ewarn "If the schematic and/or board editors complain about missing libraries when you open old projects,"
		ewarn "you will have to take one or more of the following actions :"
		ewarn "- Install the missing libraries manually."
		ewarn "- Remove the libraries from the 'Libs and Dir' preferences."
		ewarn "- Fix the libraries' locations in the 'Libs and Dir' preferences."
		ewarn "- Emerge kicad without the 'minimal' USE flag."
	else
		elog "Please note that the PDF datasheets that can be linked to components from the default libraries"
		elog "cannot be mirrored by Gentoo for legal reasons."
		elog "If you want them, you need to download them yourself from :"
		elog "${HOMEPAGE}"
		elog "and install them manually."
	fi
	elog
	elog "You may want to emerge media-gfx/wings if you want to create 3D models of components."
}



-- 
gentoo-commits@lists.gentoo.org mailing list