[gentoo-commits] gentoo-x86 commit in net-misc/rsync: ChangeLog rsync-3.0.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/rsync: ChangeLog rsync-3.0.0.ebuild

[Mike Frysinger (vapier)]

vapier      08/03/01 22:13:43

  Modified:             ChangeLog
  Added:                rsync-3.0.0.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_pre2)

Revision  Changes    Path
1.148                net-misc/rsync/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.148&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.148&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rsync/ChangeLog?r1=1.147&r2=1.148

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v
retrieving revision 1.147
retrieving revision 1.148
diff -u -r1.147 -r1.148
--- ChangeLog	20 Feb 2008 04:25:08 -0000	1.147
+++ ChangeLog	1 Mar 2008 22:13:43 -0000	1.148
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rsync
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.147 2008/02/20 04:25:08 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.148 2008/03/01 22:13:43 vapier Exp $
+
+*rsync-3.0.0 (01 Mar 2008)
+
+  01 Mar 2008; Mike Frysinger <vapier@gentoo.org> +rsync-3.0.0.ebuild:
+  Version bump.
 
 *rsync-3.0.0_pre10 (20 Feb 2008)
 



1.1                  net-misc/rsync/rsync-3.0.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rsync/rsync-3.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rsync/rsync-3.0.0.ebuild?rev=1.1&content-type=text/plain

Index: rsync-3.0.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/rsync-3.0.0.ebuild,v 1.1 2008/03/01 22:13:43 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs autotools

DESCRIPTION="File transfer program to keep remote files into sync"
HOMEPAGE="http://rsync.samba.org/"
SRC_URI="http://rsync.samba.org/ftp/rsync/${P/_/}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="acl ipv6 static xattr xinetd"

DEPEND=">=dev-libs/popt-1.5
	acl? ( kernel_linux? ( sys-apps/acl ) )
	xattr? ( kernel_linux? ( sys-apps/attr ) )
	xinetd? ( sys-apps/xinetd )"

S=${WORKDIR}/${P/_/}

src_compile() {
	use static && append-ldflags -static
	econf \
		--without-included-popt \
		$(use_enable acl acl-support) \
		$(use_enable xattr xattr-support) \
		$(use_enable ipv6) \
		--with-rsyncd-conf=/etc/rsyncd.conf \
		|| die
	emake || die "emake failed"
}

pkg_preinst() {
	if [[ -e ${ROOT}/etc/rsync/rsyncd.conf ]] && [[ ! -e ${ROOT}/etc/rsyncd.conf ]] ; then
		mv "${ROOT}"/etc/rsync/rsyncd.conf "${ROOT}"/etc/rsyncd.conf
		rm -f "${ROOT}"/etc/rsync/.keep
		rmdir "${ROOT}"/etc/rsync >& /dev/null
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	newconfd "${FILESDIR}"/rsyncd.conf.d rsyncd
	newinitd "${FILESDIR}"/rsyncd.init.d rsyncd
	dodoc NEWS OLDNEWS README TODO tech_report.tex
	insinto /etc
	doins "${FILESDIR}"/rsyncd.conf
	if use xinetd ; then
		insinto /etc/xinetd.d
		newins "${FILESDIR}"/rsyncd.xinetd rsyncd
	fi
}

pkg_postinst() {
	ewarn "The rsyncd.conf file has been moved for you to /etc/rsyncd.conf"
	echo
	ewarn "Please make sure you do NOT disable the rsync server running"
	ewarn "in a chroot.  Please check /etc/rsyncd.conf and make sure"
	ewarn "it says: use chroot = yes"
}



-- 
gentoo-commits@lists.gentoo.org mailing list