[gentoo-commits] gentoo-x86 commit in media-sound/alsaplayer: ChangeLog alsaplayer-0.99.80.ebuild alsaplayer-0.99.80_rc3.ebuild alsaplayer-0.99.80_rc4.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/alsaplayer: ChangeLog alsaplayer-0.99.80.ebuild alsaplayer-0.99.80_rc3.ebuild alsaplayer-0.99.80_rc4.ebuild

[Samuli Suominen (drac)]

drac        08/03/01 12:01:27

  Modified:             ChangeLog
  Added:                alsaplayer-0.99.80.ebuild
  Removed:              alsaplayer-0.99.80_rc3.ebuild
                        alsaplayer-0.99.80_rc4.ebuild
  Log:
  Version bump wrt #198437, thanks to Christian Faulhammer for reporting.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.66                 media-sound/alsaplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsaplayer/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsaplayer/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsaplayer/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	13 Oct 2007 17:43:30 -0000	1.65
+++ ChangeLog	1 Mar 2008 12:01:27 -0000	1.66
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/alsaplayer
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v 1.65 2007/10/13 17:43:30 dirtyepic Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v 1.66 2008/03/01 12:01:27 drac Exp $
+
+*alsaplayer-0.99.80 (01 Mar 2008)
+
+  01 Mar 2008; Samuli Suominen <drac@gentoo.org>
+  -files/alsaplayer-0.99.80_rc3-glib.patch, -alsaplayer-0.99.80_rc3.ebuild,
+  -alsaplayer-0.99.80_rc4.ebuild, +alsaplayer-0.99.80.ebuild:
+  Version bump wrt #198437, thanks to Christian Faulhammer for reporting.
 
   13 Oct 2007; Ryan Hill <dirtyepic@gentoo.org> metadata.xml:
   Remove me from metadata.



1.1                  media-sound/alsaplayer/alsaplayer-0.99.80.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.80.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.80.ebuild?rev=1.1&content-type=text/plain

Index: alsaplayer-0.99.80.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.80.ebuild,v 1.1 2008/03/01 12:01:27 drac Exp $

inherit autotools eutils

DESCRIPTION="A heavily multi-threaded pluggable audio player."
HOMEPAGE="http://www.alsaplayer.org"
SRC_URI="http://www.${PN}.org/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~sparc ~x86"
IUSE="alsa audiofile doc esd flac gtk jack mad mikmod nas nls ogg opengl oss vorbis xosd"

RDEPEND="media-libs/libsndfile
	mad? ( media-libs/libmad )
	gtk? ( >=x11-libs/gtk+-2.8 )
	alsa? ( media-libs/alsa-lib )
	audiofile? ( media-libs/audiofile )
	esd? ( media-sound/esound )
	flac? ( media-libs/flac )
	jack? ( >=media-sound/jack-audio-connection-kit-0.80 )
	mikmod? ( >=media-libs/libmikmod-3.1.10 )
	nas? ( media-libs/nas )
	ogg? ( media-libs/libogg )
	opengl? ( virtual/opengl )
	vorbis? ( media-libs/libvorbis )
	xosd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}_rc3-flags.patch
	eautoreconf
}


src_compile() {
	use xosd || export ac_cv_lib_xosd_xosd_create="no"
	use doc || export ac_cv_prog_HAVE_DOXYGEN="false"

	local myconf

	if ! use alsa && ! use oss && ! use esd && ! use jack && ! use nas; then
		ewarn "You've disabled alsa, oss, esd, jack and nas. Enabling oss for you."
		myconf="${myconf} --enable-oss"
	fi

	econf --disable-gtk --disable-sgi \
		$(use_enable audiofile) \
		$(use_enable esd) \
		$(use_enable flac) \
		$(use_enable gtk gtk2) \
		$(use_enable jack) \
		$(use_enable mikmod) \
		$(use_enable nas) \
		$(use_enable opengl) \
		$(use_enable oss) \
		$(use_enable sparc) \
		$(use_enable vorbis oggvorbis) \
		$(use_enable alsa) \
		$(use_enable nls) \
		$(use_enable mad) \
		--disable-dependency-tracking \
		${myconf}

	emake CFLAGS="${CFLAGS}" || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" docdir="${D}/usr/share/doc/${PF}" install \
		|| die "emake install failed."
	dodoc AUTHORS ChangeLog README TODO docs/*.txt
}



-- 
gentoo-commits@lists.gentoo.org mailing list