[gentoo-commits] gentoo-x86 commit in app-antivirus/clamav: ChangeLog clamav-0.92.1.ebuild

["Andrej Kacian (ticho)" <ticho@gentoo.org>]

ticho       08/02/11 23:42:29

  Modified:             ChangeLog
  Added:                clamav-0.92.1.ebuild
  Log:
  Version bump. Dropped compatibility patch to keep cl_loaddbdir() exposed.
  (Portage version: 2.1.4.3)

Revision  Changes    Path
1.273                app-antivirus/clamav/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.273&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.273&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?r1=1.272&r2=1.273

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v
retrieving revision 1.272
retrieving revision 1.273
diff -u -r1.272 -r1.273
--- ChangeLog	11 Feb 2008 22:58:32 -0000	1.272
+++ ChangeLog	11 Feb 2008 23:42:29 -0000	1.273
@@ -1,6 +1,11 @@
 # ChangeLog for app-antivirus/clamav
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.272 2008/02/11 22:58:32 ticho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.273 2008/02/11 23:42:29 ticho Exp $
+
+*clamav-0.92.1 (11 Feb 2008)
+
+  11 Feb 2008; Andrej Kacian <ticho@gentoo.org> +clamav-0.92.1.ebuild:
+  Version bump. Dropped compatibility patch to keep cl_loaddbdir() exposed.
 
   11 Feb 2008; Andrej Kacian <ticho@gentoo.org> clamav-0.91.2.ebuild,
   clamav-0.91.2-r1.ebuild, clamav-0.92.ebuild:



1.1                  app-antivirus/clamav/clamav-0.92.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/clamav-0.92.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/clamav-0.92.1.ebuild?rev=1.1&content-type=text/plain

Index: clamav-0.92.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/clamav-0.92.1.ebuild,v 1.1 2008/02/11 23:42:29 ticho Exp $

inherit autotools eutils flag-o-matic fixheadtails multilib

DESCRIPTION="Clam Anti-Virus Scanner"
HOMEPAGE="http://www.clamav.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bzip2 crypt mailwrapper milter nls selinux"

DEPEND="virtual/libc
	bzip2? ( app-arch/bzip2 )
	crypt? ( >=dev-libs/gmp-4.1.2 )
	milter? ( || ( mail-filter/libmilter mail-mta/sendmail ) )
	nls? ( sys-devel/gettext )
	dev-libs/gmp
	>=sys-libs/zlib-1.2.1-r3
	>=sys-apps/sed-4"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-clamav )
	sys-apps/grep"
PROVIDE="virtual/antivirus"

pkg_setup() {
	if use milter; then
		if [ ! -e /usr/$(get_libdir)/libmilter.a ] ; then
			ewarn "In order to enable milter support, clamav needs sendmail with enabled milter"
			ewarn "USE flag, or mail-filter/libmilter package."
		fi
	fi

	enewgroup clamav
	enewuser clamav -1 -1 /dev/null clamav
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.90-nls.patch
	eautoreconf
}

src_compile() {
	has_version =sys-libs/glibc-2.2* && filter-lfs-flags

	local myconf

	# we depend on fixed zlib, so we can disable this check to prevent redundant
	# warning (bug #61749)
	myconf="${myconf} --disable-zlib-vcheck"
	# use id utility instead of /etc/passwd parsing (bug #72540)
	myconf="${myconf} --enable-id-check"
	use milter && {
		myconf="${myconf} --enable-milter"
		use mailwrapper && \
			myconf="${myconf} --with-sendmail=/usr/sbin/sendmail.sendmail"
	}

	ht_fix_file configure
	econf ${myconf} \
		$(use_enable bzip2) \
		$(use_enable nls) \
		--disable-experimental \
		--with-dbdir=/var/lib/clamav || die
	emake || die
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS BUGS NEWS README ChangeLog FAQ
	newconfd "${FILESDIR}"/clamd.conf clamd
	newinitd "${FILESDIR}"/clamd.rc clamd
	dodoc "${FILESDIR}"/clamav-milter.README.gentoo

	dodir /var/run/clamav
	keepdir /var/run/clamav
	fowners clamav:clamav /var/run/clamav
	dodir /var/log/clamav
	keepdir /var/log/clamav
	fowners clamav:clamav /var/log/clamav

	# Change /etc/clamd.conf to be usable out of the box
	sed -i -e "s:^\(Example\):\# \1:" \
		-e "s:.*\(PidFile\) .*:\1 /var/run/clamav/clamd.pid:" \
		-e "s:.*\(LocalSocket\) .*:\1 /var/run/clamav/clamd.sock:" \
		-e "s:.*\(User\) .*:\1 clamav:" \
		-e "s:^\#\(LogFile\) .*:\1 /var/log/clamav/clamd.log:" \
		-e "s:^\#\(LogTime\).*:\1 yes:" \
		"${D}"/etc/clamd.conf

	# Do the same for /etc/freshclam.conf
	sed -i -e "s:^\(Example\):\# \1:" \
		-e "s:.*\(PidFile\) .*:\1 /var/run/clamav/freshclam.pid:" \
		-e "s:.*\(DatabaseOwner\) .*:\1 clamav:" \
		-e "s:^\#\(UpdateLogFile\) .*:\1 /var/log/clamav/freshclam.log:" \
		-e "s:^\#\(NotifyClamd\).*:\1 /etc/clamd.conf:" \
		-e "s:^\#\(ScriptedUpdates\).*:\1 yes:" \
		"${D}"/etc/freshclam.conf

	if use milter ; then
		echo "START_MILTER=no" \
			>> "${D}"/etc/conf.d/clamd
		echo "MILTER_SOCKET=\"/var/run/clamav/clmilter.sock\"" \
			>>"${D}"/etc/conf.d/clamd
		echo "MILTER_OPTS=\"-m 10 --timeout=0\"" \
			>>"${D}"/etc/conf.d/clamd
	fi

	diropts ""
	dodir /etc/logrotate.d
	insopts -m0644
	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${PN}.logrotate ${PN}
}

pkg_postinst() {
	echo
	if use milter ; then
		elog "For simple instructions how to setup the clamav-milter"
		elog "read /usr/share/doc/${PF}/clamav-milter.README.gentoo.gz"
		echo
	fi
	ewarn "WARNING: In 0.92.1, the logic in the scanner limits have been reworked. This"
	ewarn "results in different command line options to clamscan, different config"
	ewarn "options to clamd and, overall, a different behaviour."
	echo
	ewarn "The soname for libclamav has changed in clamav-0.92."
	ewarn "If you have upgraded from that or earlier version, it is recommended to run:"
	ewarn "\trevdep-rebuild --library libclamav.so.2"
	ewarn "This will fix linking errors caused by this change."
	echo
}



-- 
gentoo-commits@lists.gentoo.org mailing list