[gentoo-commits] gentoo-x86 commit in net-voip/linphone: ChangeLog linphone-2.0.1.ebuild

[gentoo-commits] gentoo-x86 commit in net-voip/linphone: ChangeLog linphone-2.0.1.ebuild

[Mike Frysinger (vapier)]

vapier      08/01/14 12:51:26

  Modified:             ChangeLog
  Added:                linphone-2.0.1.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.4)

Revision  Changes    Path
1.5                  net-voip/linphone/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/linphone/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/linphone/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/linphone/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	20 Aug 2007 20:22:42 -0000	1.4
+++ ChangeLog	14 Jan 2008 12:51:25 -0000	1.5
@@ -1,6 +1,14 @@
 # ChangeLog for net-voip/linphone
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.4 2007/08/20 20:22:42 vapier Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.5 2008/01/14 12:51:25 vapier Exp $
+
+*linphone-2.0.1 (14 Jan 2008)
+
+  14 Jan 2008; Mike Frysinger <vapier@gentoo.org>
+  +files/linphone-1.99.0-core-amd64.patch,
+  +files/linphone-2.0.1-configure-gsm.patch,
+  +files/linphone-2.0.1-mediastreamer-deps.patch, +linphone-2.0.1.ebuild:
+  Version bump.
 
 *linphone-1.7.1-r1 (20 Aug 2007)
 



1.1                  net-voip/linphone/linphone-2.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/linphone/linphone-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/linphone/linphone-2.0.1.ebuild?rev=1.1&content-type=text/plain

Index: linphone-2.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/linphone-2.0.1.ebuild,v 1.1 2008/01/14 12:51:25 vapier Exp $

# Note: video support in linphone relies on swscaler being disabled
#       in ffmpeg.  this is because the video code in linphone is old
#       and uses the old interface.  solution: fix linphone's video
#       code.  workaround: build ffmpeg w/out --enable-swscaler.

inherit eutils

DESCRIPTION="Voice Over IP phone (internet phone which uses SIP)"
HOMEPAGE="http://www.linphone.org/"
SRC_URI="http://download.savannah.nongnu.org/releases/${PN}/stable/sources/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa arts console gsm gtk ilbc ipv6 novideo xv"

RDEPEND="dev-libs/glib
	dev-perl/XML-Parser
	net-dns/bind-tools
	>=net-libs/libosip-3.0.3
	>=net-libs/libeXosip-3.0.3
	>=media-libs/speex-1.1.12
	gsm? ( >=media-sound/gsm-1.0.12 )
	x86? ( xv? ( dev-lang/nasm ) )
	gtk? (
		>=x11-libs/gtk+-2
		gnome-base/libglade
	)
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/arts )
	ilbc? ( dev-libs/ilbc-rfc3951 )
	!novideo? (
		>=media-libs/libsdl-1.2.9
		media-video/ffmpeg
		>=media-libs/libtheora-1.0_alpha7
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"
# use the bundled ortp until newer versions leave package.mask
#	>=net-libs/ortp-0.9.0
#	portaudio? ( >=media-libs/portaudio-19_pre )"
# media-libs/gsm-1.0.12 fails on amd64 due to bug #192736

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/linphone-1.6.0-call.patch
	epatch "${FILESDIR}"/linphone-1.99.0-core-amd64.patch
	epatch "${FILESDIR}"/linphone-2.0.1-configure-gsm.patch
	epatch "${FILESDIR}"/linphone-2.0.1-mediastreamer-deps.patch
}

src_compile() {
	econf \
		--disable-strict \
		--libdir=/usr/$(get_libdir)/linphone \
		$(use_enable console console_ui) \
		$(use_enable gtk gtk_ui) \
		$(use_with ilbc) \
		$(use_enable ipv6) \
		$(use_enable alsa) \
		$(use_enable arts artsc) \
		$(use_enable gsm) \
		$(use_enable !novideo video) \
		--disable-portaudio \
		$(use_enable x86 truespeech) \
		|| die "Unable to configure"
		#--enable-external-ortp \
		#$(use_enable portaudio)
	emake || die "Unable to make"
}

src_install () {
	emake DESTDIR="${D}" install || die "Failed to install"
	dodoc AUTHORS BUGS ChangeLog INSTALL NEWS README README.arm TODO

	# don't install ortp includes, docs and pkgconfig files
	# to avoid conflicts with net-libs/ortp
	rm -rf "${D}"/usr/include/ortp
	rm -rf "${D}"/usr/share/gtk-doc/html/ortp
	rm -rf "${D}"/usr/$(get_libdir)/linphone/pkgconfig
	rm -rf "${D}"/ortp
}



-- 
gentoo-commits@lists.gentoo.org mailing list