[gentoo-commits] gentoo-x86 commit in app-pda/libsyncml: ChangeLog libsyncml-0.4.5.ebuild

[gentoo-commits] gentoo-x86 commit in app-pda/libsyncml: ChangeLog libsyncml-0.4.5.ebuild

[Piotr Jaroszynski (peper)]

peper       07/12/29 14:40:32

  Modified:             ChangeLog
  Added:                libsyncml-0.4.5.ebuild
  Log:
  Add 0.4.5.
  (Portage version: 2.1.4_rc11)

Revision  Changes    Path
1.8                  app-pda/libsyncml/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	7 Dec 2007 16:25:18 -0000	1.7
+++ ChangeLog	29 Dec 2007 14:40:31 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for app-pda/libsyncml
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.7 2007/12/07 16:25:18 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.8 2007/12/29 14:40:31 peper Exp $
+
+*libsyncml-0.4.5 (29 Dec 2007)
+
+  29 Dec 2007; Piotr Jaroszyński <peper@gentoo.org>
+  +libsyncml-0.4.5.ebuild:
+  Add 0.4.5.
 
   07 Dec 2007; Piotr Jaroszyński <peper@gentoo.org> libsyncml-9999.ebuild:
   Update the scm ebuild wrt to the upstream switch to cmake. Make obex and



1.1                  app-pda/libsyncml/libsyncml-0.4.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/libsyncml-0.4.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/libsyncml-0.4.5.ebuild?rev=1.1&content-type=text/plain

Index: libsyncml-0.4.5.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/libsyncml-0.4.5.ebuild,v 1.1 2007/12/29 14:40:31 peper Exp $

EAPI="1"

inherit eutils

DESCRIPTION="Implementation of the SyncML protocol"
HOMEPAGE="http://libsyncml.opensync.org/"
SRC_URI="http://libsyncml.opensync.org/download/releases/${PV}/${P}.tar.bz2"

KEYWORDS="~amd64 ~x86"
SLOT="0"
LICENSE="LGPL-2.1"
IUSE="bluetooth +debug doc http +obex"

RDEPEND=">=dev-libs/glib-2.0
	>=dev-libs/libwbxml-0.9.2
	dev-libs/libxml2
	http? ( >=net-libs/libsoup-2.2.91 )
	obex? ( >=dev-libs/openobex-1.1 )
	bluetooth? ( net-wireless/bluez-libs )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

# Some of the tests are broken
RESTRICT="test"

pkg_setup() {
	if ! use obex && ! use http; then
		eerror "${CATEGORY}/${P} without support for obex nor http is unusable."
		eerror "Please enable \"obex\" or/and \"http\" USE flags."
		die "Please enable \"obex\" or/and \"http\" USE flags."
	fi

	if use bluetooth; then
		if use obex && ! built_with_use dev-libs/openobex bluetooth; then
			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
			eerror "and \"obex\" USE flags, but dev-libs/openobex was built without"
			eerror "the \"bluetooth\" USE flag."
			eerror "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
			die "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
		elif ! use obex; then
			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
			eerror "USE flag, but you didn't enable the \"obex\" flag, which is"
			eerror "needed for bluetooth support."
			eerror "Please enable \"obex\" USE flag."
			die "Please enable \"obex\" USE flag."
		fi
	fi
}

src_compile() {
	econf \
		$(use_enable bluetooth) \
		$(use_enable obex) \
		$(use_enable http) \
		$(use_enable debug) \
		$(use_enable debug tracing) \
		--disable-unit-tests \
		|| die "econf failed"
		#$(use_enable test unit-tests) \

	emake || die "emake failed"

	use doc && doxygen Doxyfile
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README

	use doc && dohtml docs/html/*
}



-- 
gentoo-commits@gentoo.org mailing list