[gentoo-commits] gentoo-x86 commit in app-mobilephone/wammu: ChangeLog wammu-0.24.ebuild

[gentoo-commits] gentoo-x86 commit in app-mobilephone/wammu: ChangeLog wammu-0.24.ebuild

[Alin Nastac (mrness)]

mrness      07/12/01 10:03:49

  Modified:             ChangeLog
  Added:                wammu-0.24.ebuild
  Log:
  Version bump (#200881).
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.27                 app-mobilephone/wammu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	11 Oct 2007 08:54:06 -0000	1.26
+++ ChangeLog	1 Dec 2007 10:03:48 -0000	1.27
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/wammu
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.26 2007/10/11 08:54:06 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.27 2007/12/01 10:03:48 mrness Exp $
+
+*wammu-0.24 (01 Dec 2007)
+
+  01 Dec 2007; Alin Năstac <mrness@gentoo.org> +wammu-0.24.ebuild:
+  Version bump (#200881).
 
 *wammu-0.23 (11 Oct 2007)
 



1.1                  app-mobilephone/wammu/wammu-0.24.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/wammu-0.24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/wammu-0.24.ebuild?rev=1.1&content-type=text/plain

Index: wammu-0.24.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/wammu-0.24.ebuild,v 1.1 2007/12/01 10:03:48 mrness Exp $

inherit distutils eutils versionator

DESCRIPTION="front-end for gammu (Nokia and other mobiles)"
HOMEPAGE="http://www.cihar.com/gammu/wammu/"
SRC_URI="http://dl.cihar.com/wammu/v0/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="bluetooth"

RDEPEND="=dev-python/wxpython-2.6*
	>=dev-python/python-gammu-0.23
	bluetooth? (
		|| (
			dev-python/pybluez
			net-wireless/gnome-bluetooth
		)
	)"
DEPEND="${RDEPEND}"

# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" af ca cs de es et fi fr hu it ko nl pl pt_BR ru sk sv zh_CN"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

src_unpack() {
	unpack ${A}

	# Select the suitable wxpython versions
	local wxpy_pkg wxpy_slot MY_WXPYTHON_SLOTS
	for wxpy_pkg in $(portageq match "${ROOT}" '=dev-python/wxpython-2.6*'); do
		if built_with_use --hidden --missing false =${wxpy_pkg} unicode ; then
			wxpy_slot=$(get_version_component_range 1-2 ${wxpy_pkg#*/*-})
			if [ -z "${MY_WXPYTHON_SLOTS}" ]; then
				MY_WXPYTHON_SLOTS="'${wxpy_slot}'"
			else
				MY_WXPYTHON_SLOTS="${MY_WXPYTHON_SLOTS}, '${wxpy_slot}'"
			fi
		fi
	done
	if [ -z "${MY_WXPYTHON_SLOTS}" ]; then
		eerror "None of the dev-python/wxpython installed versions have been built with Unicode support."
		eerror "Install wxpython with unicode USE flag enabled and try again."
		die "dev-python/wxpython is missing Unicode support"
	fi

	cd "${S}"
	sed -e "s/WXPYTHON_VER/${MY_WXPYTHON_SLOTS}/" \
		"${FILESDIR}"/${PN}-wxversion.patch \
		> "${T}"/${PN}-wxversion.patch
	epatch "${T}"/${PN}-wxversion.patch

	cd locale || die "locale directory not found"
	local lang
	for lang in ${MY_AVAILABLE_LINGUAS} ; do
		if ! use linguas_${lang} ; then
			rm -r ${lang}
		fi
	done
}

src_compile() {
	# SKIPWXCHECK: else 'import wx' results in
	# Xlib: connection to ":0.0" refused by server
	SKIPWXCHECK=yes distutils_src_compile
}

src_install() {
	DOCS="AUTHORS FAQ NEWS"
	SKIPWXCHECK=yes distutils_src_install
}



-- 
gentoo-commits@gentoo.org mailing list