[gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.14.4.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.14.4.ebuild

[Mart Raudsepp (leio)]

leio        07/11/25 15:03:02

  Modified:             ChangeLog
  Added:                glib-2.14.4.ebuild
  Log:
  Version bump for various non-critical bug fixes
  (Portage version: 2.1.4_rc3)

Revision  Changes    Path
1.297                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.297&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.297&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.296&r2=1.297

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.296
retrieving revision 1.297
diff -u -r1.296 -r1.297
--- ChangeLog	23 Nov 2007 17:48:30 -0000	1.296
+++ ChangeLog	25 Nov 2007 15:03:01 -0000	1.297
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.296 2007/11/23 17:48:30 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.297 2007/11/25 15:03:01 leio Exp $
+
+*glib-2.14.4 (25 Nov 2007)
+
+  25 Nov 2007; Mart Raudsepp <leio@gentoo.org> +glib-2.14.4.ebuild:
+  Version bump for various non-critical bug fixes
 
   23 Nov 2007; Jeroen Roovers <jer@gentoo.org> glib-2.14.3.ebuild:
   Stable for HPPA (bug #198845).



1.1                  dev-libs/glib/glib-2.14.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.14.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.14.4.ebuild?rev=1.1&content-type=text/plain

Index: glib-2.14.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.14.4.ebuild,v 1.1 2007/11/25 15:03:01 leio Exp $

inherit gnome.org libtool eutils flag-o-matic

DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug doc hardened"

RDEPEND="virtual/libc
	virtual/libiconv"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.16
	>=sys-devel/gettext-0.11
	doc? (
		>=dev-util/gtk-doc-1.4
		~app-text/docbook-xml-dtd-4.1.2
	)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if use ppc64 && use hardened ; then
		replace-flags -O[2-3] -O1
		epatch "${FILESDIR}/glib-2.6.3-testglib-ssp.patch"
	fi

	if use ia64 ; then
		# Only apply for < 4.1
		local major=$(gcc-major-version)
		local minor=$(gcc-minor-version)
		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
		fi
	fi

	sed -e "s/MATCH_LIMIT_RECURSION=10000000/MATCH_LIMIT_RECURSION=8192/g" \
		-i "${S}/glib/pcre/Makefile.in" "${S}/glib/pcre/Makefile.am"

	# Fix gmodule issues on fbsd; bug #184301
	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch

	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
}

src_compile() {
	epunt_cxx

	local myconf

	# Building with --disable-debug highly unrecommended.  It will build glib in
	# an unusable form as it disables some commonly used API.  Please do not
	# convert this to the use_enable form, as it results in a broken build.
	# -- compnerd (3/27/06)
	use debug && myconf="--enable-debug"

	# always build static libs, see #153807
	econf \
		$(use_enable doc gtk-doc) \
		${myconf} \
		--with-threads=posix \
		--enable-static || die "configure failed"

	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Installation failed"

	# Do not install charset.alias even if generated, leave it to libiconv
	rm -f "${D}/usr/lib/charset.alias"

	dodoc AUTHORS ChangeLog* NEWS* README
}



-- 
gentoo-commits@gentoo.org mailing list