[gentoo-commits] gentoo-x86 commit in games-fps/doomsday: ChangeLog doomsday-1.9.0_beta52.ebuild doomsday-1.9.0_beta4-r1.ebuild doomsday-1.9.0_beta5.ebuild doomsday-1.9.0_beta4.ebuild

[gentoo-commits] gentoo-x86 commit in games-fps/doomsday: ChangeLog doomsday-1.9.0_beta52.ebuild doomsday-1.9.0_beta4-r1.ebuild doomsday-1.9.0_beta5.ebuild doomsday-1.9.0_beta4.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    07/11/23 20:50:18

  Modified:             ChangeLog
  Added:                doomsday-1.9.0_beta52.ebuild
  Removed:              doomsday-1.9.0_beta4-r1.ebuild
                        doomsday-1.9.0_beta5.ebuild
                        doomsday-1.9.0_beta4.ebuild
  Log:
  version bump; clean out old, insecure versions
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.22                 games-fps/doomsday/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/doomsday/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/doomsday/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/doomsday/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/doomsday/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	13 Mar 2007 01:29:19 -0000	1.21
+++ ChangeLog	23 Nov 2007 20:50:17 -0000	1.22
@@ -1,6 +1,15 @@
 # ChangeLog for games-fps/doomsday
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/doomsday/ChangeLog,v 1.21 2007/03/13 01:29:19 wolf31o2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/doomsday/ChangeLog,v 1.22 2007/11/23 20:50:17 mr_bones_ Exp $
+
+*doomsday-1.9.0_beta52 (23 Nov 2007)
+
+  23 Nov 2007; Michael Sterrett <mr_bones_@gentoo.org>
+  -files/doomsday-1.9.0_beta4-configure.patch,
+  -files/doomsday-1.9.0_beta4-music-driver.patch,
+  -doomsday-1.9.0_beta4.ebuild, -doomsday-1.9.0_beta4-r1.ebuild,
+  -doomsday-1.9.0_beta5.ebuild, +doomsday-1.9.0_beta52.ebuild:
+  version bump; clean out old, insecure versions
 
   13 Mar 2007; Chris Gianelloni <wolf31o2@gentoo.org>
   doomsday-1.9.0_beta5.ebuild:



1.1                  games-fps/doomsday/doomsday-1.9.0_beta52.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/doomsday/doomsday-1.9.0_beta52.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/doomsday/doomsday-1.9.0_beta52.ebuild?rev=1.1&content-type=text/plain

Index: doomsday-1.9.0_beta52.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/doomsday/doomsday-1.9.0_beta52.ebuild,v 1.1 2007/11/23 20:50:17 mr_bones_ Exp $

inherit toolchain-funcs games

MY_P=deng-1.9.0-beta5.2 # FIXME, this is stupid
DESCRIPTION="A modern gaming engine for Doom, Heretic, and Hexen"
HOMEPAGE="http://www.doomsdayhq.com/"
SRC_URI="mirror://sourceforge/deng/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="openal"

RDEPEND="virtual/opengl
	virtual/glu
	media-libs/libsdl
	media-libs/sdl-mixer
	media-libs/sdl-net
	media-libs/libpng
	openal? ( media-libs/openal )"
DEPEND="${RDEPEND}
	>=dev-util/cmake-2.4
	app-arch/zip"

S=${WORKDIR}/${MY_P}/${MY_P}/build

src_compile() {
	cmake \
		-DCMAKE_C_COMPILER=$(type -P $(tc-getCC)) \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-Ddatadir="${GAMES_DATADIR}"/${PN} \
		-Dbindir="${GAMES_BINDIR}" \
		-Dlibdir="$(games_get_libdir)" \
		$(use openal && echo -DBUILDOPENAL=1) \
		../ || die "cmake failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	mv "${D}/${GAMES_DATADIR}"/{${PN}/data/jdoom,doom-data} || die
	dosym "${GAMES_DATADIR}"/doom-data "${GAMES_DATADIR}"/${PN}/data/jdoom || die

	local game
	for game in jdoom jheretic jhexen ; do
		newgamesbin "${FILESDIR}"/wrapper ${game}
		sed -i "s:GAME:${game}:" \
			"${D}/${GAMES_BINDIR}"/${game} \
			|| die "sed ${GAMES_BINDIR}/${game} failed"
	done

	# Make wrappers for the common wads
	local n
	for n in doom doom2 ; do
		games_make_wrapper ${PN}-${n} \
			"jdoom -file \"${GAMES_DATADIR}\"/doom-data/${n}.wad"
	done

	doman ../engine/doc/${PN}.6
	dodoc ../engine/doc/*.txt README
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "To play the original Doom levels, place doom.wad and/or doom2.wad"
	elog "into ${GAMES_DATADIR}/doom-data"
	elog "Then run doomsday-doom or doomsday-doom2 accordingly."
	elog
	elog "doom1.wad is the shareware demo wad consisting of 1 episode,"
	elog "and doom.wad is the full Doom 1 set of 3 episodes"
	elog "(or 4 in the Final Doom wad)."
	elog
	elog "You can even emerge doom-data and/or freedoom, with the doomsday use"
	elog "flag enabled, to play for free"
}



-- 
gentoo-commits@gentoo.org mailing list