[gentoo-commits] gentoo-x86 commit in app-editors/jedit: ChangeLog jedit-4.3_pre11.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/jedit: ChangeLog jedit-4.3_pre11.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    07/11/17 22:50:30

  Modified:             ChangeLog
  Added:                jedit-4.3_pre11.ebuild
  Log:
  Version bump. Fixes bug #196961.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.80                 app-editors/jedit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	13 Nov 2007 06:50:26 -0000	1.79
+++ ChangeLog	17 Nov 2007 22:50:30 -0000	1.80
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/jedit
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.79 2007/11/13 06:50:26 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.80 2007/11/17 22:50:30 betelgeuse Exp $
+
+*jedit-4.3_pre11 (17 Nov 2007)
+
+  17 Nov 2007; Petteri Räty <betelgeuse@gentoo.org>
+  +jedit-4.3_pre11.ebuild:
+  Version bump. Fixes bug #196961.
 
   13 Nov 2007; Christian Faulhammer <opfer@gentoo.org> jedit-4.2-r2.ebuild,
   jedit-4.3_pre9.ebuild:



1.1                  app-editors/jedit/jedit-4.3_pre11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/jedit-4.3_pre11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/jedit/jedit-4.3_pre11.ebuild?rev=1.1&content-type=text/plain

Index: jedit-4.3_pre11.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/jedit-4.3_pre11.ebuild,v 1.1 2007/11/17 22:50:30 betelgeuse Exp $

WANT_ANT_TASKS="ant-nodeps"

inherit java-pkg-2 java-ant-2 eutils fdo-mime

# TODO use versionator
MY_PV="${PV//_/}"

DESCRIPTION="Programmer's editor written in Java"
HOMEPAGE="http://www.jedit.org"
SRC_URI="mirror://sourceforge/${PN}/${PN}${MY_PV}source.tar.bz2"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
SLOT="0"
IUSE="doc"

RDEPEND=">=virtual/jre-1.5
	=dev-java/gnu-regexp-1*"
DEPEND=">=virtual/jdk-1.5
	doc? (
		=app-text/docbook-xml-dtd-4.3*
		>=app-text/docbook-xsl-stylesheets-1.65.1
		dev-libs/libxslt
	)
	=dev-java/gnu-regexp-1*"

S="${WORKDIR}/jEdit"

JEDIT_HOME="/usr/share/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# we need to use our own classpath
	java-ant_rewrite-classpath build.xml

	if use doc; then
		local xsl=$(echo /usr/share/sgml/docbook/xsl-stylesheets-*)
		xsl=${xsl// *}

		local xml=$(echo /usr/share/sgml/docbook/xml-dtd-4.3*)
		xml=${xml// *}

		echo "build.directory=." > build.properties
		echo "docbook.dtd.catalog=${xml}/docbook.cat" >> build.properties
		echo "docbook.xsl=${xsl}" >> build.properties
	fi

	# remove bundled sources
	rm -r gnu/* # gnu-regexp
	# still need to do: bsh, com.microstar.xml.*, org.gjt.*
	java-pkg_filter-compiler jikes
}
src_compile() {
	# TODO could build more docs, ie userdocs target instead of generate-javadoc
	eant build $(use_doc generate-javadoc) \
		-Dgentoo.classpath=$(java-pkg_getjars gnu-regexp-1):$(java-config --tools)
}

src_install () {
	dodir ${JEDIT_HOME}
	cp -R build/${PN}.jar jars doc macros modes properties startup \
		"${D}/usr/share/jedit"

	java-pkg_regjar ${JEDIT_HOME}/${PN}.jar

	java-pkg_dolauncher ${PN} --pwd ${JEDIT_HOME} --main org.gjt.sp.jedit.jEdit

	use doc && java-pkg_dojavadoc build/classes/javadoc/api

	make_desktop_entry ${PN} \
		jEdit \
		${JEDIT_HOME}/doc/${PN}.png \
		"Development;Utility;TextEditor"

	# keep the plugin directory
	keepdir ${JEDIT_HOME}/jars
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog "The system directory for jEdit plugins is"
	elog "${JEDIT_HOME}/jars"
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	elog "jEdit plugins installed into /usr/share/jedit/jars"
	elog "(after installation of jEdit itself) haven't been"
	elog "removed. To get rid of jEdit completely, you may"
	elog "want to run"
	elog ""
	elog "\trm -r ${JEDIT_HOME}"
	elog "Ignore this message if you are reinstalling or upgrading."
}



-- 
gentoo-commits@gentoo.org mailing list