[gentoo-commits] gentoo-x86 commit in app-shells/dash: ChangeLog dash-0.5.4.1-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-shells/dash: ChangeLog dash-0.5.4.1-r1.ebuild

[Roy Marples (uberlord)]

uberlord    07/10/08 10:25:03

  Modified:             ChangeLog
  Added:                dash-0.5.4.1-r1.ebuild
  Log:
  Fully support POSIX arithmetic
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.46                 app-shells/dash/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-shells/dash/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	13 Aug 2007 12:32:26 -0000	1.45
+++ ChangeLog	8 Oct 2007 10:25:03 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for app-shells/dash
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/ChangeLog,v 1.45 2007/08/13 12:32:26 uberlord Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/ChangeLog,v 1.46 2007/10/08 10:25:03 uberlord Exp $
+
+*dash-0.5.4.1-r1 (08 Oct 2007)
+
+  08 Oct 2007; Roy Marples <uberlord@gentoo.org>
+  +files/dash-0.5.4-posix-arith.patch, +dash-0.5.4.1-r1.ebuild:
+  Fully support POSIX arithmetic
 
 *dash-0.5.4.1 (13 Aug 2007)
 



1.1                  app-shells/dash/dash-0.5.4.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/dash-0.5.4.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-shells/dash/dash-0.5.4.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: dash-0.5.4.1-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/dash-0.5.4.1-r1.ebuild,v 1.1 2007/10/08 10:25:03 uberlord Exp $

inherit autotools eutils flag-o-matic toolchain-funcs

DEB_PV=${PV%.*}
DEB_PATCH=${PV##*.}
DEB_PF="${PN}_${DEB_PV}-${DEB_PATCH}"
MY_P="${PN}-${DEB_PV}"

DESCRIPTION="DASH is a direct descendant of the NetBSD version of ash (the
Almquist SHell) and is POSIX compliant"
HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${PN}-${DEB_PV}.tar.gz
		mirror://debian/pool/main/d/dash/${DEB_PF}.diff.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~x86"
IUSE="libedit static"

DEPEND="libedit? ( dev-libs/libedit )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	epatch "${WORKDIR}/${DEB_PF}".diff

	cd "${S}"
	epatch debian/diff/*

	# Fix reading of long lines
	epatch "${FILESDIR}/${PN}"-0.5.3-read-length.patch

	# Support posix arithmetic expansion
	epatch "${FILESDIR}/${PN}"-0.5.4-posix-arith.patch

	# Fix the invalid sort
	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins

	# Always statically link libedit in to ensure we always boot if it changes
	# which it has done in the past.
	local s="s/-ledit/-Wl,-Bstatic -ledit -Wl,-Bdynamic -lcurses/g"
	use static && s="s/-ledit/-ledit -lcurses/g"
	sed -i -e "${s}" configure.ac || die "Failed to sed configure.ac"

	# May as well, as the debian patches force this anyway
	eautoreconf
}

src_compile() {
	local myconf=

	use static && append-ldflags -static
	use libedit && myconf="${myconf} --with-libedit"
	export CC="$(tc-getCC)"

	econf ${myconf} || die "econf failed"
	emake CFLAGS="${CFLAGS}" || die "emake failed"
}

src_install() {
	exeinto /bin
	newexe src/dash dash
	newman src/dash.1 dash.1
	dodoc COPYING ChangeLog
}



-- 
gentoo-commits@gentoo.org mailing list