* [gentoo-commits] gentoo-x86 commit in net-im/pidgin: ChangeLog pidgin-2.2.0.ebuild
@ 2007-09-16 14:00 Olivier Crete (tester)
0 siblings, 0 replies; 2+ messages in thread
From: Olivier Crete (tester) @ 2007-09-16 14:00 UTC (permalink / raw
To: gentoo-commits
tester 07/09/16 14:00:59
Modified: ChangeLog
Added: pidgin-2.2.0.ebuild
Log:
Version bump
(Portage version: 2.1.3.9)
Revision Changes Path
1.29 net-im/pidgin/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?r1=1.28&r2=1.29
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog 28 Aug 2007 14:42:04 -0000 1.28
+++ ChangeLog 16 Sep 2007 14:00:59 -0000 1.29
@@ -1,6 +1,11 @@
# ChangeLog for net-im/pidgin
# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.28 2007/08/28 14:42:04 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.29 2007/09/16 14:00:59 tester Exp $
+
+*pidgin-2.2.0 (16 Sep 2007)
+
+ 16 Sep 2007; Olivier Crête <tester@gentoo.org> +pidgin-2.2.0.ebuild:
+ Version bump
28 Aug 2007; nixnut <nixnut@gentoo.org> pidgin-2.1.0.ebuild:
Stable on ppc wrt bug 189781
1.1 net-im/pidgin/pidgin-2.2.0.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild?rev=1.1&content-type=text/plain
Index: pidgin-2.2.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild,v 1.1 2007/09/16 14:00:59 tester Exp $
WANT_AUTOMAKE=1.9
inherit flag-o-matic eutils toolchain-funcs multilib autotools perl-app gnome2
MY_PV=${P/_beta/beta}
DESCRIPTION="GTK Instant Messenger client"
HOMEPAGE="http://pidgin.im/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bonjour dbus debug doc eds gadu gnutls gstreamer meanwhile networkmanager nls perl silc tcl tk spell qq gadu"
IUSE="${IUSE} gtk sasl ncurses groupwise prediction zephyr" # mono"
RDEPEND="
bonjour? ( net-dns/avahi )
dbus? ( >=dev-libs/dbus-glib-0.71
>=dev-python/dbus-python-0.71
>=sys-apps/dbus-0.90
>=dev-lang/python-2.4 )
gtk? (
spell? ( >=app-text/gtkspell-2.0.2 )
>=x11-libs/gtk+-2.0
>=x11-libs/startup-notification-0.5
x11-libs/libXScrnSaver
eds? ( gnome-extra/evolution-data-server ) )
>=dev-libs/glib-2.0
gstreamer? ( =media-libs/gstreamer-0.10*
=media-libs/gst-plugins-good-0.10* )
perl? ( >=dev-lang/perl-5.8.2-r1 )
gadu? ( net-libs/libgadu )
gnutls? ( net-libs/gnutls )
!gnutls? ( >=dev-libs/nss-3.11 )
meanwhile? ( net-libs/meanwhile )
silc? ( >=net-im/silc-toolkit-0.9.12-r3 )
zephyr? ( >=app-crypt/mit-krb5-1.3.6-r1 )
tcl? ( dev-lang/tcl )
tk? ( dev-lang/tk )
sasl? ( >=dev-libs/cyrus-sasl-2 )
doc? ( app-doc/doxygen )
dev-libs/libxml2
networkmanager? ( net-misc/networkmanager )
prediction? ( =dev-db/sqlite-3* )"
#mono? ( dev-lang/mono )"
DEPEND="$RDEPEND
dev-lang/perl
dev-perl/XML-Parser
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
S="${WORKDIR}/${MY_PV}"
# Enable Default protocols
DYNAMIC_PRPLS="irc,jabber,oscar,yahoo,zephyr,simple,msn"
# List of plugins yet to be ported (will be removed at some point)
# net-im/gaim-bnet
# x11-plugins/autoprofile
# x11-plugins/gaim-xfire
# x11-plugins/gaim-galago
# x11-themes/gaim-smileys (get liquidx to fix it)
# Abandonned
# x11-plugins/ignorance
# x11-plugins/bangexec
# x11-plugins/gaim-assistant
# Last release in 2004
# net-im/gaim-blogger
# x11-plugins/gaimosd
# Last release in 2005
# app-accessibility/festival-gaim
# Merged into something else
# net-im/gaim-meanwhile (integrated in gaim)
# net-im/gaim-snpp (merged into the plugin pack)
# x11-plugins/gaim-slashexec (integrated into plugin pack)
# List of plugins
# net-im/librvp
# x11-plugins/guifications
# x11-plugins/pidgin-encryption
# x11-plugins/pidgin-extprefs
# x11-plugins/pidgin-hotkeys
# x11-plugins/pidgin-latex
# x11-plugins/pidgin-libnotify
# x11-plugins/pidgin-otr
# x11-plugins/pidgin-rhythmbox
# x11-plugins/purple-plugin_pack
print_pidgin_warning() {
ewarn
ewarn "We strongly recommend that you backup your ~/.gaim directory"
ewarn "before running Pidgin for the first time. Things you should be"
ewarn "on the lookout for include problems with preferences being lost"
ewarn "or forgotten, buddy icons not working as you expect, plugins or"
ewarn "other external files not properly being found."
ewarn
ewarn "If you are merging ${MY_P} from an earlier version of gaim,"
ewarn "you may need to re-merge any plugins like gaim-encryption."
ewarn
ewarn "If you experience problems with pidgin, file them as bugs with"
ewarn "Gentoo's bugzilla, http://bugs.gentoo.org. DO NOT report them"
ewarn "as bugs with pidgin's bug tracker, and by all means DO NOT"
ewarn "seek help in #pidgin."
ewarn
ewarn "Be sure to USE=\"debug\" and include a backtrace for any seg"
ewarn "faults, see http://developer.pidgin.im/wiki/GetABacktrace for details on"
ewarn "backtraces."
ewarn
ewarn "Please read the pidgin FAQ at http://developer.pidgin.im/wiki/FAQ"
ewarn
}
pkg_setup() {
print_pidgin_warning
if use gadu && built_with_use net-libs/libgadu ssl ; then
eerror
eerror "You need to rebuild net-libs/libgadu with USE=-ssl in order"
eerror "enable gadu gadu support in pidgin."
eerror
die "Configure failed"
fi
if use ncurses && ! built_with_use sys-libs/ncurses unicode; then
eerror
eerror "You need to rebuild sys-libs/ncurses with USE=unicode in order"
eerror "to build finch the console client of pidgin."
eerror
die "Configure failed"
fi
if ! use gtk && ! use ncurses ; then
einfo
elog "As you did not pick gtk or ncurses use flag, building"
elog "console only."
einfo
fi
if use zephyr && ! built_with_use app-crypt/mit-krb5 krb4 ; then
eerror
eerror "You need to rebuild app-crypt/mit-krb5 with USE=krb4 in order to"
eerror "enable krb4 support for the zephyr protocol in pidgin"
eerror
die "Configure failed"
fi
}
src_compile() {
# Stabilize things, for your own good
strip-flags
replace-flags -O? -O2
# -msse2 doesn't play nice on gcc 3.2
[[ "`gcc-version`" == "3.2" ]] && filter-flags -msse2
local myconf
if use gadu; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},gg"
myconf="${myconf} --with-gadu-includes=."
myconf="${myconf} --with-gadu-libs=."
fi
if use silc; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},silc"
fi
if use qq; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},qq"
fi
if use meanwhile; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},sametime"
fi
if use bonjour; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},bonjour"
fi
if use groupwise; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},novell"
fi
if use zephyr; then
DYNAMIC_PRPLS="${DYNAMIC_PRPLS},zephyr"
fi
if use gnutls ; then
einfo "Disabling NSS, using GnuTLS"
myconf="${myconf} --enable-nss=no --enable-gnutls=yes"
myconf="${myconf} --with-gnutls-includes=/usr/include/gnutls"
myconf="${myconf} --with-gnutls-libs=/usr/$(get_libdir)"
else
einfo "Disabling GnuTLS, using NSS"
myconf="${myconf} --enable-gnutls=no --enable-nss=yes"
fi
if ! use ncurses && ! use gtk; then
myconf="${myconf} --enable-consoleui --disable-gtkui"
else
myconf="${myconf} $(use_enable ncurses consoleui) $(use_enable gtk gtkui)"
fi
econf \
$(use_enable nls) \
$(use_enable perl) \
$(use_enable gtk startup-notification) \
$(use_enable gtk screensaver) \
$(use_enable gtk sm) \
$(use_enable tcl) \
$(use_enable spell gtkspell) \
$(use_enable tk) \
$(use_enable debug) \
$(use_enable dbus) \
$(use_enable meanwhile) \
$(use_enable eds gevolution) \
$(use_enable gstreamer) \
$(use_enable sasl cyrus-sasl ) \
$(use_enable doc doxygen) \
$(use_enable prediction cap) \
$(use_enable networkmanager nm) \
$(use_with zephyr krb4) \
"--with-dynamic-prpls=${DYNAMIC_PRPLS}" \
--disable-mono \
--x-includes=/usr/include/X11 \
${myconf} || die "Configuration failed"
#$(use_enable mono) \
emake || die "make failed"
}
src_install() {
gnome2_src_install
use perl && fixlocalpod
dodoc AUTHORS COPYING HACKING INSTALL NEWS README ChangeLog
}
pkg_postinst() {
gnome2_pkg_postinst
print_pidgin_warning
}
--
gentoo-commits@gentoo.org mailing list
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-im/pidgin: ChangeLog pidgin-2.2.0.ebuild
@ 2007-09-16 18:51 Olivier Crete (tester)
0 siblings, 0 replies; 2+ messages in thread
From: Olivier Crete (tester) @ 2007-09-16 18:51 UTC (permalink / raw
To: gentoo-commits
tester 07/09/16 18:51:47
Modified: ChangeLog pidgin-2.2.0.ebuild
Log:
Add MyspaceIM, fixes bug #192713
(Portage version: 2.1.3.9)
Revision Changes Path
1.30 net-im/pidgin/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/ChangeLog?r1=1.29&r2=1.30
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog 16 Sep 2007 14:00:59 -0000 1.29
+++ ChangeLog 16 Sep 2007 18:51:46 -0000 1.30
@@ -1,6 +1,9 @@
# ChangeLog for net-im/pidgin
# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.29 2007/09/16 14:00:59 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/ChangeLog,v 1.30 2007/09/16 18:51:46 tester Exp $
+
+ 16 Sep 2007; Olivier Crête <tester@gentoo.org> pidgin-2.2.0.ebuild:
+ Add MyspaceIM, fixes bug #192713
*pidgin-2.2.0 (16 Sep 2007)
1.2 net-im/pidgin/pidgin-2.2.0.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild?r1=1.1&r2=1.2
Index: pidgin-2.2.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- pidgin-2.2.0.ebuild 16 Sep 2007 14:00:59 -0000 1.1
+++ pidgin-2.2.0.ebuild 16 Sep 2007 18:51:46 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild,v 1.1 2007/09/16 14:00:59 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/pidgin/pidgin-2.2.0.ebuild,v 1.2 2007/09/16 18:51:46 tester Exp $
WANT_AUTOMAKE=1.9
@@ -58,7 +58,7 @@
S="${WORKDIR}/${MY_PV}"
# Enable Default protocols
-DYNAMIC_PRPLS="irc,jabber,oscar,yahoo,zephyr,simple,msn"
+DYNAMIC_PRPLS="irc,jabber,oscar,yahoo,zephyr,simple,msn,myspace"
# List of plugins yet to be ported (will be removed at some point)
# net-im/gaim-bnet
--
gentoo-commits@gentoo.org mailing list
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2007-09-16 18:59 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2007-09-16 18:51 [gentoo-commits] gentoo-x86 commit in net-im/pidgin: ChangeLog pidgin-2.2.0.ebuild Olivier Crete (tester)
-- strict thread matches above, loose matches on Subject: below --
2007-09-16 14:00 Olivier Crete (tester)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox