* [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.2.0.ebuild
@ 2010-02-26 20:08 99% Michael Sterrett (mr_bones_)
0 siblings, 0 replies; 1+ results
From: Michael Sterrett (mr_bones_) @ 2010-02-26 20:08 UTC (permalink / raw
To: gentoo-commits
mr_bones_ 10/02/26 20:08:38
Modified: ChangeLog
Added: freeciv-2.2.0.ebuild
Log:
version bump
(Portage version: 2.1.7.16/cvs/Linux i686)
Revision Changes Path
1.99 games-strategy/freeciv/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freeciv/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freeciv/ChangeLog?r1=1.98&r2=1.99
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog 9 Feb 2010 05:51:43 -0000 1.98
+++ ChangeLog 26 Feb 2010 20:08:38 -0000 1.99
@@ -1,6 +1,12 @@
# ChangeLog for games-strategy/freeciv
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.98 2010/02/09 05:51:43 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/ChangeLog,v 1.99 2010/02/26 20:08:38 mr_bones_ Exp $
+
+*freeciv-2.2.0 (26 Feb 2010)
+
+ 26 Feb 2010; Michael Sterrett <mr_bones_@gentoo.org>
+ +freeciv-2.2.0.ebuild, +files/freeciv-2.2.0-clean-man.patch:
+ version bump
09 Feb 2010; Michael Sterrett <mr_bones_@gentoo.org>
freeciv-2.1.11.ebuild:
1.1 games-strategy/freeciv/freeciv-2.2.0.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freeciv/freeciv-2.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freeciv/freeciv-2.2.0.ebuild?rev=1.1&content-type=text/plain
Index: freeciv-2.2.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freeciv/freeciv-2.2.0.ebuild,v 1.1 2010/02/26 20:08:38 mr_bones_ Exp $
EAPI=2
inherit eutils gnome2-utils games
DESCRIPTION="multiplayer strategy game (Civilization Clone)"
HOMEPAGE="http://www.freeciv.org/"
SRC_URI="mirror://sourceforge/freeciv/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="auth dedicated ggz gtk nls readline sdl"
RDEPEND="readline? ( sys-libs/readline )
sys-libs/zlib
app-arch/bzip2
!dedicated? (
nls? ( virtual/libintl )
gtk? ( x11-libs/gtk+:2 )
sdl? (
media-libs/libsdl[audio,video]
media-libs/sdl-image[png]
media-libs/freetype
media-libs/sdl-mixer
)
!gtk? ( !sdl? ( x11-libs/gtk+:2 ) )
ggz? ( dev-games/ggz-client-libs )
media-libs/libpng
auth? ( virtual/mysql )
)"
DEPEND="${RDEPEND}
dev-util/pkgconfig
!dedicated? (
nls? ( sys-devel/gettext )
x11-proto/xextproto
)"
src_prepare() {
# install the .desktop in /usr/share/applications
# install the icons in /usr/share/pixmaps
sed -i \
-e 's:^\(desktopfiledir = \).*:\1/usr/share/applications:' \
-e 's:^\(icon[0-9]*dir = \)$(prefix)\(.*\):\1/usr\2:' \
-e 's:^\(icon[0-9]*dir = \)$(datadir)\(.*\):\1/usr/share\2:' \
client/Makefile.in \
server/Makefile.in \
data/Makefile.in \
data/icons/Makefile.in \
|| die "sed failed"
# remove civclient manpage if dedicated server
if use dedicated ; then
epatch "${FILESDIR}"/${P}-clean-man.patch
fi
}
src_configure() {
local myclient="gtk" # default to gtk if none specified
if use dedicated ; then
myclient="no"
else
use sdl && myclient="${myclient} sdl"
fi
egamesconf \
--disable-dependency-tracking \
--localedir=/usr/share/locale \
$(use_enable auth) \
$(use_enable nls) \
$(use_with readline) \
$(use_enable sdl sdl-mixer) \
$(use_with ggz ggz-client) \
--enable-client="${myclient}"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
if ! use dedicated ; then
# Create and install the html manual. It can't be done for dedicated
# servers, because the 'civmanual' tool is then not built. Also
# delete civmanual from the GAMES_BINDIR, because it's then useless.
# Note: to have it localized, it should be ran from _postinst, or
# something like that, but then it's a PITA to avoid orphan files...
./manual/civmanual || die "civmanual failed"
dohtml manual*.html || die "dohtml failed"
rm -f "${D}/${GAMES_BINDIR}"/civmanual
use sdl && make_desktop_entry freeciv-sdl "Freeciv (SDL)" freeciv-client
fi
dodoc ChangeLog NEWS doc/{BUGS,CodingStyle,HACKING,HOWTOPLAY,README*,TODO}
prepgamesdirs
}
pkg_preinst() {
games_pkg_preinst
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
gnome2_icon_cache_update
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [relevance 99%]
Results 1-1 of 1 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2010-02-26 20:08 99% [gentoo-commits] gentoo-x86 commit in games-strategy/freeciv: ChangeLog freeciv-2.2.0.ebuild Michael Sterrett (mr_bones_)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox