* [gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: ChangeLog freeipmi-1.0.1.ebuild freeipmi-0.6.10.ebuild
@ 2011-01-31 17:46 99% Diego Petteno (flameeyes)
0 siblings, 0 replies; 1+ results
From: Diego Petteno (flameeyes) @ 2011-01-31 17:46 UTC (permalink / raw
To: gentoo-commits
flameeyes 11/01/31 17:46:49
Modified: ChangeLog
Added: freeipmi-1.0.1.ebuild
Removed: freeipmi-0.6.10.ebuild
Log:
Version bump, remove old version and patch. Thanks to Christian (idl0r) in bug #353327.
(Portage version: 2.2.0_alpha19/cvs/Linux x86_64)
Revision Changes Path
1.30 sys-libs/freeipmi/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?r1=1.29&r2=1.30
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog 5 Oct 2010 19:52:13 -0000 1.29
+++ ChangeLog 31 Jan 2011 17:46:49 -0000 1.30
@@ -1,6 +1,14 @@
# ChangeLog for sys-libs/freeipmi
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.29 2010/10/05 19:52:13 maekke Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.30 2011/01/31 17:46:49 flameeyes Exp $
+
+*freeipmi-1.0.1 (31 Jan 2011)
+
+ 31 Jan 2011; Diego E. Pettenò <flameeyes@gentoo.org>
+ -freeipmi-0.6.10.ebuild, -files/freeipmi-0.6.10+glibc-2.8.patch,
+ +freeipmi-1.0.1.ebuild:
+ Version bump, remove old version and patch. Thanks to Christian (idl0r) in
+ bug #353327.
05 Oct 2010; Markus Meier <maekke@gentoo.org> freeipmi-0.8.9.ebuild:
x86 stable, bug #339140
1.1 sys-libs/freeipmi/freeipmi-1.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.1.ebuild?rev=1.1&content-type=text/plain
Index: freeipmi-1.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.1.ebuild,v 1.1 2011/01/31 17:46:49 flameeyes Exp $
EAPI=2
inherit autotools
DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
HOMEPAGE="http://www.gnu.org/software/freeipmi/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz
http://ftp.gluster.com/pub/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"
RDEPEND="dev-libs/libgcrypt"
DEPEND="${RDEPEND}
virtual/os-headers"
src_prepare() {
# Fix build mistake, only causes warnings but at least stop it.
sed -i -e '/-module/d' "${S}"/libfreeipmi/src/Makefile.am || die
AT_M4DIR="config" eautoreconf
}
src_configure() {
econf \
$(use_enable debug) \
--disable-dependency-tracking \
--enable-fast-install \
--disable-static \
--disable-init-scripts \
--enable-logrotate-config \
--localstatedir=/var
}
# There are no tests
src_test() { :; }
src_install() {
emake DESTDIR="${D}" docdir="/usr/share/doc/${PF}" install || die "emake install failed"
find "${D}" -name '*.la' -delete
# freeipmi by defaults install _all_ commands to /usr/sbin, but
# quite a few can be run remotely as standard user, so move them
# in /usr/bin afterwards.
dodir /usr/bin
for file in ipmi{detect,ping,power,console}; do
mv "${D}"/usr/{s,}bin/${file} || die
# The default install symlinks these commands to add a dash
# after the ipmi prefix; we repeat those after move for
# consistency.
rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
dosym ${file} /usr/bin/${file/ipmi/ipmi-}
done
dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt || die
keepdir \
/var/cache/ipmimonitoringsdrcache \
/var/lib/freeipmi \
/var/log/{freeipmi,ipmiconsole}
newinitd "${FILESDIR}/ipmidetectd.initd" ipmidetectd
newinitd "${FILESDIR}/bmc-watchdog.initd" bmc-watchdog
newconfd "${FILESDIR}/bmc-watchdog.confd" bmc-watchdog
}
^ permalink raw reply [relevance 99%]
Results 1-1 of 1 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2011-01-31 17:46 99% [gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: ChangeLog freeipmi-1.0.1.ebuild freeipmi-0.6.10.ebuild Diego Petteno (flameeyes)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox