* [gentoo-commits] gentoo-x86 commit in media-gfx/imagemagick: ChangeLog imagemagick-6.7.5.0.ebuild
@ 2012-01-30 12:50 99% Samuli Suominen (ssuominen)
0 siblings, 0 replies; 1+ results
From: Samuli Suominen (ssuominen) @ 2012-01-30 12:50 UTC (permalink / raw
To: gentoo-commits
ssuominen 12/01/30 12:50:48
Modified: ChangeLog
Added: imagemagick-6.7.5.0.ebuild
Log:
Version bump to fix building with sys-libs/zlib >= 1.2.5.2 wrt #401499 by Juergen Rose
(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
Revision Changes Path
1.457 media-gfx/imagemagick/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/imagemagick/ChangeLog?rev=1.457&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/imagemagick/ChangeLog?rev=1.457&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/imagemagick/ChangeLog?r1=1.456&r2=1.457
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v
retrieving revision 1.456
retrieving revision 1.457
diff -u -r1.456 -r1.457
--- ChangeLog 28 Jan 2012 03:44:36 -0000 1.456
+++ ChangeLog 30 Jan 2012 12:50:47 -0000 1.457
@@ -1,6 +1,13 @@
# ChangeLog for media-gfx/imagemagick
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.456 2012/01/28 03:44:36 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.457 2012/01/30 12:50:47 ssuominen Exp $
+
+*imagemagick-6.7.5.0 (30 Jan 2012)
+
+ 30 Jan 2012; Samuli Suominen <ssuominen@gentoo.org>
+ +imagemagick-6.7.5.0.ebuild:
+ Version bump to fix building with sys-libs/zlib >= 1.2.5.2 wrt #401499 by
+ Juergen Rose
28 Jan 2012; Samuli Suominen <ssuominen@gentoo.org>
imagemagick-6.7.4.10.ebuild:
1.1 media-gfx/imagemagick/imagemagick-6.7.5.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/imagemagick/imagemagick-6.7.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/imagemagick/imagemagick-6.7.5.0.ebuild?rev=1.1&content-type=text/plain
Index: imagemagick-6.7.5.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/imagemagick-6.7.5.0.ebuild,v 1.1 2012/01/30 12:50:47 ssuominen Exp $
EAPI=4
inherit multilib toolchain-funcs versionator
MY_P=ImageMagick-$(replace_version_separator 3 '-')
DESCRIPTION="A collection of tools and libraries for many image formats"
HOMEPAGE="http://www.imagemagick.org/"
SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
LICENSE="imagemagick"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz gs hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
RDEPEND=">=sys-devel/libtool-2.2.6b
autotrace? ( >=media-gfx/autotrace-0.31.1 )
bzip2? ( app-arch/bzip2 )
corefonts? ( media-fonts/corefonts )
djvu? ( app-text/djvu )
fftw? ( sci-libs/fftw:3.0 )
fontconfig? ( media-libs/fontconfig )
fpx? ( >=media-libs/libfpx-1.3.0-r1 )
graphviz? ( >=media-gfx/graphviz-2.6 )
gs? ( app-text/ghostscript-gpl )
jbig? ( media-libs/jbigkit )
jpeg? ( virtual/jpeg )
jpeg2k? ( media-libs/jasper )
lcms? ( media-libs/lcms:2 )
lqr? ( >=media-libs/liblqr-0.1.0 )
opencl? ( virtual/opencl )
openexr? ( media-libs/openexr )
pango? ( x11-libs/pango )
perl? ( >=dev-lang/perl-5.8.6-r6 )
png? ( media-libs/libpng:0 )
raw? ( media-gfx/ufraw )
svg? ( >=gnome-base/librsvg-2.9.0 )
tiff? ( media-libs/tiff:0 )
truetype? ( media-libs/freetype:2 )
webp? ( media-libs/libwebp )
wmf? ( >=media-libs/libwmf-0.2.8 )
X? (
x11-libs/libXext
x11-libs/libXt
x11-libs/libICE
x11-libs/libSM
)
xml? ( >=dev-libs/libxml2-2.4.10 )
lzma? ( app-arch/xz-utils )
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
!media-gfx/graphicsmagick[imagemagick]
app-arch/xz-utils
dev-util/pkgconfig
>=sys-apps/sed-4
X? ( x11-proto/xextproto )"
REQUIRED_USE="corefonts? ( truetype )
test? ( corefonts )"
S=${WORKDIR}/${MY_P}
RESTRICT="perl? ( userpriv )"
DOCS="AUTHORS.txt ChangeLog NEWS.txt README.txt"
src_configure() {
local depth=16
use q8 && depth=8
use q32 && depth=32
use q64 && depth=64
local openmp=disable
if use openmp && tc-has-openmp; then
openmp=enable
fi
econf \
--docdir="${EPREFIX}/usr/share/doc/${PF}" \
$(use_enable static-libs static) \
$(use_enable hdri) \
$(use_enable opencl) \
--with-threads \
--without-included-ltdl \
--with-ltdl-include="${EPREFIX}/usr/include" \
--with-ltdl-lib="${EPREFIX}/usr/$(get_libdir)" \
--with-modules \
--with-quantum-depth=${depth} \
$(use_with cxx magick-plus-plus) \
$(use_with perl) \
--with-perl-options='INSTALLDIRS=vendor' \
--with-gs-font-dir="${EPREFIX}/usr/share/fonts/default/ghostscript" \
$(use_with bzip2 bzlib) \
$(use_with X x) \
$(use_with zlib) \
$(use_with autotrace) \
$(use_with gs dps) \
$(use_with djvu) \
--with-dejavu-font-dir="${EPREFIX}/usr/share/fonts/dejavu" \
$(use_with fftw) \
$(use_with fpx) \
$(use_with fontconfig) \
$(use_with truetype freetype) \
$(use_with gs gslib) \
$(use_with graphviz gvc) \
$(use_with jbig) \
$(use_with jpeg) \
$(use_with jpeg2k jp2) \
--without-lcms \
$(use_with lcms lcms2) \
$(use_with lqr) \
$(use_with lzma) \
$(use_with openexr) \
$(use_with pango) \
$(use_with png) \
$(use_with svg rsvg) \
$(use_with tiff) \
$(use_with webp) \
$(use_with corefonts windows-font-dir /usr/share/fonts/corefonts) \
$(use_with wmf) \
$(use_with xml) \
--${openmp}-openmp
}
src_test() {
has_version media-gfx/imagemagick || emake -j1 check
}
src_install() {
default
if use perl; then
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
fi
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}
^ permalink raw reply [relevance 99%]
Results 1-1 of 1 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2012-01-30 12:50 99% [gentoo-commits] gentoo-x86 commit in media-gfx/imagemagick: ChangeLog imagemagick-6.7.5.0.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox