* [gentoo-commits] repo/gentoo:master commit in: media-sound/mp3blaster/
@ 2017-11-29 23:19 99% Andreas Sturmlechner
0 siblings, 0 replies; 1+ results
From: Andreas Sturmlechner @ 2017-11-29 23:19 UTC (permalink / raw
To: gentoo-commits
commit: be5254d5e9e693c7e02a78cc81d78c978d10a5bf
Author: Rolf Eike Beer <eike <AT> sf-mail <DOT> de>
AuthorDate: Tue Nov 28 20:06:31 2017 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Nov 29 23:19:19 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=be5254d5
media-sound/mp3blaster: remove old
Closes: https://github.com/gentoo/gentoo/pull/6339
media-sound/mp3blaster/Manifest | 2 -
media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild | 61 --------------------
media-sound/mp3blaster/mp3blaster-3.2.5-r2.ebuild | 69 -----------------------
3 files changed, 132 deletions(-)
diff --git a/media-sound/mp3blaster/Manifest b/media-sound/mp3blaster/Manifest
index 2af8e90fb18..0a4f8e3a6f7 100644
--- a/media-sound/mp3blaster/Manifest
+++ b/media-sound/mp3blaster/Manifest
@@ -1,3 +1 @@
-DIST mp3blaster-3.2.5.tar.gz 329407 SHA256 129115742c77362cc3508eb7782702cfb44af2463a5453e8d19ea68abccedc29 SHA512 53f623340b7a8e4be6cd973474fd5f23c623b6d1c667478dc0d4c7a1ef5758f4bbc09d9d0698d1539d8d1c3ef45301b447f3ed74f68586070a07a7f9fa8c353e WHIRLPOOL 96cdc3b6436dec282a5836c00e2151dd04f218175fdd2451fcfd45f70bced05dea0c8915cf1a817d24a9961fc8ab3d9c5b568a5ae67e23e2b1915604b2d7806e
DIST mp3blaster-3.2.6.tar.gz 354019 SHA256 43d9f656367d16aaac163f93dc323e9843c3dd565401567edef3e1e72b9e1ee0 SHA512 eb977eb46b86449c6d433b1740aa08580e5b8f3d55d82d6f2623cd5fd103d73b7df127fb9ac650a21da61ad4948eb569a812e15d9adc9424d491fa625e198e0d WHIRLPOOL d617d9cf9dccd01cda71f31806ad9b5f4a02d94df29befb3d37408e9831c8883c8501050d453f242fe27066b6af47d0fb68242070217f781ca03cb19b3afbe2a
-DIST mp3blaster_3.2.5-3.debian.tar.gz 11000 SHA256 e4d424aeccde6ccd219270f4e4f0bf8f70b97e13075447b6d6d069110ed092c9 SHA512 1d899c85c2a2e1326fac0f87c61ead82273a08c672aeab0929479d9aa10c6ae703bb63c1a6aec14c8f5b6a139089fa5228cf09db72ea5b114efb60a196bd4788 WHIRLPOOL 9c1c99d5a4f4e5060a9eae4e681f0df841d6932f34a12102a82d2e1f795d4db41fd3f15d6aa6a34d04d42259d73ba67f775b24a51df30779d4f4466ded40f69f
diff --git a/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild b/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild
deleted file mode 100644
index 72aa2ae0f69..00000000000
--- a/media-sound/mp3blaster/mp3blaster-3.2.5-r1.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=4
-inherit eutils
-
-DESCRIPTION="Text console based program for playing audio files"
-HOMEPAGE="http://mp3blaster.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
- mirror://debian/pool/main/m/${PN}/${PN}_${PV}-3.debian.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="alpha amd64 arm ppc ppc64 sparc x86 ~x86-fbsd"
-IUSE="lirc oss sdl sid vorbis"
-
-RDEPEND=">=sys-libs/ncurses-5.7-r7
- lirc? ( app-misc/lirc )
- sdl? ( media-libs/libsdl )
- sid? ( =media-libs/libsidplay-1* )
- vorbis? ( >=media-libs/libvorbis-1 )"
-DEPEND="${RDEPEND}
- x11-misc/imake
- oss? ( virtual/os-headers )"
-
-REQUIRED_USE="|| ( oss sdl )"
-
-DOCS="AUTHORS BUGS ChangeLog CREDITS FAQ NEWS README TODO"
-
-src_prepare() {
- EPATCH_SOURCE=${WORKDIR}/debian/patches EPATCH_SUFFIX=patch EPATCH_FORCE=yes epatch
- # file collision with media-sound/splay
- sed -i -e 's:splay.1:splay_mp3blaster.1:' Makefile.in || die
- mv -vf splay{,_mp3blaster}.1 || die
-}
-
-src_configure() {
- # libpth and newthreads support are both broken
- econf \
- --disable-newthreads \
- --without-pth \
- --without-nas \
- $(use_with lirc) \
- $(use_with vorbis oggvorbis) \
- $(use_with sid sidplay) \
- --without-esd \
- $(use_with sdl) \
- $(use_with oss)
-}
-
-src_install() {
- default
-
- doman "${WORKDIR}"/debian/manpages/mp3tag.1
-
- # relocate everything except commands.txt because it's used by src/main.cc
- mv -vf "${ED}"usr/share/${PN}/{charmap,sample.*} "${ED}"usr/share/doc/${PF} || die
-
- # file collision with media-sound/splay
- mv -vf "${ED}"usr/bin/splay{,_mp3blaster} || die
-}
diff --git a/media-sound/mp3blaster/mp3blaster-3.2.5-r2.ebuild b/media-sound/mp3blaster/mp3blaster-3.2.5-r2.ebuild
deleted file mode 100644
index d4545c71cb4..00000000000
--- a/media-sound/mp3blaster/mp3blaster-3.2.5-r2.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools
-
-DESCRIPTION="Text console based program for playing audio files"
-HOMEPAGE="http://mp3blaster.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
- mirror://debian/pool/main/m/${PN}/${PN}_${PV}-3.debian.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="lirc oss +sdl sid vorbis"
-
-RDEPEND="
- sys-libs/ncurses:0=
- lirc? ( app-misc/lirc )
- sdl? ( media-libs/libsdl )
- sid? ( media-libs/libsidplay:1 )
- vorbis? ( media-libs/libvorbis )"
-DEPEND="${RDEPEND}
- x11-misc/imake
- oss? ( virtual/os-headers )"
-
-REQUIRED_USE="|| ( oss sdl )"
-
-PATCHES=(
- "${WORKDIR}"/debian/patches
- "${FILESDIR}"/${PN}-3.2.5-fix-c++14.patch
- "${FILESDIR}"/${PN}-3.2.5-fix-build-system.patch
-)
-
-src_prepare() {
- default
- eautoreconf
-
- # file collision with media-sound/splay
- sed -i -e 's:splay.1:splay_mp3blaster.1:' Makefile.in || die
- mv -vf splay{,_mp3blaster}.1 || die
-}
-
-src_configure() {
- # libpth and newthreads support are both broken
- econf \
- --disable-newthreads \
- --without-pth \
- --without-nas \
- $(use_with lirc) \
- $(use_with vorbis oggvorbis) \
- $(use_with sid sidplay) \
- --without-esd \
- $(use_with sdl) \
- $(use_with oss)
-}
-
-src_install() {
- default
-
- doman "${WORKDIR}"/debian/manpages/mp3tag.1
-
- # relocate everything except commands.txt because it's used by src/main.cc
- mv -vf "${ED%/}"/usr/share/{${PN}/{charmap,sample.*},doc/${PF}} || die
-
- # file collision with media-sound/splay
- mv -vf "${ED%/}"/usr/bin/splay{,_mp3blaster} || die
-}
^ permalink raw reply related [relevance 99%]
Results 1-1 of 1 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2017-11-29 23:19 99% [gentoo-commits] repo/gentoo:master commit in: media-sound/mp3blaster/ Andreas Sturmlechner
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox