* [gentoo-commits] repo/gentoo:master commit in: media-gfx/optipng/
@ 2020-01-28 15:29 99% Sebastian Pipping
0 siblings, 0 replies; 1+ results
From: Sebastian Pipping @ 2020-01-28 15:29 UTC (permalink / raw
To: gentoo-commits
commit: ac427444d5deb09bb73cc5c6896f543c90b5f95e
Author: Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 28 15:28:25 2020 +0000
Commit: Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue Jan 28 15:29:42 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac427444
media-gfx/optipng: EAPI 7
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.84, Repoman-2.3.20
media-gfx/optipng/optipng-0.7.7-r1.ebuild | 60 +++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/media-gfx/optipng/optipng-0.7.7-r1.ebuild b/media-gfx/optipng/optipng-0.7.7-r1.ebuild
new file mode 100644
index 00000000000..11a75013d0a
--- /dev/null
+++ b/media-gfx/optipng/optipng-0.7.7-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Compress PNG files without affecting image quality"
+HOMEPAGE="http://optipng.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE=""
+
+RDEPEND="sys-libs/zlib
+ media-libs/libpng:0="
+DEPEND="${RDEPEND}
+ sys-apps/findutils"
+
+DOCS=( AUTHORS.txt README.txt )
+
+src_prepare() {
+ rm -R src/{libpng,zlib} || die
+ find . -type d -name build -exec rm -R {} + || die
+
+ # next release is almost a complete rewrite, so plug this compilation
+ # problem in anticipation of the much (c)leaner(?) rewrite
+ sed -i \
+ -e 's/^#if defined AT_FDCWD/#if (defined(AT_FDCWD) \&\& !(defined(__SVR4) \&\& defined(__sun)))/' \
+ src/optipng/ioutil.c || die
+
+ tc-export CC AR RANLIB
+ export LD=$(tc-getCC)
+
+ eapply_user
+}
+
+src_configure() {
+ ./configure \
+ -with-system-libpng \
+ -with-system-zlib \
+ || die "configure failed"
+}
+
+src_compile() {
+ emake -C src/optipng
+}
+
+src_install() {
+ einstalldocs
+
+ dodoc doc/*.txt
+ docinto html
+ dodoc doc/*.html
+ doman src/${PN}/man/${PN}.1
+
+ dobin src/${PN}/${PN}
+}
^ permalink raw reply related [relevance 99%]
Results 1-1 of 1 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2020-01-28 15:29 99% [gentoo-commits] repo/gentoo:master commit in: media-gfx/optipng/ Sebastian Pipping
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox