[gentoo-commits] proj/gnome:master commit in: gnome-base/gnome-extra-apps/, gnome-base/gnome-applets/, ...

[gentoo-commits] proj/gnome:master commit in: gnome-base/gnome-extra-apps/, gnome-base/gnome-applets/, ...

[Alexandre Restovtsev]

commit:     7af56af62fbd27b4a45b8f588e002bde296fdf13
Author:     Alexandre Rostovtsev <tetromino <AT> gmail <DOT> com>
AuthorDate: Sun Jun 19 01:57:33 2011 +0000
Commit:     Alexandre Restovtsev <tetromino <AT> gmail <DOT> com>
CommitDate: Sun Jun 19 09:38:21 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=7af56af6

gnome-extra/gucharmap: slot gtk3 version to 2.90 (bug #362035)

gnome-extra/gucharmap installs a library that is used by several
packages to display a unicode character picker tool. Some of these
packages - such as abiword, bluefish, and libtomoe-gtk - are unlikely to
be ported to gtk3 in the immediate future. It is therefore desirable to
be able to install the gtk2 version of the gucharmap library in
parallel with the gtk3-based one.

The solution is to slot the gtk2 version to "0" and the gtk3 version to
"2.90". Both versions can be built from the same 3.0.x source via the
appropriate --with-gtk configure option. If we ensure that only one of
the slots (2.90, naturally) installs the gucharmap program and
associated .desktop file and schemas, and rename slot 2.90's gettext
domain, there will be no file collisions.

This partially addresses bug #362035.

v2:
Mgorny on IRC pointed out that my original slotmove command would have
moved gucharmap-3.0.1-r200 to slot 2.90 the next time updates/2Q-2011
changed. So instead, explicitly list all versions of gucharmap for gtk3
that have ever been in the overlay.

---
 .../gedit-plugins/gedit-plugins-3.0.4.ebuild       |    2 +-
 gnome-base/gnome-applets/gnome-applets-9999.ebuild |    2 +-
 .../gnome-extra-apps/gnome-extra-apps-3.0.0.ebuild |    2 +-
 gnome-extra/gucharmap/gucharmap-3.0.1-r200.ebuild  |   62 ++++++++++++++++++++
 ...ap-3.0.1.ebuild => gucharmap-3.0.1-r300.ebuild} |   24 +++++--
 profiles/updates/2Q-2011                           |    3 +
 6 files changed, 85 insertions(+), 10 deletions(-)

diff --git a/app-editors/gedit-plugins/gedit-plugins-3.0.4.ebuild b/app-editors/gedit-plugins/gedit-plugins-3.0.4.ebuild
index 2c57407..5fa9eba 100644
--- a/app-editors/gedit-plugins/gedit-plugins-3.0.4.ebuild
+++ b/app-editors/gedit-plugins/gedit-plugins-3.0.4.ebuild
@@ -34,7 +34,7 @@ RDEPEND=">=app-editors/gedit-3.0.0[python?]
 		x11-libs/pango[introspection]
 		x11-libs/gdk-pixbuf:2[introspection]
 	)
-	charmap? ( >=gnome-extra/gucharmap-3.0.0[introspection] )
+	charmap? ( >=gnome-extra/gucharmap-3.0.0:2.90[introspection] )
 	synctex? ( >=dev-python/dbus-python-0.82 )
 	terminal? ( x11-libs/vte:2.90[introspection] )"
 DEPEND="${RDEPEND}

diff --git a/gnome-base/gnome-applets/gnome-applets-9999.ebuild b/gnome-base/gnome-applets/gnome-applets-9999.ebuild
index e44d64b..0712c20 100644
--- a/gnome-base/gnome-applets/gnome-applets-9999.ebuild
+++ b/gnome-base/gnome-applets/gnome-applets-9999.ebuild
@@ -46,7 +46,7 @@ RDEPEND=">=x11-libs/gtk+-3.0.0:3
 		gnome-base/gnome-settings-daemon
 		gnome-base/libgnome
 
-		>=gnome-extra/gucharmap-2.33.0
+		>=gnome-extra/gucharmap-2.33.0:2.90
 		>=gnome-base/libgtop-2.11.92 )
 	gstreamer?	(
 		>=media-libs/gstreamer-0.10.2

diff --git a/gnome-base/gnome-extra-apps/gnome-extra-apps-3.0.0.ebuild b/gnome-base/gnome-extra-apps/gnome-extra-apps-3.0.0.ebuild
index af463db..c3c10fb 100644
--- a/gnome-base/gnome-extra-apps/gnome-extra-apps-3.0.0.ebuild
+++ b/gnome-base/gnome-extra-apps/gnome-extra-apps-3.0.0.ebuild
@@ -28,7 +28,7 @@ RDEPEND="
 	>=gnome-extra/gnome-system-monitor-${PV}
 	>=gnome-extra/gnome-tweak-tool-${PV}
 	>=gnome-extra/gnome-utils-${PV}
-	>=gnome-extra/gucharmap-${PV}
+	>=gnome-extra/gucharmap-${PV}:2.90
 	>=mail-client/evolution-${PV}
 	>=media-sound/sound-juicer-2.99
 	>=media-video/cheese-${PV}

diff --git a/gnome-extra/gucharmap/gucharmap-3.0.1-r200.ebuild b/gnome-extra/gucharmap/gucharmap-3.0.1-r200.ebuild
new file mode 100644
index 0000000..b718b9c
--- /dev/null
+++ b/gnome-extra/gucharmap/gucharmap-3.0.1-r200.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/gucharmap-2.32.1.ebuild,v 1.1 2010/11/19 21:53:00 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Unicode character map viewer library"
+HOMEPAGE="http://live.gnome.org/Gucharmap"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="cjk doc +introspection"
+
+RDEPEND=">=dev-libs/glib-2.16.3[introspection?]
+	>=x11-libs/pango-1.2.1[introspection?]
+	>=x11-libs/gtk+-2.14.0:2[introspection?]
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40
+
+	sys-devel/gettext
+
+	doc? ( >=dev-util/gtk-doc-1.0 )"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-static
+		--disable-scrollkeeper
+		--disable-maintainer-mode
+		--with-gtk=2.0
+		--disable-charmap
+		--disable-gconf
+		$(use_enable introspection)
+		$(use_enable cjk unihan)"
+	# gconf is only needed for the gucharmap program
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+}
+
+src_prepare() {
+	# .desktop and schema files are only needed for the gucharmap program
+	sed -e 's:desktop_DATA\s*=.*:desktop_DATA = :' \
+		-e 's:schema_DATA\s*=.*:schema_DATA = :' \
+		-i Makefile.* || die "sed Makefile.* failed"
+
+	gnome2_src_prepare
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if ! has_version "gnome-extra/gucharmap:2.90" ; then
+		ewarn "Note: ${PF} includes only the gucharmap-2 library."
+		ewarn "If you need the gucharmap program, emerge gucharmap:2.90"
+	fi
+}

diff --git a/gnome-extra/gucharmap/gucharmap-3.0.1.ebuild b/gnome-extra/gucharmap/gucharmap-3.0.1-r300.ebuild
similarity index 64%
rename from gnome-extra/gucharmap/gucharmap-3.0.1.ebuild
rename to gnome-extra/gucharmap/gucharmap-3.0.1-r300.ebuild
index b93d93d..bccb8df 100644
--- a/gnome-extra/gucharmap/gucharmap-3.0.1.ebuild
+++ b/gnome-extra/gucharmap/gucharmap-3.0.1-r300.ebuild
@@ -8,20 +8,22 @@ GNOME2_LA_PUNT="yes"
 
 inherit gnome2
 
-DESCRIPTION="Unicode character map viewer"
+DESCRIPTION="Unicode character map viewer and library"
 HOMEPAGE="http://live.gnome.org/Gucharmap"
 
-LICENSE="GPL-2 LGPL-2.1"
-SLOT="0"
+LICENSE="GPL-3"
+SLOT="2.90"
 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
 IUSE="cjk doc gnome +introspection test"
 
-RDEPEND=">=dev-libs/glib-2.16.3
-	>=x11-libs/pango-1.2.1
-	>=x11-libs/gtk+-3.0.0:3
+COMMON_DEPEND=">=dev-libs/glib-2.16.3[introspection?]
+	>=x11-libs/pango-1.2.1[introspection?]
+	>=x11-libs/gtk+-3.0.0:3[introspection?]
 
 	gnome? ( gnome-base/gconf:2 )
 	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+RDEPEND="${COMMON_DEPEND}
+	!!<gnome-extra/gucharmap-3:0"
 DEPEND="${RDEPEND}
 	app-text/scrollkeeper
 	>=dev-util/pkgconfig-0.9
@@ -42,5 +44,13 @@ pkg_setup() {
 		$(use_enable gnome gconf)
 		$(use_enable introspection)
 		$(use_enable cjk unihan)"
-	DOCS="ChangeLog NEWS README TODO"
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+}
+
+src_prepare() {
+	# prevent file collisions with slot 0
+	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	gnome2_src_prepare
 }

diff --git a/profiles/updates/2Q-2011 b/profiles/updates/2Q-2011
index fbfd3ba..2b5cd76 100644
--- a/profiles/updates/2Q-2011
+++ b/profiles/updates/2Q-2011
@@ -1 +1,4 @@
 slotmove =net-libs/rest-0.7* 0 0.7
+slotmove =gnome-extra/gucharmap-2.33.2 0 2.90
+slotmove =gnome-extra/gucharmap-3.0.0 0 2.90
+slotmove =gnome-extra/gucharmap-3.0.1 0 2.90