From: "Alexandre Restovtsev" <tetromino@gmail.com>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] proj/gnome:gnome-next commit in: gnome-extra/gnome-shell-extensions/
Date: Fri, 12 Aug 2011 08:29:56 +0000 (UTC) [thread overview]
Message-ID: <4cc7c1ddb7578b33ecaa12f6c8b81e84845d57dd.tetromino@gentoo> (raw)
commit: 4cc7c1ddb7578b33ecaa12f6c8b81e84845d57dd
Author: Alexandre Rostovtsev <tetromino <AT> gmail <DOT> com>
AuthorDate: Thu Aug 11 03:26:11 2011 +0000
Commit: Alexandre Restovtsev <tetromino <AT> gmail <DOT> com>
CommitDate: Fri Aug 12 08:26:48 2011 +0000
URL: http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=4cc7c1dd
gnome-extra/gnome-shell-extensions: 3.0.2 → 3.0.2-r1, exts initially default to disabled
Use eselect-gnome-shell-extensions to initially disable installed
extensions by default (the system default can be changed using eselect,
and can be overridden per-user using gsettings or gnome-tweak-tool).
Do not install the xrandr-indicator extension (broken on gnome-3.0
versions of gjs).
Example extension is now installed in /usr/share/doc, and only if
USE=examples.
---
.../gnome-shell-extensions-3.0.2-r1.ebuild | 85 ++++++++++++++++++++
.../gnome-shell-extensions-3.0.2.ebuild | 47 -----------
.../gnome-shell-extensions-9999.ebuild | 54 +++++++++++--
3 files changed, 132 insertions(+), 54 deletions(-)
diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2-r1.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2-r1.ebuild
new file mode 100644
index 0000000..7182306
--- /dev/null
+++ b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME_TARBALL_SUFFIX="bz2"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+if [[ ${PV} = 9999 ]]; then
+ EGIT_BRANCH="gnome-3-0"
+ inherit gnome2-live
+fi
+
+DESCRIPTION="JavaScript extensions for GNOME Shell"
+HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples"
+if [[ ${PV} = 9999 ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64 ~x86"
+fi
+
+COMMON_DEPEND="
+ >=dev-libs/glib-2.26
+ >=gnome-base/gnome-desktop-2.91.6:3
+ app-admin/eselect-gnome-shell-extensions"
+RDEPEND="${COMMON_DEPEND}
+ gnome-base/gnome-desktop:3[introspection]
+ =gnome-base/gnome-shell-3.0*
+ media-libs/clutter:1.0[introspection]
+ net-libs/telepathy-glib[introspection]
+ x11-libs/gtk+:3[introspection]
+ x11-libs/pango[introspection]"
+DEPEND="${COMMON_DEPEND}
+ sys-devel/gettext
+ >=dev-util/pkgconfig-0.22
+ >=dev-util/intltool-0.26
+ gnome-base/gnome-common"
+
+pkg_setup() {
+ DOCS="NEWS README"
+ G2CONF="${G2CONF}
+ --enable-extensions=all
+ --disable-schemas-compile"
+}
+
+src_prepare() {
+ gnome2_src_prepare
+
+ # xrandr-indicator crashes gnome-shell with <gjs-0.7.15;
+ # see gnome bug 649077. For simplicity, just disable it for gnome-3.0.
+ sed -e 's:\(ALL_EXTENSIONS=.*\)xrandr-indicator:\1:' \
+ -i configure || die
+}
+
+src_install() {
+ gnome2_src_install
+
+ local example="example@gnome-shell-extensions.gnome.org"
+ if use examples; then
+ mv "${ED}usr/share/gnome-shell/extensions/${example}" \
+ "${ED}usr/share/doc/${PF}/" || die
+ else
+ rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
+ fi
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+
+ einfo "Updating list of installed extensions"
+ eselect gnome-shell-extensions update || die
+ elog
+ elog "Installed extensions installed are initially disabled by default."
+ elog "To change the system default and enable some extensions, you can use"
+ elog "# eselect gnome-shell-extensions"
+ elog "Alternatively, you can use the org.gnome.shell disabled-extensions"
+ elog "gsettings key to change the disabled extension list per-user."
+ elog
+}
diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2.ebuild
deleted file mode 100644
index 2aeccd4..0000000
--- a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.0.2.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="no"
-GNOME_TARBALL_SUFFIX="bz2"
-GNOME2_LA_PUNT="yes"
-
-inherit gnome2
-if [[ ${PV} = 9999 ]]; then
- inherit gnome2-live
-fi
-
-DESCRIPTION="JavaScript Extensions for GNOME Shell"
-HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE=""
-if [[ ${PV} = 9999 ]]; then
- KEYWORDS=""
-else
- KEYWORDS="~amd64 ~x86"
-fi
-
-COMMON_DEPEND="
- >=dev-libs/glib-2.26
- >=gnome-base/gnome-desktop-2.91.6:3"
-RDEPEND="${COMMON_DEPEND}
- gnome-base/gnome-desktop:3[introspection]
- media-libs/clutter:1.0[introspection]
- net-libs/telepathy-glib[introspection]
- x11-libs/gtk+:3[introspection]
- x11-libs/pango[introspection]"
-DEPEND="${COMMON_DEPEND}
- sys-devel/gettext
- >=dev-util/pkgconfig-0.22
- >=dev-util/intltool-0.26
- gnome-base/gnome-common"
-
-pkg_setup() {
- DOCS="NEWS README"
- G2CONF="${G2CONF}
- --enable-extensions=all
- --disable-schemas-compile"
-}
diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-9999.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-9999.ebuild
index 4adb188..7182306 100644
--- a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-9999.ebuild
+++ b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-9999.ebuild
@@ -4,29 +4,34 @@
EAPI="4"
GCONF_DEBUG="no"
+GNOME_TARBALL_SUFFIX="bz2"
GNOME2_LA_PUNT="yes"
-inherit gnome2 gnome2-live
+inherit gnome2
+if [[ ${PV} = 9999 ]]; then
+ EGIT_BRANCH="gnome-3-0"
+ inherit gnome2-live
+fi
-DESCRIPTION="JavaScript Extensions for GNOME Shell"
+DESCRIPTION="JavaScript extensions for GNOME Shell"
HOMEPAGE="http://live.gnome.org/GnomeShell/Extensions"
LICENSE="GPL-2"
SLOT="0"
-IUSE="+nm-applet"
+IUSE="examples"
if [[ ${PV} = 9999 ]]; then
KEYWORDS=""
else
- EGIT_TREE="3.0.1"
- EGIT_BRANCH="gnome-3-0"
KEYWORDS="~amd64 ~x86"
fi
COMMON_DEPEND="
>=dev-libs/glib-2.26
- >=gnome-base/gnome-desktop-2.91.6:3"
+ >=gnome-base/gnome-desktop-2.91.6:3
+ app-admin/eselect-gnome-shell-extensions"
RDEPEND="${COMMON_DEPEND}
gnome-base/gnome-desktop:3[introspection]
+ =gnome-base/gnome-shell-3.0*
media-libs/clutter:1.0[introspection]
net-libs/telepathy-glib[introspection]
x11-libs/gtk+:3[introspection]
@@ -38,8 +43,43 @@ DEPEND="${COMMON_DEPEND}
gnome-base/gnome-common"
pkg_setup() {
- DOCS="HACKING README"
+ DOCS="NEWS README"
G2CONF="${G2CONF}
--enable-extensions=all
--disable-schemas-compile"
}
+
+src_prepare() {
+ gnome2_src_prepare
+
+ # xrandr-indicator crashes gnome-shell with <gjs-0.7.15;
+ # see gnome bug 649077. For simplicity, just disable it for gnome-3.0.
+ sed -e 's:\(ALL_EXTENSIONS=.*\)xrandr-indicator:\1:' \
+ -i configure || die
+}
+
+src_install() {
+ gnome2_src_install
+
+ local example="example@gnome-shell-extensions.gnome.org"
+ if use examples; then
+ mv "${ED}usr/share/gnome-shell/extensions/${example}" \
+ "${ED}usr/share/doc/${PF}/" || die
+ else
+ rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
+ fi
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+
+ einfo "Updating list of installed extensions"
+ eselect gnome-shell-extensions update || die
+ elog
+ elog "Installed extensions installed are initially disabled by default."
+ elog "To change the system default and enable some extensions, you can use"
+ elog "# eselect gnome-shell-extensions"
+ elog "Alternatively, you can use the org.gnome.shell disabled-extensions"
+ elog "gsettings key to change the disabled extension list per-user."
+ elog
+}
next reply other threads:[~2011-08-12 8:30 UTC|newest]
Thread overview: 3+ messages / expand[flat|nested] mbox.gz Atom feed top
2011-08-12 8:29 Alexandre Restovtsev [this message]
-- strict thread matches above, loose matches on Subject: below --
2011-09-11 22:13 [gentoo-commits] proj/gnome:gnome-next commit in: gnome-extra/gnome-shell-extensions/ Alexandre Restovtsev
2011-08-12 8:29 Alexandre Restovtsev
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=4cc7c1ddb7578b33ecaa12f6c8b81e84845d57dd.tetromino@gentoo \
--to=tetromino@gmail.com \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox