[gentoo-commits] gentoo-x86 commit in net-misc/youtube-dl: ChangeLog youtube-dl-2015.08.06.1.ebuild youtube-dl-2015.07.21.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/youtube-dl: ChangeLog youtube-dl-2015.08.06.1.ebuild youtube-dl-2015.07.21.ebuild

[Jeroen Roovers (jer)]

jer         15/08/08 08:11:57

  Modified:             ChangeLog
  Added:                youtube-dl-2015.08.06.1.ebuild
  Removed:              youtube-dl-2015.07.21.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.495                net-misc/youtube-dl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?rev=1.495&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?rev=1.495&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?r1=1.494&r2=1.495

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v
retrieving revision 1.494
retrieving revision 1.495
diff -u -r1.494 -r1.495
--- ChangeLog	29 Jul 2015 04:51:00 -0000	1.494
+++ ChangeLog	8 Aug 2015 08:11:57 -0000	1.495
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/youtube-dl
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v 1.494 2015/07/29 04:51:00 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v 1.495 2015/08/08 08:11:57 jer Exp $
+
+*youtube-dl-2015.08.06.1 (08 Aug 2015)
+
+  08 Aug 2015; Jeroen Roovers <jer@gentoo.org> -youtube-dl-2015.07.21.ebuild,
+  +youtube-dl-2015.08.06.1.ebuild:
+  Version bump.
 
 *youtube-dl-2015.07.28 (29 Jul 2015)
 



1.1                  net-misc/youtube-dl/youtube-dl-2015.08.06.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/youtube-dl-2015.08.06.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/youtube-dl-2015.08.06.1.ebuild?rev=1.1&content-type=text/plain

Index: youtube-dl-2015.08.06.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/youtube-dl-2015.08.06.1.ebuild,v 1.1 2015/08/08 08:11:57 jer Exp $

EAPI=5

PYTHON_COMPAT=(python{2_7,3_3,3_4})
DISTUTILS_SINGLE_IMPL=true
inherit bash-completion-r1 distutils-r1 eutils

DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="http://rg3.github.com/youtube-dl/"
SRC_URI="http://youtube-dl.org/downloads/${PV}/${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="offensive test"

DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( dev-python/nose[coverage(+)] )
"

S="${WORKDIR}/${PN}"

src_prepare() {
	if ! use offensive; then
		sed -i -e "/__version__/s|'$|-gentoo_no_offensive_sites'|g" \
			youtube_dl/version.py || die
		# these have single line import statements
		local xxx=(
			alphaporno anysex behindkink drtuber eporner eroprofile extremetube
			fourtube foxgay goshgay hellporno hentaistigma hornbunny keezmovies
			mofosex motherless porn91 pornhd pornotube pornovoisines pornoxo
			redtube sexykarma sexu sunporno slutload spankbang spankwire thisav
			trutube tube8 vporn xbef xnxx xtube xvideos xxxymovies youjizz
			youporn
		)
		# these have multi-line import statements
		local mxxx=(
			pornhub xhamster tnaflix
		)
		# do single line imports
		sed -i \
			-e $( printf '/%s/d;' ${xxx[@]} ) \
			youtube_dl/extractor/__init__.py \
			|| die

		# do multiple line imports
		sed -i \
			-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
			youtube_dl/extractor/__init__.py \
			|| die

		sed -i \
			-e $( printf '/%s/d;' ${mxxx[@]} ) \
			youtube_dl/extractor/generic.py \
			youtube_dl/extractor/tumblr.py \
			|| die

		rm \
			$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
			test/test_age_restriction.py \
			|| die
	fi

	epatch_user
}

src_compile() {
	distutils-r1_src_compile
}

src_test() {
	emake test
}

src_install() {
	python_domodule youtube_dl
	dobin bin/${PN}
	dodoc README.txt
	doman ${PN}.1
	newbashcomp ${PN}.bash-completion ${PN}
	python_fix_shebang "${ED}"
}