[gentoo-commits] gentoo-x86 commit in app-editors/jedit: ChangeLog jedit-5.2.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/jedit: ChangeLog jedit-5.2.0.ebuild

[Sebastian Pipping (sping)]

sping       15/08/08 00:36:33

  Modified:             ChangeLog
  Added:                jedit-5.2.0.ebuild
  Log:
  app-editors/jedit: 5.2.0 (bug #552764)
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

Revision  Changes    Path
1.112                app-editors/jedit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/jedit/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/jedit/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	9 Jun 2015 09:49:51 -0000	1.111
+++ ChangeLog	8 Aug 2015 00:36:33 -0000	1.112
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/jedit
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.111 2015/06/09 09:49:51 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/ChangeLog,v 1.112 2015/08/08 00:36:33 sping Exp $
+
+*jedit-5.2.0 (08 Aug 2015)
+
+  08 Aug 2015; Sebastian Pipping <sping@gentoo.org> +jedit-5.2.0.ebuild,
+  +files/jedit-5.2.0-build-xml.patch:
+  Bump to 5.2.0 (bug #552764)
 
   09 Jun 2015; Justin Lecher <jlec@gentoo.org> metadata.xml:
   Updating remote-id in metadata.xml



1.1                  app-editors/jedit/jedit-5.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/jedit/jedit-5.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/jedit/jedit-5.2.0.ebuild?rev=1.1&content-type=text/plain

Index: jedit-5.2.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/jedit/jedit-5.2.0.ebuild,v 1.1 2015/08/08 00:36:33 sping Exp $

EAPI=5

JAVA_PKG_IUSE="doc test"

inherit java-pkg-2 java-ant-2 eutils fdo-mime

DESCRIPTION="Programmer's editor written in Java"
HOMEPAGE="http://www.jedit.org"
SRC_URI="mirror://sourceforge/${PN}/${PN}${PV}source.tar.bz2"

LICENSE="BSD GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
SLOT="0"
IUSE=""

# missing from tarball
RESTRICT="test"

COMMON_DEP="
	dev-java/jsr305:0"
RDEPEND="${COMMON_DEP}
	>=virtual/jre-1.7"
DEPEND="${COMMON_DEP}
	>=virtual/jdk-1.7
	dev-java/ant-apache-bsf:0
	dev-java/ant-contrib:0
	dev-java/bsh[bsf]
	test? (
		dev-java/ant-junit:0
	)"

S="${WORKDIR}/jEdit"

JEDIT_HOME="/usr/share/${PN}"

java_prepare() {
	mkdir -p lib/{ant-contrib,compile,default-plugins,scripting} || die

	epatch "${FILESDIR}"/${P}-build-xml.patch
}

JAVA_ANT_REWRITE_CLASSPATH="true"

EANT_ANT_TASKS="ant-apache-bsf ant-contrib bsh"
EANT_GENTOO_CLASSPATH="jsr305"
EANT_EXTRA_ARGS="-Divy.jar.present=true -Divy.done=true"
EANT_BUILD_TARGET="build"
# TODO could build more docs, ie generate-doc-faq generate-doc-news
# generate-doc-users-guide ua.
EANT_DOC_TARGET="generate-javadoc"
# in fact needed only for docs, but shouldn't hurt
EANT_NEEDS_TOOLS="true"

src_test() {
	java-pkg-2_src_test
}

src_install () {
	dodir ${JEDIT_HOME}
	cp -R build/${PN}.jar jars doc keymaps macros modes properties startup \
		"${D}${JEDIT_HOME}" || die

	java-pkg_regjar ${JEDIT_HOME}/${PN}.jar

	java-pkg_dolauncher ${PN} --main org.gjt.sp.jedit.jEdit

	use doc && java-pkg_dojavadoc build/classes/javadoc/api

	make_desktop_entry ${PN} \
		jEdit \
		${JEDIT_HOME}/doc/${PN}.png \
		"Development;Utility;TextEditor"

	# keep the plugin directory
	keepdir ${JEDIT_HOME}/jars
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog "The system directory for jEdit plugins is"
	elog "${JEDIT_HOME}/jars"
	elog "If you get plugin related errors on startup, first try updating them."
}

pkg_postrm() {
	if [[ -z ${REPLACED_BY_VERSION} ]]; then
		fdo-mime_desktop_database_update
		elog "jEdit plugins installed into /usr/share/jedit/jars"
		elog "(after installation of jEdit itself) haven't been"
		elog "removed. To get rid of jEdit completely, you may"
		elog "want to run"
		elog ""
		elog "    rm -r ${JEDIT_HOME}"
	fi
}