[gentoo-commits] gentoo-x86 commit in x11-wm/enlightenment: enlightenment-0.19.8.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-wm/enlightenment: enlightenment-0.19.8.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/08/06 03:57:52

  Modified:             ChangeLog
  Added:                enlightenment-0.19.8.ebuild
  Log:
  Version bump #555718 by DrSlony.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.209                x11-wm/enlightenment/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.209&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?rev=1.209&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/ChangeLog?r1=1.208&r2=1.209

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v
retrieving revision 1.208
retrieving revision 1.209
diff -u -r1.208 -r1.209
--- ChangeLog	6 Aug 2015 03:43:45 -0000	1.208
+++ ChangeLog	6 Aug 2015 03:57:52 -0000	1.209
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/enlightenment
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.208 2015/08/06 03:43:45 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/ChangeLog,v 1.209 2015/08/06 03:57:52 vapier Exp $
+
+*enlightenment-0.19.8 (06 Aug 2015)
+
+  06 Aug 2015; Mike Frysinger <vapier@gentoo.org> +enlightenment-0.19.8.ebuild:
+  Version bump #555718 by DrSlony.
 
 *enlightenment-1.0.17 (06 Aug 2015)
 



1.1                  x11-wm/enlightenment/enlightenment-0.19.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/enlightenment-0.19.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/enlightenment/enlightenment-0.19.8.ebuild?rev=1.1&content-type=text/plain

Index: enlightenment-0.19.8.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/enlightenment/enlightenment-0.19.8.ebuild,v 1.1 2015/08/06 03:57:52 vapier Exp $

EAPI="5"

MY_P=${P/_/-}

if [[ ${PV} == *9999 ]] ; then
	EGIT_SUB_PROJECT="core"
	EGIT_URI_APPEND="${PN}"
else
	SRC_URI="http://download.enlightenment.org/rel/apps/${PN}/${MY_P}.tar.xz"
	EKEY_STATE="snap"
fi

inherit enlightenment

DESCRIPTION="Enlightenment DR17 window manager"

LICENSE="BSD-2"
KEYWORDS="~amd64 ~arm ~x86"
SLOT="0.17/${PV%%_*}"

# The @ is just an anchor to expand from
__EVRY_MODS=""
__CONF_MODS="
	+@applications +@comp +@dialogs +@display
	+@interaction +@intl +@menus
	+@paths +@performance +@randr +@shelves +@theme +@wallpaper2
	+@window-manipulation +@window-remembers"
__NORM_MODS="
	@access +@appmenu +@backlight +@bluez4 +@battery +@clock
	+@connman +@contact +@cpufreq +@everything +@fileman
	+@fileman-opinfo +@gadman +@ibar +@ibox +@illume2 +@mixer +@msgbus
	+@music-control +@notification +@pager +@quickaccess +@shot
	+@start +@syscon +@systray +@tasks +@teamwork +@temperature +@tiling
	+@winlist +@wizard @wl-desktop-shell @wl-screenshot +@xkbswitch"
IUSE_E_MODULES="
	${__CONF_MODS//@/enlightenment_modules_conf-}
	${__NORM_MODS//@/enlightenment_modules_}"

IUSE="pam spell static-libs systemd +udev ukit wayland ${IUSE_E_MODULES}"

RDEPEND="
	pam? ( sys-libs/pam )
	systemd? ( sys-apps/systemd )
	wayland? (
		dev-libs/efl[wayland]
		>=dev-libs/wayland-1.2.0
		>=x11-libs/pixman-0.31.1
		>=x11-libs/libxkbcommon-0.3.1
	)
	>=dev-libs/efl-${PV}[X]
	>=media-libs/elementary-${PV}
	x11-libs/xcb-util-keysyms"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/quickstart.diff
	enlightenment_src_prepare
}

src_configure() {
	E_ECONF=(
		--disable-install-sysactions
		$(use_enable doc)
		--disable-device-hal
		$(use_enable nls)
		$(use_enable pam)
		$(use_enable systemd)
		--enable-device-udev
		$(use_enable udev mount-eeze)
		$(use_enable ukit mount-udisks)
		$(use_enable wayland wayland-clients)
	)
	local u c
	for u in ${IUSE_E_MODULES} ; do
		u=${u#+}
		c=${u#enlightenment_modules_}
		E_ECONF+=( $(use_enable ${u} ${c}) )
	done
	enlightenment_src_configure
}

src_install() {
	enlightenment_src_install
	insinto /etc/enlightenment
	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
}