[gentoo-commits] gentoo-x86 commit in dev-lang/ekopath: ekopath-6.0.468_p20150803.ebuild ChangeLog

["Michal Gorny (mgorny)" <mgorny@gentoo.org>]

mgorny      15/08/04 16:35:59

  Modified:             ChangeLog
  Added:                ekopath-6.0.468_p20150803.ebuild
  Log:
  New snapshot
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.32                 dev-lang/ekopath/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/ekopath/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/ekopath/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/ekopath/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/ekopath/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	8 Jul 2015 17:31:44 -0000	1.31
+++ ChangeLog	4 Aug 2015 16:35:58 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/ekopath
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/ekopath/ChangeLog,v 1.31 2015/07/08 17:31:44 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/ekopath/ChangeLog,v 1.32 2015/08/04 16:35:58 mgorny Exp $
+
+*ekopath-6.0.468_p20150803 (04 Aug 2015)
+
+  04 Aug 2015; Michał Górny <mgorny@gentoo.org>
+  +ekopath-6.0.468_p20150803.ebuild:
+  New snapshot
 
 *ekopath-6.0.439_p20150707 (08 Jul 2015)
 



1.1                  dev-lang/ekopath/ekopath-6.0.468_p20150803.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/ekopath/ekopath-6.0.468_p20150803.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/ekopath/ekopath-6.0.468_p20150803.ebuild?rev=1.1&content-type=text/plain

Index: ekopath-6.0.468_p20150803.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/ekopath/ekopath-6.0.468_p20150803.ebuild,v 1.1 2015/08/04 16:35:58 mgorny Exp $

EAPI=5

inherit versionator multilib pax-utils

MY_PV=$(get_version_component_range 1-3)
DATE=$(get_version_component_range 4)
DATE=${DATE#p}
DATE=${DATE:0:4}-${DATE:4:2}-${DATE:6}
INSTALLER=${PN}-${DATE}-installer.run

DESCRIPTION="PathScale EKOPath Compiler Suite"
HOMEPAGE="http://www.pathscale.com/ekopath-compiler-suite"
SRC_URI="http://c591116.r16.cf2.rackcdn.com/${PN}/nightly/Linux/${INSTALLER}"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

DEPEND="!!app-arch/rpm"
RDEPEND=""

RESTRICT="bindist mirror"

QA_PREBUILT="
	opt/${PN}/lib/${MY_PV}/x8664/*
	opt/${PN}/bin/*"

S="${WORKDIR}"

src_unpack() {
	cp "${DISTDIR}/${INSTALLER}" "${S}/" || die
	chmod +x "${S}/${INSTALLER}" || die
}

src_prepare() {
	cat > 99${PN} <<-EOF
		PATH=${EROOT%/}/opt/${PN}/bin
		ROOTPATH=${EROOT%/}/opt/${PN}/bin
		LDPATH=${EROOT%/}/opt/${PN}/lib:${EROOT%/}/opt/${PN}/lib/${MY_PV}/x8664/64
		MANPATH=${EROOT%/}/opt/${PN}/docs/man
	EOF
}

src_install() {
	# EI_PAX marking is obsolete and PT_PAX breaks the binary.
	# We must use XT_PAX to run the installer.
	if [[ ${PAX_MARKINGS} == "XT" ]]; then
		pax-mark m "${INSTALLER}"
	fi

	./"${INSTALLER}" \
		--prefix "${ED%/}/opt/${PN}" \
		--mode unattended || die

	if [[ ! -d ${ED%/}/opt/${PN}/lib/${MY_PV} ]]; then
		local guess
		cd "${ED%/}/opt/${PN}/lib" && guess=( * )

		if [[ ${guess[@]} ]]; then
			die "Incorrect release version in PV, guessing it should be: ${guess[*]}"
		else
			die "No libdir installed"
		fi
	fi
	[[ -x ${ED%}/opt/${PN}/bin/pathcc ]] || die "No pathcc executable was installed, your hardware is unsupported most likely"

	rm -r "${ED}/opt/${PN}"/uninstall* || die
	doenvd 99${PN}
}