[gentoo-commits] gentoo-x86 commit in x11-misc/zim: ChangeLog zim-0.63.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/zim: ChangeLog zim-0.63.ebuild

[Sebastian Pipping (sping)]

sping       15/08/03 20:32:44

  Modified:             ChangeLog
  Added:                zim-0.63.ebuild
  Log:
  x11-misc/zim: 0.63 (bug #556332)
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

Revision  Changes    Path
1.28                 x11-misc/zim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	3 Aug 2015 20:18:38 -0000	1.27
+++ ChangeLog	3 Aug 2015 20:32:43 -0000	1.28
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/zim
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v 1.27 2015/08/03 20:18:38 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/ChangeLog,v 1.28 2015/08/03 20:32:43 sping Exp $
+
+*zim-0.63 (03 Aug 2015)
+
+  03 Aug 2015; Sebastian Pipping <sping@gentoo.org> +zim-0.63.ebuild:
+  Bump to 0.63 (bug #556332)
 
   03 Aug 2015; Sebastian Pipping <sping@gentoo.org> zim-0.61.ebuild,
   zim-0.62.ebuild:



1.1                  x11-misc/zim/zim-0.63.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/zim-0.63.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/zim/zim-0.63.ebuild?rev=1.1&content-type=text/plain

Index: zim-0.63.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/zim-0.63.ebuild,v 1.1 2015/08/03 20:32:43 sping Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite"
DISTUTILS_SINGLE_IMPL=1

inherit distutils-r1 gnome2-utils fdo-mime virtualx

DESCRIPTION="A desktop wiki"
HOMEPAGE="http://zim-wiki.org/"
SRC_URI="http://zim-wiki.org/downloads/${P}.tar.gz"

LICENSE="BSD GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="dev-python/pygtk[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	x11-misc/xdg-utils
	test? (
		dev-vcs/bzr
		dev-vcs/git
		dev-vcs/mercurial )"

PATCHES=(
	"${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch
)

python_prepare() {
	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die

	if [[ ${LINGUAS} ]]; then
		local lingua
		for lingua in translations/*.po; do
			lingua=${lingua/.po}
			lingua=${lingua/translations\/}
			has ${lingua} ${LINGUAS} || \
				{ rm translations/${lingua}.po || die; }
		done
	fi

	distutils-r1_python_prepare
}

python_test() {
	VIRTUALX_COMMAND="${PYTHON}" virtualmake test.py
}

python_install() {
	distutils-r1_python_install --skip-xdg-cmd
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	if ! has_version ${CATEGORY}/${PN}; then
		einfo "Please emerge these packages for additional functionality"
		einfo "    dev-lang/R"
		einfo "    dev-python/gtkspell-python"
		einfo "    dev-vcs/bzr"
		einfo "    gnome-extra/zeitgeist"
		einfo "    media-gfx/graphviz"
		einfo "    media-gfx/imagemagick"
		einfo "    media-gfx/scrot"
		einfo "    media-sound/lilypond"
		einfo "    sci-visualization/gnuplot"
		einfo "    virtual/latex-base app-text/dvipng"
	fi
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}