[gentoo-commits] gentoo-x86 commit in net-firewall/fwknop: fwknop-2.6.6-r1.ebuild ChangeLog fwknop-2.6.6.ebuild

[gentoo-commits] gentoo-x86 commit in net-firewall/fwknop: fwknop-2.6.6-r1.ebuild ChangeLog fwknop-2.6.6.ebuild

[Ian Delaney (idella4)]

idella4     15/07/29 11:41:52

  Modified:             ChangeLog
  Added:                fwknop-2.6.6-r1.ebuild
  Removed:              fwknop-2.6.6.ebuild
  Log:
  revbump; new script files added to equip for systemd, other script files edited from patches via bug #554690, remove defunct fwknop-2.6.6.ebuild to avoid any mixing of updated scripts
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.8                  net-firewall/fwknop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	1 May 2015 09:54:59 -0000	1.7
+++ ChangeLog	29 Jul 2015 11:41:52 -0000	1.8
@@ -1,6 +1,15 @@
 # ChangeLog for net-firewall/fwknop
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v 1.7 2015/05/01 09:54:59 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v 1.8 2015/07/29 11:41:52 idella4 Exp $
+
+*fwknop-2.6.6-r1 (29 Jul 2015)
+
+  29 Jul 2015; Ian Delaney <idella4@gentoo.org> +files/fwknopd.service,
+  +fwknop-2.6.6-r1.ebuild, -fwknop-2.6.6.ebuild, files/fwknopd.confd,
+  files/fwknopd.init:
+  revbump; new script files added to equip for systemd, other script files
+  edited from patches via bug #554690, remove defunct fwknop-2.6.6.ebuild to
+  avoid any mixing of updated scripts
 
   01 May 2015; Ian Delaney <idella4@gentoo.org> files/fwknopd.confd,
   files/fwknopd.init:



1.1                  net-firewall/fwknop/fwknop-2.6.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: fwknop-2.6.6-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6-r1.ebuild,v 1.1 2015/07/29 11:41:52 idella4 Exp $

EAPI=5

# Does work with python2_7, does not work with python3_3 on my machine
# More feedback is welcome, since setup.py does not provide any info
PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1
DISTUTILS_SINGLE_IMPL=1
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1

inherit autotools-utils distutils-r1 systemd

DESCRIPTION="Single Packet Authorization and Port Knocking application"
HOMEPAGE="http://www.cipherdyne.org/fwknop/"
SRC_URI="https://github.com/mrash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="client extras gdbm gpg python server udp-server"

RDEPEND="
	client? ( net-misc/wget[ssl] )
	gpg? (
		dev-libs/libassuan
		dev-libs/libgpg-error
	)
	python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}
	gdbm? ( sys-libs/gdbm )
	gpg? ( app-crypt/gpgme )
	server? (
		!udp-server? ( net-libs/libpcap )
		net-firewall/iptables
	)
"

REQUIRED_USE="
	python? ( ${PYTHON_REQUIRED_USE} )
	udp-server? ( server )
"

DOCS=( ChangeLog README.md )

src_prepare() {
	# Install example configs with .example suffix
	if use server; then
		sed -i 's/conf;/conf.example;/g' "${S}"/Makefile.am || die
	fi

	autotools-utils_src_prepare

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_prepare
	fi
}

src_configure() {
	local myeconfargs=(
		--localstatedir=/run
		--enable-digest-cache
		$(use_enable client)
		$(use_enable !gdbm file-cache)
		$(use_enable server)
		$(use_enable udp-server)
		$(use_with gpg gpgme)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_compile
	fi
}

src_install() {
	autotools-utils_src_install
	prune_libtool_files --modules

	if use server; then
		newinitd "${FILESDIR}/fwknopd.init" fwknopd
		newconfd "${FILESDIR}/fwknopd.confd" fwknopd
		systemd_dounit "${FILESDIR}/fwknopd.service"
		systemd_newtmpfilesd "${FILESDIR}/fwknopd.tmpfiles.conf" fwknopd.conf
	fi

	use extras && dodoc "${S}/extras/apparmor/usr.sbin.fwknopd"

	if use python; then
		# Unset DOCS since distutils-r1.eclass interferes
		local DOCS=()
		cd "${S}"/python || die
		distutils-r1_src_install
	fi
}