[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: git-cola-2.2.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: git-cola-2.2.1.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/07/29 07:45:09

  Modified:             ChangeLog
  Added:                git-cola-2.2.1.ebuild
  Log:
  Version Bump, bug #554456; thanks Coacher for all the work
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

Revision  Changes    Path
1.50                 dev-vcs/git-cola/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	27 May 2015 17:00:39 -0000	1.49
+++ ChangeLog	29 Jul 2015 07:45:09 -0000	1.50
@@ -1,6 +1,14 @@
 # ChangeLog for dev-vcs/git-cola
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.49 2015/05/27 17:00:39 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.50 2015/07/29 07:45:09 jlec Exp $
+
+*git-cola-2.2.1 (29 Jul 2015)
+
+  29 Jul 2015; Justin Lecher <jlec@gentoo.org>
+  +files/git-cola-2.2.1-disable-live-tests.patch,
+  +files/git-cola-2.2.1-update-git-config-in-tests.patch,
+  +git-cola-2.2.1.ebuild:
+  Version Bump, bug #554456; thanks Coacher for all the work
 
   27 May 2015; Justin Lecher <jlec@gentoo.org> -files/1.3.8-disable-tests.patch,
   -files/1.8.1-system-ssh-askpass.patch, -files/1.9.1-disable-tests.patch:



1.1                  dev-vcs/git-cola/git-cola-2.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-2.2.1.ebuild?rev=1.1&content-type=text/plain

Index: git-cola-2.2.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/git-cola-2.2.1.ebuild,v 1.1 2015/07/29 07:45:09 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 python3_{3,4} )
DISTUTILS_SINGLE_IMPL=true

inherit distutils-r1 readme.gentoo virtualx

DESCRIPTION="The highly caffeinated git GUI"
HOMEPAGE="https://git-cola.github.io/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc test"

RDEPEND="
	dev-python/pyinotify[${PYTHON_USEDEP}]
	dev-python/send2trash[${PYTHON_USEDEP}]
	dev-python/PyQt4[${PYTHON_USEDEP}]
	dev-vcs/git"
DEPEND="${RDEPEND}
	sys-devel/gettext
	doc? (
		dev-python/sphinx[${PYTHON_USEDEP}]
		python_targets_python2_7? ( dev-python/sphinxtogithub[$(python_gen_usedep 'python2*')] )
		)
	test? ( dev-python/nose[${PYTHON_USEDEP}] )
"

PATCHES=(
	"${FILESDIR}"/${P}-disable-live-tests.patch
	"${FILESDIR}"/${P}-update-git-config-in-tests.patch
)

python_prepare_all() {
	rm share/git-cola/bin/*askpass* || die

	# remove broken tests
	rm test/i18n_test.py || die

	# don't install docs into wrong location
	sed -i -e '/doc/d' setup.py || die

	# fix doc directory reference
	sed -i \
		-e "s/'doc', 'git-cola'/'doc', '${PF}'/" \
		cola/resources.py || die

	# fix ssh-askpass directory reference
	sed -i -e 's/resources\.share/resources\.prefix/' cola/app.py || die

	distutils-r1_python_prepare_all
}

python_compile_all() {
	cd share/doc/${PN}/ || die
	if use doc; then
		emake all
	else
		sed \
			-e '/^install:/s:install-html::g' \
			-e '/^install:/s:install-man::g' \
			-i Makefile || die
	fi
}

python_test() {
	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C" \
	VIRTUALX_COMMAND="nosetests --verbose --with-id --with-doctest \
		--exclude=sphinxtogithub" \
	virtualmake
}

src_install() {
	distutils-r1_src_install
}

python_install_all() {
	cd share/doc/${PN}/ || die
	emake \
		DESTDIR="${D}" \
		docdir="${EPREFIX}/usr/share/doc/${PF}" \
		prefix="${EPREFIX}/usr" \
		install

	python_fix_shebang "${ED}/usr/share/git-cola/bin/git-xbase"
	python_optimize "${ED}/usr/share/git-cola/lib/cola"

	use doc || HTML_DOCS=( "${FILESDIR}"/index.html )

	distutils-r1_python_install_all
	readme.gentoo_create_doc
}