[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: mkvtoolnix-8.2.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: mkvtoolnix-8.2.0.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       15/07/19 10:20:15

  Modified:             ChangeLog
  Added:                mkvtoolnix-8.2.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.221                media-video/mkvtoolnix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.221&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.221&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?r1=1.220&r2=1.221

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v
retrieving revision 1.220
retrieving revision 1.221
diff -u -r1.220 -r1.221
--- ChangeLog	18 Jul 2015 18:45:23 -0000	1.220
+++ ChangeLog	19 Jul 2015 10:20:14 -0000	1.221
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mkvtoolnix
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.220 2015/07/18 18:45:23 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.221 2015/07/19 10:20:14 pacho Exp $
+
+*mkvtoolnix-8.2.0 (19 Jul 2015)
+
+  19 Jul 2015; Pacho Ramos <pacho@gentoo.org> +mkvtoolnix-8.2.0.ebuild:
+  Version bump
 
   18 Jul 2015; Pacho Ramos <pacho@gentoo.org>
   +files/mkvtoolnix-6.6.0-boost-1.56.patch, mkvtoolnix-6.6.0.ebuild:



1.1                  media-video/mkvtoolnix/mkvtoolnix-8.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-8.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-8.2.0.ebuild?rev=1.1&content-type=text/plain

Index: mkvtoolnix-8.2.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-8.2.0.ebuild,v 1.1 2015/07/19 10:20:14 pacho Exp $

EAPI=5
WX_GTK_VER="3.0"
inherit eutils multilib toolchain-funcs versionator wxwidgets multiprocessing autotools

DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="debug pch qt5 wxwidgets"

ruby_atom() {
	local ruby_slot=${1/ruby/}
	ruby_slot="${ruby_slot:0:1}.${ruby_slot:1:2}"
	echo "dev-lang/ruby:${ruby_slot}"
}

# hacks to avoid using the ruby eclasses since this requires something similar
# to the python-any-r1 eclass for ruby which currently doesn't exist
RUBY_IMPLS=( ruby22 ruby21 ruby20 )
RUBY_BDEPS="$(for ruby_impl in "${RUBY_IMPLS[@]}"; do
	echo "( $(ruby_atom ${ruby_impl}) virtual/rubygems[ruby_targets_${ruby_impl}] )"; done)"

RDEPEND="
	>=dev-libs/boost-1.46.0:=
	>=dev-libs/libebml-1.3.1:=
	dev-libs/pugixml
	media-libs/flac
	>=media-libs/libmatroska-1.4.2:=
	media-libs/libogg
	media-libs/libvorbis
	sys-apps/file
	>=sys-devel/gcc-4.6
	sys-libs/zlib
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtwidgets:5
	)
	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
"
DEPEND="${RDEPEND}
	|| ( ${RUBY_BDEPS} )
	sys-devel/gettext
	virtual/pkgconfig
"

pkg_pretend() {
	# http://bugs.gentoo.org/419257
	local ver=4.6
	local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
	if ! version_is_at_least ${ver} $(gcc-version); then
		eerror ${msg}
		die ${msg}
	fi
}

src_prepare() {
	local ruby_impl
	for ruby_impl in "${RUBY_IMPLS[@]}"; do
		if has_version "$(ruby_atom ${ruby_impl})"; then
			export RUBY=${ruby_impl}
			break
		fi
	done

	[[ -z ${RUBY} ]] && die "No available ruby implementations to build with"

	epatch "${FILESDIR}"/${PN}-5.8.0-boost-configure.patch
	eautoreconf
}

src_configure() {
	local myconf

	if use qt5 ; then
		# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
		myconf+=(
			--with-moc=/usr/$(get_libdir)/qt5/bin/moc
			--with-uic=/usr/$(get_libdir)/qt5/bin/uic
			--with-rcc=/usr/$(get_libdir)/qt5/bin/rcc
			--with-mkvtoolnix-gui
		)
	fi

	if use wxwidgets ; then
		need-wxwidgets unicode
		myconf+=( --with-wx-config=${WX_CONFIG} )
	fi

	econf \
		$(use_enable debug) \
		$(use_enable qt5 qt) \
		$(use_enable wxwidgets) \
		$(usex pch "" --disable-precompiled-headers) \
		"${myconf[@]}" \
		--disable-optimization \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--with-boost="${EPREFIX}"/usr \
		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir) \
		--without-curl
}

src_compile() {
	"${RUBY}" ./drake V=1 -j$(makeopts_jobs) || die
}

src_install() {
	DESTDIR="${D}" "${RUBY}" ./drake -j$(makeopts_jobs) install || die

	dodoc AUTHORS ChangeLog README.md TODO
	doman doc/man/*.1

	use wxwidgets && docompress -x /usr/share/doc/${PF}/guide
}