[gentoo-commits] gentoo-x86 commit in app-admin/apache-tools: ChangeLog apache-tools-2.4.16.ebuild apache-tools-2.4.12.ebuild

[gentoo-commits] gentoo-x86 commit in app-admin/apache-tools: ChangeLog apache-tools-2.4.16.ebuild apache-tools-2.4.12.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/07/16 06:08:19

  Modified:             ChangeLog apache-tools-2.4.12.ebuild
  Added:                apache-tools-2.4.16.ebuild
  Log:
  Version bump (bug #554948). Slightly tweaked openssl dependency
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 981CA6FC)

Revision  Changes    Path
1.206                app-admin/apache-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/ChangeLog?rev=1.206&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/ChangeLog?rev=1.206&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/ChangeLog?r1=1.205&r2=1.206

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/apache-tools/ChangeLog,v
retrieving revision 1.205
retrieving revision 1.206
diff -u -r1.205 -r1.206
--- ChangeLog	16 Mar 2015 21:58:00 -0000	1.205
+++ ChangeLog	16 Jul 2015 06:08:19 -0000	1.206
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/apache-tools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/apache-tools/ChangeLog,v 1.205 2015/03/16 21:58:00 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/apache-tools/ChangeLog,v 1.206 2015/07/16 06:08:19 polynomial-c Exp $
+
+*apache-tools-2.4.16 (16 Jul 2015)
+
+  16 Jul 2015; Lars Wendler <polynomial-c@gentoo.org>
+  apache-tools-2.4.12.ebuild, +apache-tools-2.4.16.ebuild:
+  Version bump (bug #554948). Slightly tweaked openssl dependency.
 
   16 Mar 2015; Lars Wendler <polynomial-c@gentoo.org>
   apache-tools-2.2.29.ebuild, apache-tools-2.4.12.ebuild:



1.3                  app-admin/apache-tools/apache-tools-2.4.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild?r1=1.2&r2=1.3

Index: apache-tools-2.4.12.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- apache-tools-2.4.12.ebuild	16 Mar 2015 21:58:00 -0000	1.2
+++ apache-tools-2.4.12.ebuild	16 Jul 2015 06:08:19 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild,v 1.2 2015/03/16 21:58:00 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.12.ebuild,v 1.3 2015/07/16 06:08:19 polynomial-c Exp $
 
 EAPI=5
 inherit flag-o-matic eutils multilib toolchain-funcs
@@ -20,7 +20,7 @@
 	dev-libs/expat
 	dev-libs/libpcre
 	kernel_linux? ( sys-apps/util-linux )
-	ssl? ( dev-libs/openssl )"
+	ssl? ( dev-libs/openssl:0= )"
 
 DEPEND="${RDEPEND}
 	sys-devel/libtool"



1.1                  app-admin/apache-tools/apache-tools-2.4.16.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.16.ebuild?rev=1.1&content-type=text/plain

Index: apache-tools-2.4.16.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/apache-tools/apache-tools-2.4.16.ebuild,v 1.1 2015/07/16 06:08:19 polynomial-c Exp $

EAPI=5
inherit flag-o-matic eutils multilib toolchain-funcs

DESCRIPTION="Useful Apache tools - htdigest, htpasswd, ab, htdbm"
HOMEPAGE="http://httpd.apache.org/"
SRC_URI="mirror://apache/httpd/httpd-${PV}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc64-solaris ~x64-solaris"
IUSE="ssl"
RESTRICT="test"

RDEPEND=">=dev-libs/apr-1.5.0:1
	dev-libs/apr-util:1
	dev-libs/expat
	dev-libs/libpcre
	kernel_linux? ( sys-apps/util-linux )
	ssl? ( dev-libs/openssl:0= )"

DEPEND="${RDEPEND}
	sys-devel/libtool"

S="${WORKDIR}/httpd-${PV}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.4.7-Makefile.patch #459446

	# This package really should upgrade to using pcre's .pc file.
	cat <<-\EOF >"${T}"/pcre-config
	#!/bin/sh
	[ "${flag}" = "--version" ] && set -- --modversion
	exec ${PKG_CONFIG} libpcre "$@"
	EOF
	chmod a+x "${T}"/pcre-config
}

src_configure() {
	# Brain dead check.
	tc-is-cross-compiler && export ap_cv_void_ptr_lt_long="no"

	tc-export PKG_CONFIG

	# Instead of filtering --as-needed (bug #128505), append --no-as-needed
	append-ldflags $(no-as-needed)

	# econf overwrites the stuff from config.layout.
	ac_cv_path_PKGCONFIG=${PKG_CONFIG} \
	econf \
		--libexecdir="${EPREFIX}"/usr/$(get_libdir)/apache2/modules \
		--sbindir="${EPREFIX}"/usr/sbin \
		--with-perl="${EPREFIX}"/usr/bin/perl \
		--with-expat="${EPREFIX}"/usr \
		--with-z="${EPREFIX}"/usr \
		--with-apr="${SYSROOT}${EPREFIX}"/usr \
		--with-apr-util="${SYSROOT}${EPREFIX}"/usr \
		--with-pcre="${T}"/pcre-config \
		$(use_enable ssl) \
		$(usex ssl '--with-ssl="${EPREFIX}"/usr' '')
	sed -i \
		-e '/^LTFLAGS/s:--silent::' \
		build/rules.mk build/config_vars.mk || die
}

src_compile() {
	emake -C support
}

src_install() {
	emake -C support DESTDIR="${D}" install
	dodoc CHANGES
	doman docs/man/{dbmmanage,htdigest,htpasswd,htdbm,ab,logresolve}.1 \
		docs/man/{htcacheclean,rotatelogs}.8

	# Providing compatiblity symlinks for #177697 (which we'll stop to install
	# at some point).
	pushd "${ED}"/usr/sbin >/dev/null || die
	local i
	for i in *; do
		dosym ${i} /usr/sbin/${i}2
	done
	popd >/dev/null || die

	# Provide a symlink for ab-ssl
	if use ssl; then
		dosym ab /usr/bin/ab-ssl
		dosym ab /usr/bin/ab2-ssl
	fi
}