[gentoo-commits] gentoo-x86 commit in www-plugins/freshplayerplugin: freshplayerplugin-0.3.1-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in www-plugins/freshplayerplugin: freshplayerplugin-0.3.1-r1.ebuild ChangeLog

[Brian Evans (grknight)]

grknight    15/07/15 20:09:28

  Modified:             ChangeLog
  Added:                freshplayerplugin-0.3.1-r1.ebuild
  Log:
  Add libav and vdpau USE flags; Fix dependencies of hardware decoding
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D1F781EFF9F4A3B6)

Revision  Changes    Path
1.5                  www-plugins/freshplayerplugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	14 Jul 2015 23:57:18 -0000	1.4
+++ ChangeLog	15 Jul 2015 20:09:28 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for www-plugins/freshplayerplugin
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog,v 1.4 2015/07/14 23:57:18 grknight Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/freshplayerplugin/ChangeLog,v 1.5 2015/07/15 20:09:28 grknight Exp $
+
+*freshplayerplugin-0.3.1-r1 (15 Jul 2015)
+
+  15 Jul 2015; Brian Evans <grknight@gentoo.org>
+  +freshplayerplugin-0.3.1-r1.ebuild:
+  Add libav and vdpau USE flags; Fix dependencies of hardware decoding
 
 *freshplayerplugin-0.3.1 (14 Jul 2015)
 



1.1                  www-plugins/freshplayerplugin/freshplayerplugin-0.3.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/freshplayerplugin/freshplayerplugin-0.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/freshplayerplugin/freshplayerplugin-0.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: freshplayerplugin-0.3.1-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/freshplayerplugin/freshplayerplugin-0.3.1-r1.ebuild,v 1.1 2015/07/15 20:09:28 grknight Exp $

EAPI=5

CMAKE_MIN_VERSION="2.8.8"

inherit cmake-utils multilib

LICENSE="MIT"
HOMEPAGE="https://github.com/i-rinat/freshplayerplugin"
DESCRIPTION="PPAPI-host NPAPI-plugin adapter for flashplayer in npapi based browsers"
SRC_URI="https://github.com/i-rinat/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SLOT=0
IUSE="gtk3 jack libav pulseaudio vaapi vdpau"

KEYWORDS="~amd64 ~x86"

HWDEC_DEPEND="
	libav? ( media-video/libav:0=[vaapi?,vdpau?,x264] )
	!libav? ( media-video/ffmpeg:0=[vaapi?,vdpau?,x264] )
	x11-libs/libva
	x11-libs/libvdpau
"

CDEPEND="
	dev-libs/glib:2=
	dev-libs/libconfig:=
	dev-libs/libevent:=[threads]
	dev-libs/openssl:0=
	media-libs/alsa-lib:=
	media-libs/freetype:2=
	media-libs/libv4l:0=
	media-libs/mesa:=[egl,gles2]
	x11-libs/libXrandr:=
	x11-libs/libXrender:=
	x11-libs/pango:=[X]
	jack? ( media-sound/jack )
	pulseaudio? ( media-sound/pulseaudio )
	!gtk3? ( x11-libs/gtk+:2= )
	gtk3? ( x11-libs/gtk+:3= )
	vaapi? ( ${HWDEC_DEPEND} )
	vdpau? ( ${HWDEC_DEPEND} )
"

DEPEND="${CDEPEND}
	dev-util/ragel
	virtual/pkgconfig
	"
RDEPEND="${CDEPEND}
	|| (
		www-plugins/chrome-binary-plugins[flash]
		www-client/google-chrome
		www-client/google-chrome-beta
		www-client/google-chrome-unstable
	)
	"

PATCHES=( "${FILESDIR}/0.2.4-cmake.patch" )

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with jack JACK)
		$(cmake-utils_use_with pulseaudio PULSEAUDIO)
		-DWITH_GTK=$(usex gtk3 3 2)
		-DCMAKE_SKIP_RPATH=1
	)
	if use vaapi || use vdpau ; then
		mycmakeargs+=( -DWITH_HWDEC=1 )
	else
		mycmakeargs+=( -DWITH_HWDEC=0 )
	fi
	cmake-utils_src_configure
}

src_install() {
	dodoc ChangeLog data/freshwrapper.conf.example README.md
	exeinto /usr/$(get_libdir)/nsbrowser/plugins
	doexe "${BUILD_DIR}/libfreshwrapper-pepperflash.so"
}