* [gentoo-commits] gentoo-x86 commit in net-mail/notmuch: ChangeLog notmuch-0.20.2.ebuild
@ 2015-07-15 7:20 Amadeusz Zolnowski (aidecoe)
0 siblings, 0 replies; only message in thread
From: Amadeusz Zolnowski (aidecoe) @ 2015-07-15 7:20 UTC (permalink / raw
To: gentoo-commits
aidecoe 15/07/15 07:20:21
Modified: ChangeLog
Added: notmuch-0.20.2.ebuild
Log:
Version bump.
NEWS
~~~~
Command-Line Interface
----------------------
- New `mimetype:` search prefix.
- Path to gpg is now configurable.
Emacs
-----
- Avoid rendering large text attachements.
- Improved rendering of CID references in HTML.
- Bug fix for marking messages read in `notmuch-tree` mode.
Vim
---
- Vim client now respects excluded tags.
Notmuch-Mutt
------------
- Support messages without Message-IDs.
Library
-------
- Undeprecate single message mboxes.
- New error logging facility.
- Several bug fixes related to stale iterators.
- New status code returning API for n_query_search_{messages,thread}.
- Fix for library `install_name` on Mac OS X.
- Fix for rounding of seconds.
Documentation
-------------
- Improved notmuch-search-terms.7.
nmbug-status
------------
- Various improvements.
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key F0134531E1DBFAB5)
Revision Changes Path
1.117 net-mail/notmuch/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.117&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.117&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?r1=1.116&r2=1.117
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v
retrieving revision 1.116
retrieving revision 1.117
diff -u -r1.116 -r1.117
--- ChangeLog 18 Apr 2015 15:56:03 -0000 1.116
+++ ChangeLog 15 Jul 2015 07:20:21 -0000 1.117
@@ -1,6 +1,57 @@
# ChangeLog for net-mail/notmuch
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.116 2015/04/18 15:56:03 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.117 2015/07/15 07:20:21 aidecoe Exp $
+
+*notmuch-0.20.2 (14 Jul 2015)
+
+ 14 Jul 2015; Amadeusz Żołnowski <aidecoe@gentoo.org>
+ +notmuch-0.20.2.ebuild:
+ Version bump.
+
+ NEWS
+ ~~~~
+
+ Command-Line Interface
+ ----------------------
+
+ - New `mimetype:` search prefix.
+ - Path to gpg is now configurable.
+
+ Emacs
+ -----
+
+ - Avoid rendering large text attachements.
+ - Improved rendering of CID references in HTML.
+ - Bug fix for marking messages read in `notmuch-tree` mode.
+
+ Vim
+ ---
+
+ - Vim client now respects excluded tags.
+
+ Notmuch-Mutt
+ ------------
+
+ - Support messages without Message-IDs.
+
+ Library
+ -------
+
+ - Undeprecate single message mboxes.
+ - New error logging facility.
+ - Several bug fixes related to stale iterators.
+ - New status code returning API for n_query_search_{messages,thread}.
+ - Fix for library `install_name` on Mac OS X.
+ - Fix for rounding of seconds.
+
+ Documentation
+ -------------
+
+ - Improved notmuch-search-terms.7.
+
+ nmbug-status
+ ------------
+ - Various improvements.
18 Apr 2015; Pacho Ramos <pacho@gentoo.org> notmuch-0.18.2.ebuild:
x86 stable wrt bug #516756
1.1 net-mail/notmuch/notmuch-0.20.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.20.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.20.2.ebuild?rev=1.1&content-type=text/plain
Index: notmuch-0.20.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/notmuch-0.20.2.ebuild,v 1.1 2015/07/15 07:20:21 aidecoe Exp $
EAPI=5
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
distutils-r1 toolchain-funcs
DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
HOMEPAGE="http://notmuchmail.org/"
SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="
nmbug? ( python )
python? ( ${PYTHON_REQUIRED_USE} )
test? ( crypt debug emacs python )
"
IUSE="crypt debug doc emacs mutt nmbug python test"
CDEPEND="
>=app-shells/bash-completion-1.9
>=dev-libs/glib-2.22
>=dev-libs/gmime-2.6.7
!=dev-libs/gmime-2.6.19
<dev-libs/xapian-1.3
>=sys-libs/zlib-1.2.5.2
sys-libs/talloc
debug? ( dev-util/valgrind )
emacs? ( >=virtual/emacs-23 )
python? ( ${PYTHON_DEPS} )
x86? ( >=dev-libs/xapian-1.2.7-r2 )
"
DEPEND="${CDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen
python? ( dev-python/sphinx[${PYTHON_USEDEP}] ) )
test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb )
"
RDEPEND="${CDEPEND}
crypt? ( app-crypt/gnupg )
nmbug? ( dev-vcs/git )
mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
virtual/perl-Pod-Parser
)
"
DOCS=( AUTHORS NEWS README )
SITEFILE="50${PN}-gentoo.el"
MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
MY_PATCHES=( )
bindings() {
local ret=0
if use $1; then
pushd bindings/$1 || die
shift
"$@"
ret=$?
popd || die
fi
return $ret
}
pkg_pretend() {
if has_version '<net-mail/notmuch-0.18'; then
ewarn
ewarn "There are few not backward compatible changes between"
ewarn "<notmuch-0.18 and >=notmuch-0.18. See NEWS file"
ewarn "(0.18 section) for details before first use!"
ewarn
fi
}
pkg_setup() {
if use emacs; then
elisp-need-emacs 23 || die "Emacs version too low"
fi
}
src_prepare() {
[[ "${MY_PATCHES[@]}" ]] && epatch "${MY_PATCHES[@]}"
bindings python distutils-r1_src_prepare
bindings python mv README README-python || die
mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
rm -f Makefile.config # assure that new Makefile.config will be generated
if use debug; then
append-cflags -g
append-cxxflags -g
fi
}
src_configure() {
local myeconfargs=(
--bashcompletiondir="$(get_bashcompdir)"
--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
--with-gmime-version=2.6
--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
$(use_with emacs)
)
tc-export CC CXX
econf "${myeconfargs[@]}"
}
src_compile() {
V=1 default
bindings python distutils-r1_src_compile
if use mutt; then
pushd contrib/notmuch-mutt || die
emake notmuch-mutt.1
popd || die
fi
if use doc; then
pydocs() {
pushd docs || die
emake html
mv html ../python || die
popd || die
}
LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
fi
}
src_test() {
pax-mark -m notmuch
emake download-test-databases
LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" default
pax-mark -ze notmuch
}
src_install() {
default
if use emacs; then
elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
fi
if use nmbug; then
dobin devel/nmbug/nmbug
dobin devel/nmbug/nmbug-status
fi
if use mutt; then
pushd contrib/notmuch-mutt || die
dobin notmuch-mutt
doman notmuch-mutt.1
insinto /etc/mutt
doins notmuch-mutt.rc
dodoc README-mutt
popd || die
fi
DOCS="" bindings python distutils-r1_src_install
use doc && bindings python dohtml -r python
}
pkg_preinst() {
if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
elog "To enable notmuch support in mutt, add the following line into"
elog "your mutt config file, please:"
elog ""
elog " source /etc/mutt/notmuch-mutt.rc"
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-07-15 7:20 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-07-15 7:20 [gentoo-commits] gentoo-x86 commit in net-mail/notmuch: ChangeLog notmuch-0.20.2.ebuild Amadeusz Zolnowski (aidecoe)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox