[gentoo-commits] gentoo-x86 commit in www-client/epiphany: epiphany-3.16.2.ebuild ChangeLog epiphany-3.12.1.ebuild

[gentoo-commits] gentoo-x86 commit in www-client/epiphany: epiphany-3.16.2.ebuild ChangeLog epiphany-3.12.1.ebuild

[Pacho Ramos (pacho)]

pacho       15/06/27 16:47:01

  Modified:             ChangeLog
  Added:                epiphany-3.16.2.ebuild
  Removed:              epiphany-3.12.1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.318                www-client/epiphany/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.318&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.318&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/ChangeLog?r1=1.317&r2=1.318

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v
retrieving revision 1.317
retrieving revision 1.318
diff -u -r1.317 -r1.318
--- ChangeLog	26 Jun 2015 09:24:00 -0000	1.317
+++ ChangeLog	27 Jun 2015 16:47:01 -0000	1.318
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/epiphany
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.317 2015/06/26 09:24:00 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.318 2015/06/27 16:47:01 pacho Exp $
+
+*epiphany-3.16.2 (27 Jun 2015)
+
+  27 Jun 2015; Pacho Ramos <pacho@gentoo.org> +epiphany-3.16.2.ebuild,
+  -epiphany-3.12.1.ebuild:
+  Version bump, drop old
 
   26 Jun 2015; Agostino Sarubbo <ago@gentoo.org> epiphany-3.14.2.ebuild:
   Stable for x86, wrt bug #551814



1.1                  www-client/epiphany/epiphany-3.16.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.16.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/epiphany/epiphany-3.16.2.ebuild?rev=1.1&content-type=text/plain

Index: epiphany-3.16.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.16.2.ebuild,v 1.1 2015/06/27 16:47:01 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

#inherit autotools eutils gnome2 pax-utils versionator virtualx
inherit eutils gnome2 pax-utils versionator virtualx

DESCRIPTION="GNOME webbrowser based on Webkit"
HOMEPAGE="https://wiki.gnome.org/Apps/Web"

# TODO: coverage
LICENSE="GPL-2"
SLOT="0"
IUSE="+jit +nss test"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

COMMON_DEPEND="
	>=app-crypt/gcr-3.5.5
	>=app-crypt/libsecret-0.14
	>=app-text/iso-codes-0.35
	>=dev-libs/glib-2.38:2[dbus]
	>=dev-libs/libxml2-2.6.12:2
	>=dev-libs/libxslt-1.1.7
	>=gnome-base/gsettings-desktop-schemas-0.0.1
	>=net-dns/avahi-0.6.22[dbus]
	>=net-libs/webkit-gtk-2.7.4:4[jit?]
	>=net-libs/libsoup-2.48:2.4
	>=x11-libs/gtk+-3.13:3
	>=x11-libs/libnotify-0.5.1:=
	gnome-base/gnome-desktop:3=

	dev-db/sqlite:3
	x11-libs/libwnck:3
	x11-libs/libX11

	x11-themes/gnome-icon-theme
	x11-themes/gnome-icon-theme-symbolic

	nss? ( dev-libs/nss )
"
# epiphany-extensions support was removed in 3.7; let's not pretend it still works
RDEPEND="${COMMON_DEPEND}
	!www-client/epiphany-extensions
"
# paxctl needed for bug #407085
# eautoreconf requires gnome-common-3.5.5
DEPEND="${COMMON_DEPEND}
	>=gnome-base/gnome-common-3.6
	>=dev-util/intltool-0.50
	sys-apps/paxctl
	sys-devel/gettext
	virtual/pkgconfig
"

src_prepare() {
	# Fix missing symbol in webextension.so, https://bugzilla.gnome.org/show_bug.cgi?id=728972
	# FIXME: More information needed per https://bugzilla.gnome.org/show_bug.cgi?id=728972#c5
	# If you are able to reproduce the failure, please provide it. Thanks
#	epatch "${FILESDIR}"/${PN}-3.14.0-missing-symbol.patch

	# Fix unittests
	# https://bugzilla.gnome.org/show_bug.cgi?id=751591
	epatch "${FILESDIR}"/${PN}-3.16.0-unittest-1.patch

	# https://bugzilla.gnome.org/show_bug.cgi?id=751593
	epatch "${FILESDIR}"/${PN}-3.14.0-unittest-2.patch

#	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--enable-shared \
		--disable-static \
		--with-distributor-name=Gentoo \
		$(use_enable nss) \
		$(use_enable test tests)
}

src_compile() {
	# needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
	unset DISPLAY
	gnome2_src_compile
}

src_test() {
	# FIXME: this should be handled at eclass level
	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die

	unset DISPLAY
	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
}

src_install() {
	DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
	gnome2_src_install
	use jit && pax-mark m "${ED}usr/bin/epiphany"
}