* [gentoo-commits] gentoo-x86 commit in app-office/texmaker: texmaker-4.4.1-r1.ebuild ChangeLog
@ 2015-06-24 6:28 Justin Lecher (jlec)
0 siblings, 0 replies; only message in thread
From: Justin Lecher (jlec) @ 2015-06-24 6:28 UTC (permalink / raw
To: gentoo-commits
jlec 15/06/24 06:28:53
Modified: ChangeLog
Added: texmaker-4.4.1-r1.ebuild
Log:
Add support for multiple styles in Qt5, thanks jorgicio for the patch; http://code.google.com/p/texmaker/issues/detail?id=1511
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)
Revision Changes Path
1.153 app-office/texmaker/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.153&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.153&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?r1=1.152&r2=1.153
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v
retrieving revision 1.152
retrieving revision 1.153
diff -u -r1.152 -r1.153
--- ChangeLog 10 May 2015 13:01:04 -0000 1.152
+++ ChangeLog 24 Jun 2015 06:28:53 -0000 1.153
@@ -1,6 +1,13 @@
# ChangeLog for app-office/texmaker
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.152 2015/05/10 13:01:04 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.153 2015/06/24 06:28:53 jlec Exp $
+
+*texmaker-4.4.1-r1 (24 Jun 2015)
+
+ 24 Jun 2015; Justin Lecher <jlec@gentoo.org>
+ +files/texmaker-4.4.1-modern-styles.patch, +texmaker-4.4.1-r1.ebuild:
+ Add support for multiple styles in Qt5, thanks jorgicio for the patch;
+ http://code.google.com/p/texmaker/issues/detail?id=1511
10 May 2015; Davide Pesavento <pesa@gentoo.org> texmaker-4.3.ebuild:
Add missing usedep for qtsingleapplication.
1.1 app-office/texmaker/texmaker-4.4.1-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.4.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.4.1-r1.ebuild?rev=1.1&content-type=text/plain
Index: texmaker-4.4.1-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-4.4.1-r1.ebuild,v 1.1 2015/06/24 06:28:53 jlec Exp $
EAPI=5
inherit eutils qmake-utils readme.gentoo
DESCRIPTION="A nice LaTeX-IDE"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="+qt4 qt5"
REQUIRED_USE="^^ ( qt4 qt5 )"
COMMON_DEPEND="
app-text/hunspell
app-text/poppler:=[qt4?,qt5?]
sys-libs/zlib
x11-libs/libX11
x11-libs/libXext
dev-qt/qtsingleapplication[X,qt4?,qt5?]
qt4? (
dev-qt/qtgui:4
dev-qt/qtcore:4
dev-qt/qtscript:4
dev-qt/qtwebkit:4
)
qt5? (
dev-qt/qtconcurrent:5
dev-qt/qtgui:5
dev-qt/qtcore:5
dev-qt/qtnetwork:5
dev-qt/qtscript:5
dev-qt/qtwebkit:5[printsupport]
dev-qt/qtwidgets:5
dev-qt/qtxml:5
)
"
RDEPEND="${COMMON_DEPEND}
virtual/latex-base
app-text/psutils
app-text/ghostscript-gpl
media-libs/netpbm
qt4? ( app-i18n/ibus-qt )"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-4.1-unbundle.patch
"${FILESDIR}"/${P}-modern-styles.patch
)
DOCS=( utilities/AUTHORS utilities/CHANGELOG.txt )
HTML_DOCS=( doc/. )
src_prepare() {
find singleapp hunspell -delete || die
epatch "${PATCHES[@]}"
cat >> ${PN}.pro <<- EOF
exists(texmakerx_my.pri):include(texmakerx_my.pri)
EOF
cp "${FILESDIR}"/texmakerx_my.pri . || die
sed \
-e '/^#include/s:hunspell/::g' \
-e '/^#include/s:singleapp/::g' \
-i *.cpp *.h || die
DOC_CONTENTS="A user manual with many screenshots is available at:
${EPREFIX}/usr/share/${PN}/usermanual_en.html"
}
src_configure() {
local myeqmakeargs=(
${PN}.pro
PREFIX="${EPREFIX}/usr"
DESKTOPDIR="${EPREFIX}/usr/share/applications"
ICONDIR="${EPREFIX}/usr/share/pixmaps"
)
if use qt4; then
eqmake4 ${myeqmakeargs[@]}
else
eqmake5 ${myeqmakeargs[@]}
fi
}
src_install() {
emake INSTALL_ROOT="${D}" install
einstalldocs
readme.gentoo_create_doc
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-24 6:28 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-24 6:28 [gentoo-commits] gentoo-x86 commit in app-office/texmaker: texmaker-4.4.1-r1.ebuild ChangeLog Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox