* [gentoo-commits] gentoo-x86 commit in dev-python/ipython: ipython-3.2.0.ebuild ipython-2.2.0-r1.ebuild ChangeLog ipython-2.4.1.ebuild ipython-3.0.0.ebuild ipython-3.1.0.ebuild
@ 2015-06-22 9:45 Justin Lecher (jlec)
0 siblings, 0 replies; only message in thread
From: Justin Lecher (jlec) @ 2015-06-22 9:45 UTC (permalink / raw
To: gentoo-commits
jlec 15/06/22 09:45:52
Modified: ChangeLog
Added: ipython-3.2.0.ebuild ipython-2.2.0-r1.ebuild
Removed: ipython-2.4.1.ebuild ipython-3.0.0.ebuild
ipython-3.1.0.ebuild
Log:
Backport vulnerability fix, bug #552816; drop vulnerable versions; create mathjax symlink USE dependent, bug #481726
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)
Revision Changes Path
1.174 dev-python/ipython/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?r1=1.173&r2=1.174
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog 21 Jun 2015 10:42:13 -0000 1.173
+++ ChangeLog 22 Jun 2015 09:45:52 -0000 1.174
@@ -1,6 +1,16 @@
# ChangeLog for dev-python/ipython
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.173 2015/06/21 10:42:13 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.174 2015/06/22 09:45:52 jlec Exp $
+
+*ipython-3.2.0 (22 Jun 2015)
+*ipython-2.2.0-r1 (22 Jun 2015)
+
+ 22 Jun 2015; Justin Lecher <jlec@gentoo.org>
+ +files/ipython-2.2.0-login-backport.patch, +ipython-2.2.0-r1.ebuild,
+ +ipython-3.2.0.ebuild, -ipython-2.4.1.ebuild, -ipython-3.0.0.ebuild,
+ -ipython-3.1.0.ebuild:
+ Backport vulnerability fix, bug #552816; drop vulnerable versions; create
+ mathjax symlink USE dependent, bug #481726
21 Jun 2015; Markus Meier <maekke@gentoo.org> ipython-3.1.0.ebuild:
add ~arm, bug #541628
1.1 dev-python/ipython/ipython-3.2.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-3.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-3.2.0.ebuild?rev=1.1&content-type=text/plain
Index: ipython-3.2.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-3.2.0.ebuild,v 1.1 2015/06/22 09:45:52 jlec Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{3,4} )
PYTHON_REQ_USE='readline,sqlite'
inherit distutils-r1 eutils virtualx
DESCRIPTION="Advanced interactive shell for Python"
HOMEPAGE="http://ipython.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc examples matplotlib mongodb notebook nbconvert octave qt4 +smp test wxwidgets"
REQUIRED_USE="test? ( doc matplotlib mongodb notebook nbconvert octave qt4 wxwidgets )"
PY2_USEDEP=$(python_gen_usedep python2_7)
CDEPEND="
dev-python/decorator[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pyparsing[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/simplegeneric[${PYTHON_USEDEP}]
matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
octave? ( dev-python/oct2py[${PYTHON_USEDEP}] )
smp? ( >=dev-python/pyzmq-13[${PYTHON_USEDEP}] )
wxwidgets? ( $(python_gen_cond_dep 'dev-python/wxpython:*[${PYTHON_USEDEP}]' python2_7) )"
RDEPEND="${CDEPEND}
notebook? (
dev-libs/mathjax
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/jsonschema[${PYTHON_USEDEP}]
>=dev-python/mistune-0.5[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
>=dev-python/pyzmq-13[${PYTHON_USEDEP}]
>=dev-python/terminado-0.3.3[${PYTHON_USEDEP}]
>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
)
nbconvert? (
|| ( >=net-libs/nodejs-0.9.12 >=app-text/pandoc-1.12.1 )
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/jsonschema[${PYTHON_USEDEP}]
>=dev-python/mistune-0.5[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
)
qt4? (
|| (
dev-python/PyQt4[${PYTHON_USEDEP},svg]
dev-python/PyQt5[${PYTHON_USEDEP},svg]
dev-python/pyside[${PYTHON_USEDEP},svg]
)
dev-python/pygments[${PYTHON_USEDEP}]
>=dev-python/pyzmq-13[${PYTHON_USEDEP}] )"
DEPEND="${CDEPEND}
test? (
app-text/dvipng
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/mock[${PY2_USEDEP}]
>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
)
doc? (
dev-python/cython[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'dev-python/fabric[${PYTHON_USEDEP}]' python2_7)
dev-python/jsonschema[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
dev-python/numpydoc[${PYTHON_USEDEP}]
dev-python/pymongo[${PYTHON_USEDEP}]
dev-python/rpy[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.1[${PYTHON_USEDEP}]
>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
)"
PATCHES=(
"${FILESDIR}"/2.1.0-substitute-files.patch
)
DISTUTILS_IN_SOURCE_BUILD=1
python_prepare_all() {
# Remove out of date insource files
rm IPython/extensions/rmagic.py || die
# Prevent un-needed download during build
if use doc; then
sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
fi
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C docs html_noapi
}
src_test() {
# virtualx has trouble with parallel runs.
local DISTUTILS_NO_PARALLEL_BUILD=1
distutils-r1_src_test
}
python_test() {
distutils_install_for_testing
local fail
run_tests() {
pushd ${TEST_DIR} > /dev/null
"${PYTHON}" -m IPython.testing.iptestcontroller --all || fail=1
popd > /dev/null
}
VIRTUALX_COMMAND=run_tests virtualmake
[[ ${fail} ]] && die "Tests fail with ${EPYTHON}"
}
python_install() {
distutils-r1_python_install
use notebook && dosym /usr/share/mathjax $(python_get_sitedir)/IPython/html/static/mathjax
# Create ipythonX.Y symlinks.
# TODO:
# 1. do we want them for pypy? No. pypy has no numpy
# 2. handle it in the eclass instead (use _python_ln_rel).
# With pypy not an option the dosym becomes unconditional
dosym ../lib/python-exec/${EPYTHON}/ipython \
/usr/bin/ipython${EPYTHON#python}
}
python_install_all() {
use doc && local HTML_DOCS=( docs/build/html/. )
use examples && local EXAMPLES=( examples/. )
distutils-r1_python_install_all
}
pkg_postinst() {
optfeature "sympyprinting" dev-python/sympy
optfeature "cythonmagic" dev-python/cython
if use nbconvert; then
if ! has_version app-text/pandoc ; then
einfo "Node.js will be used to convert notebooks to other formats"
einfo "like HTML. Support for that is still experimental. If you"
einfo "encounter any problems, please use app-text/pandoc instead."
fi
fi
}
1.1 dev-python/ipython/ipython-2.2.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-2.2.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-2.2.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: ipython-2.2.0-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-2.2.0-r1.ebuild,v 1.1 2015/06/22 09:45:52 jlec Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{3,4} )
PYTHON_REQ_USE='readline,sqlite'
inherit distutils-r1 virtualx
DESCRIPTION="Advanced interactive shell for Python"
HOMEPAGE="http://ipython.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc examples matplotlib mongodb notebook nbconvert octave qt4 +smp test wxwidgets"
PY2_USEDEP=$(python_gen_usedep python2_7)
CDEPEND="
dev-python/decorator[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pyparsing[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/simplegeneric[${PYTHON_USEDEP}]
matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
octave? ( dev-python/oct2py[${PYTHON_USEDEP}] )
smp? ( >=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}] )
wxwidgets? ( $(python_gen_cond_dep 'dev-python/wxpython:*[${PYTHON_USEDEP}]' python2_7) )"
RDEPEND="${CDEPEND}
notebook? (
>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
>=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
dev-libs/mathjax
)
nbconvert? (
>=app-text/pandoc-1.12.1
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
)
qt4? (
|| (
dev-python/PyQt4[${PYTHON_USEDEP}]
dev-python/pyside[${PYTHON_USEDEP}]
)
dev-python/pygments[${PYTHON_USEDEP}]
>=dev-python/pyzmq-2.1.11[${PYTHON_USEDEP}] )"
DEPEND="${CDEPEND}
test? (
dev-python/nose[${PYTHON_USEDEP}]
dev-python/mock[${PY2_USEDEP}]
)
doc? (
dev-python/cython[${PYTHON_USEDEP}]
$(python_gen_cond_dep 'dev-python/fabric[${PYTHON_USEDEP}]' python2_7)
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}]
dev-python/numpydoc[${PYTHON_USEDEP}]
dev-python/pymongo[${PYTHON_USEDEP}]
dev-python/rpy[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
>=www-servers/tornado-3.1[${PYTHON_USEDEP}]
)"
PATCHES=(
"${FILESDIR}"/2.1.0-substitute-files.patch
"${FILESDIR}"/2.1.0-disable-tests.patch
"${FILESDIR}"/${P}-login-backport.patch
)
DISTUTILS_IN_SOURCE_BUILD=1
python_prepare_all() {
# Remove out of date insource files
rm IPython/extensions/rmagic.py || die
rm IPython/extensions/octavemagic.py || die
# Prevent un-needed download during build
if use doc; then
sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
fi
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C docs html
}
src_test() {
# virtualx has trouble with parallel runs.
local DISTUTILS_NO_PARALLEL_BUILD=1
distutils-r1_src_test
}
python_test() {
distutils_install_for_testing
local fail
run_tests() {
pushd ${TEST_DIR} > /dev/null
"${PYTHON}" -m IPython.testing.iptestcontroller --all || fail=1
popd > /dev/null
}
VIRTUALX_COMMAND=run_tests virtualmake
[[ ${fail} ]] && die "Tests fail with ${EPYTHON}"
}
python_install() {
distutils-r1_python_install
use notebook && dosym /usr/share/mathjax $(python_get_sitedir)/IPython/html/static/mathjax
# Create ipythonX.Y symlinks.
# TODO:
# 1. do we want them for pypy? No. pypy has no numpy
# 2. handle it in the eclass instead (use _python_ln_rel).
# With pypy not an option the dosym becomes unconditional
dosym ../lib/python-exec/${EPYTHON}/ipython \
/usr/bin/ipython${EPYTHON#python}
}
python_install_all() {
use doc && local HTML_DOCS=( docs/build/html/. )
use examples && local EXAMPLES=( examples/. )
distutils-r1_python_install_all
}
pkg_postinst() {
elog "To enable sympyprinting, it's required to emerge sympy"
elog "To enable cythonmagic, it's required to emerge cython"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-22 9:46 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-22 9:45 [gentoo-commits] gentoo-x86 commit in dev-python/ipython: ipython-3.2.0.ebuild ipython-2.2.0-r1.ebuild ChangeLog ipython-2.4.1.ebuild ipython-3.0.0.ebuild ipython-3.1.0.ebuild Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox