* [gentoo-commits] gentoo-x86 commit in dev-util/coccinelle: ChangeLog coccinelle-1.0.1.ebuild
@ 2015-06-22 8:02 Alexis Ballier (aballier)
0 siblings, 0 replies; only message in thread
From: Alexis Ballier (aballier) @ 2015-06-22 8:02 UTC (permalink / raw
To: gentoo-commits
aballier 15/06/22 08:02:35
Modified: ChangeLog
Added: coccinelle-1.0.1.ebuild
Log:
version bump
Signed-off-by: Alexis Ballier <aballier@gentoo.org>
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 160F534A)
Revision Changes Path
1.40 dev-util/coccinelle/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccinelle/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccinelle/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccinelle/ChangeLog?r1=1.39&r2=1.40
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog 16 May 2015 10:12:56 -0000 1.39
+++ ChangeLog 22 Jun 2015 08:02:35 -0000 1.40
@@ -1,6 +1,11 @@
# ChangeLog for dev-util/coccinelle
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.39 2015/05/16 10:12:56 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.40 2015/06/22 08:02:35 aballier Exp $
+
+*coccinelle-1.0.1 (22 Jun 2015)
+
+ 22 Jun 2015; Alexis Ballier <aballier@gentoo.org> +coccinelle-1.0.1.ebuild:
+ version bump
*coccinelle-1.0.0 (16 May 2015)
1.1 dev-util/coccinelle/coccinelle-1.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccinelle/coccinelle-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccinelle/coccinelle-1.0.1.ebuild?rev=1.1&content-type=text/plain
Index: coccinelle-1.0.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/coccinelle-1.0.1.ebuild,v 1.1 2015/06/22 08:02:35 aballier Exp $
EAPI="5"
PYTHON_COMPAT=( python2_7 )
inherit multilib eutils python-single-r1 bash-completion-r1 elisp-common autotools
MY_P="${P/_/-}"
DESCRIPTION="Program matching and transformation engine"
HOMEPAGE="http://coccinelle.lip6.fr/"
SRC_URI="http://coccinelle.lip6.fr/distrib/${MY_P}.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc emacs ocaml +ocamlopt pcre python test vim-syntax"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
# ocaml enables ocaml scripting (uses findlib)
CDEPEND=">=dev-lang/ocaml-3.12:=[ocamlopt?]
dev-ml/sexplib:=[ocamlopt?]
dev-ml/menhir:=[ocamlopt?]
|| ( dev-ml/camlp4:=[ocamlopt?] <dev-lang/ocaml-4.02.0 )
dev-ml/parmap:=[ocamlopt?]
emacs? ( virtual/emacs )
ocaml? ( dev-ml/findlib:= )
pcre? ( dev-ml/pcre-ocaml:=[ocamlopt?] )
python? ( ${PYTHON_DEPS} )"
RDEPEND="${CDEPEND}
vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"
# dev-texlive/texlive-fontsextra contains 'ifsym.sty'
DEPEND="${CDEPEND}
virtual/pkgconfig
doc? (
virtual/latex-base
dev-texlive/texlive-latexextra
dev-texlive/texlive-fontsextra
)"
REQUIRED_USE="test? ( ocaml python )"
DOCS=( authors.txt bugs.txt changes.txt credits.txt readme.txt )
S=${WORKDIR}/${MY_P}
SITEFILE=50coccinelle-gentoo.el
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
if use python ; then
# fix python install location
sed -e "s:\$(SHAREDIR)/python:$(python_get_sitedir):" \
-e "s:PYTHON_TARGET:PYTHON_INSTALL_TARGET:" \
-i Makefile || die
fi
sed -i "s:^SHAREDIR=.*:SHAREDIR=/usr/$(get_libdir)/ocaml/${PN}/:" scripts/spatch.sh.in || die
# This is regenerated by menhir, bundled version does not build with latest
# one...
rm -f parsing_cocci/parser_cocci_menhir.ml
epatch "${FILESDIR}"/${PN}-1.0.0_rc16-findtool.patch
eautoreconf
}
src_configure() {
econf \
$(use_enable python) \
$(use_enable ocaml) \
$(use_enable pcre) \
$(use_enable pcre pcre-syntax)
sed -e "s:^LIBDIR=.*:LIBDIR=/usr/$(get_libdir)/ocaml/stublibs/:" \
-e "s:^SHAREDIR=.*:SHAREDIR=/usr/$(get_libdir)/ocaml/${PN}/:" \
-i Makefile.config || die
}
src_compile() {
emake depend
emake
use ocamlopt && emake opt
if use doc ; then
VARTEXFONTS="${T}"/fonts emake docs
fi
if use emacs ; then
elisp-compile editors/emacs/cocci.el || die
fi
}
src_test() {
source env.sh # needed for built in-place python plugin
./spatch standard.h -parse_c -dir tests/ || die
yes | ./spatch -iso_file standard.iso -macro_file_builtins standard.h -testall || die
if use ocamlopt ; then
./spatch.opt -iso_file standard.iso -macro_file_builtins standard.h -testall || die
fi
}
src_install() {
default
use doc && dodoc docs/manual/*.pdf
newbashcomp scripts/spatch.bash_completion spatch
if use emacs ; then
elisp-install ${PN} editors/emacs/*
elisp-site-file-install "${FILESDIR}"/${SITEFILE}
fi
if use vim-syntax ; then
newdoc editors/vim/README README-vim
rm editors/vim/README || die
insinto /usr/share/vim/vimfiles
doins -r editors/vim/*
fi
use python && python_optimize
export STRIP_MASK='*/coccinelle/spatch'
}
pkg_postinst() {
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-22 8:02 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-22 8:02 [gentoo-commits] gentoo-x86 commit in dev-util/coccinelle: ChangeLog coccinelle-1.0.1.ebuild Alexis Ballier (aballier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox