* [gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon-control-center: ChangeLog cinnamon-control-center-2.6.0.ebuild
@ 2015-06-14 1:57 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; only message in thread
From: Alexandre Rostovtsev (tetromino) @ 2015-06-14 1:57 UTC (permalink / raw
To: gentoo-commits
tetromino 15/06/14 01:57:50
Modified: ChangeLog
Added: cinnamon-control-center-2.6.0.ebuild
Log:
Version bump for Cinnamon 2.6
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x18E5B6F2D8D5EC8D)
Revision Changes Path
1.20 gnome-extra/cinnamon-control-center/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog?r1=1.19&r2=1.20
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog 12 May 2015 18:44:43 -0000 1.19
+++ ChangeLog 14 Jun 2015 01:57:50 -0000 1.20
@@ -1,6 +1,13 @@
# ChangeLog for gnome-extra/cinnamon-control-center
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog,v 1.19 2015/05/12 18:44:43 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-control-center/ChangeLog,v 1.20 2015/06/14 01:57:50 tetromino Exp $
+
+*cinnamon-control-center-2.6.0 (13 Jun 2015)
+
+ 13 Jun 2015; Alexandre Rostovtsev <tetromino@gentoo.org>
+ +cinnamon-control-center-2.6.0.ebuild,
+ +files/cinnamon-control-center-2.6.0-optional.patch:
+ Version bump for Cinnamon 2.6
12 May 2015; Pacho Ramos <pacho@gentoo.org>
cinnamon-control-center-2.4.2-r2.ebuild:
1.1 gnome-extra/cinnamon-control-center/cinnamon-control-center-2.6.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-control-center/cinnamon-control-center-2.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cinnamon-control-center/cinnamon-control-center-2.6.0.ebuild?rev=1.1&content-type=text/plain
Index: cinnamon-control-center-2.6.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon-control-center/cinnamon-control-center-2.6.0.ebuild,v 1.1 2015/06/14 01:57:50 tetromino Exp $
EAPI="5"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes" # gmodule is used, which uses dlopen
inherit autotools eutils gnome2
DESCRIPTION="Cinnamons's main interface to configure various aspects of the desktop"
HOMEPAGE="http://cinnamon.linuxmint.com/"
SRC_URI="https://github.com/linuxmint/cinnamon-control-center/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
IUSE="+colord +cups input_devices_wacom"
KEYWORDS="~amd64 ~x86"
# False positives caused by nested configure scripts
QA_CONFIGURE_OPTIONS=".*"
# FIXME: modemmanager is not optional
# networkmanager is not optional
COMMON_DEPEND="
>=dev-libs/glib-2.31:2
dev-libs/libxml2:2
>=gnome-base/libgnomekbd-2.91.91:0=
>=gnome-extra/cinnamon-desktop-1.0:0=
>=gnome-extra/cinnamon-menus-1.0:0=
>=gnome-extra/cinnamon-settings-daemon-1.0:0=
>=gnome-extra/nm-applet-0.9.8
media-libs/fontconfig
>=media-libs/libcanberra-0.13[gtk3]
>=media-sound/pulseaudio-1.1[glib]
>=net-misc/modemmanager-0.7
>=net-misc/networkmanager-0.9.8[modemmanager]
>=sys-auth/polkit-0.103
>=x11-libs/gdk-pixbuf-2.23.0:2
>=x11-libs/gtk+-3.4.1:3
>=x11-libs/libnotify-0.7.3:0=
x11-libs/libX11
x11-libs/libxklavier
colord? ( >=x11-misc/colord-0.1.14:0= )
cups? ( >=net-print/cups-1.4[dbus] )
input_devices_wacom? (
>=dev-libs/libwacom-0.7
>=x11-libs/gtk+-3.8:3
>=x11-libs/libXi-1.2 )
"
# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
# libgnomekbd needed only for gkbd-keyboard-display tool
RDEPEND="${COMMON_DEPEND}
|| ( ( app-admin/openrc-settingsd sys-auth/consolekit ) >=sys-apps/systemd-31 )
x11-themes/gnome-icon-theme
x11-themes/gnome-icon-theme-symbolic
colord? ( >=gnome-extra/gnome-color-manager-3 )
cups? (
|| ( >=app-admin/system-config-printer-gnome-1.3.5
app-admin/system-config-printer )
net-print/cups-pk-helper )
input_devices_wacom? ( gnome-extra/cinnamon-settings-daemon[input_devices_wacom] )
"
DEPEND="${COMMON_DEPEND}
app-text/iso-codes
x11-proto/xproto
x11-proto/xf86miscproto
x11-proto/kbproto
dev-libs/libxslt
>=dev-util/intltool-0.40.1
>=sys-devel/gettext-0.17
virtual/pkgconfig
gnome-base/gnome-common
"
# Needed for autoreconf
# gnome-base/gnome-common
src_prepare() {
# make some panels optional
epatch "${FILESDIR}"/${PN}-2.6.0-optional.patch
epatch_user
eautoreconf
gnome2_src_prepare
}
src_configure() {
# --enable-systemd doesn't do anything in $PN-2.2.5
gnome2_src_configure \
--disable-static \
--enable-documentation \
--without-libsocialweb \
$(use_enable colord color) \
$(use_enable cups) \
$(use_enable input_devices_wacom wacom)
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-14 1:57 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-14 1:57 [gentoo-commits] gentoo-x86 commit in gnome-extra/cinnamon-control-center: ChangeLog cinnamon-control-center-2.6.0.ebuild Alexandre Rostovtsev (tetromino)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox