[gentoo-commits] gentoo-x86 commit in dev-ruby/rcairo: rcairo-1.14.1-r1.ebuild rcairo-1.14.1.ebuild ChangeLog rcairo-1.14.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-ruby/rcairo: rcairo-1.14.1-r1.ebuild rcairo-1.14.1.ebuild ChangeLog rcairo-1.14.0.ebuild

[Manuel Rueger (mrueg)]

mrueg       15/06/13 10:02:24

  Modified:             rcairo-1.14.1.ebuild ChangeLog
  Added:                rcairo-1.14.1-r1.ebuild
  Removed:              rcairo-1.14.0.ebuild
  Log:
  Remove old. Create stable candidate.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.3                  dev-ruby/rcairo/rcairo-1.14.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild?r1=1.2&r2=1.3

Index: rcairo-1.14.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- rcairo-1.14.1.ebuild	25 Feb 2015 18:27:16 -0000	1.2
+++ rcairo-1.14.1.ebuild	13 Jun 2015 10:02:23 -0000	1.3
@@ -1,10 +1,10 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild,v 1.2 2015/02/25 18:27:16 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1.ebuild,v 1.3 2015/06/13 10:02:23 mrueg Exp $
 
 EAPI=5
 
-USE_RUBY="ruby19 ruby20 ruby21 ruby22"
+USE_RUBY="ruby19 ruby20"
 
 RUBY_FAKEGEM_NAME="cairo"
 
@@ -48,7 +48,7 @@
 }
 
 each_ruby_compile() {
-	emake V=1 -Cext/cairo || die "make failed"
+	emake V=1 -Cext/cairo
 
 	# again, try to make it more standard, to install it more easily.
 	cp ext/cairo/cairo$(get_modname) lib/ || die
@@ -65,12 +65,12 @@
 	each_fakegem_install
 
 	insinto $(ruby_get_hdrdir)
-	doins ext/cairo/rb_cairo.h || die "Cannot install header file."
+	doins ext/cairo/rb_cairo.h
 }
 
 all_ruby_install() {
 	all_fakegem_install
 
 	insinto /usr/share/doc/${PF}/samples
-	doins -r samples/* || die "Cannot install sample files."
+	doins -r samples/*
 }



1.94                 dev-ruby/rcairo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	25 Feb 2015 18:27:16 -0000	1.93
+++ ChangeLog	13 Jun 2015 10:02:23 -0000	1.94
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.93 2015/02/25 18:27:16 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.94 2015/06/13 10:02:23 mrueg Exp $
+
+*rcairo-1.14.1-r1 (13 Jun 2015)
+
+  13 Jun 2015; Manuel Rüger <mrueg@gentoo.org> +rcairo-1.14.1-r1.ebuild,
+  -rcairo-1.14.0.ebuild, rcairo-1.14.1.ebuild:
+  Remove old. Create stable candidate.
 
   25 Feb 2015; Hans de Graaff <graaff@gentoo.org> rcairo-1.14.1.ebuild:
   Add ruby22.



1.1                  dev-ruby/rcairo/rcairo-1.14.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: rcairo-1.14.1-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.14.1-r1.ebuild,v 1.1 2015/06/13 10:02:23 mrueg Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21 ruby22"

RUBY_FAKEGEM_NAME="cairo"

# Documentation depends on files that are not distributed.
RUBY_FAKEGEM_TASK_DOC=""

RUBY_FAKEGEM_TASK_TEST=""

RUBY_FAKEGEM_DOCDIR="doc"

RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"

inherit multilib ruby-fakegem

DESCRIPTION="Ruby bindings for cairo"
HOMEPAGE="http://cairographics.org/rcairo/"

IUSE=""

SLOT="0"
LICENSE="|| ( Ruby GPL-2 )"
KEYWORDS="~amd64 ~ppc ~x86"

RDEPEND="${RDEPEND}
	>=x11-libs/cairo-1.2.0[svg]"
DEPEND="${DEPEND}
	>=x11-libs/cairo-1.2.0[svg]"

ruby_add_bdepend "
	dev-ruby/pkg-config
	dev-ruby/ruby-glib2
	test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"

all_ruby_prepare() {
	# Avoid development dependency.
	sed -i -e '/notify/ s:^:#:' test/cairo-test-utils.rb || die
}

each_ruby_configure() {
	${RUBY} -Cext/cairo extconf.rb || die "extconf failed"
}

each_ruby_compile() {
	emake V=1 -Cext/cairo

	# again, try to make it more standard, to install it more easily.
	cp ext/cairo/cairo$(get_modname) lib/ || die
}

each_ruby_test() {
	# don't rely on the Rakefile because it's a mess to load with
	# their hierarchy, do it manually.
	${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
		-e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
}

each_ruby_install() {
	each_fakegem_install

	insinto $(ruby_get_hdrdir)
	doins ext/cairo/rb_cairo.h
}

all_ruby_install() {
	all_fakegem_install

	insinto /usr/share/doc/${PF}/samples
	doins -r samples/*
}