* [gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-boxes: gnome-boxes-3.16.2.ebuild ChangeLog gnome-boxes-3.14.2.ebuild gnome-boxes-3.12.3.ebuild
@ 2015-06-09 23:34 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2015-06-09 23:34 UTC (permalink / raw
To: gentoo-commits
eva 15/06/09 23:34:39
Modified: ChangeLog
Added: gnome-boxes-3.16.2.ebuild
Removed: gnome-boxes-3.14.2.ebuild gnome-boxes-3.12.3.ebuild
Log:
Version bump for Gnome 3.16. Clean up old revisions.
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)
Revision Changes Path
1.14 gnome-extra/gnome-boxes/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog?r1=1.13&r2=1.14
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog 14 Mar 2015 18:37:23 -0000 1.13
+++ ChangeLog 9 Jun 2015 23:34:39 -0000 1.14
@@ -1,6 +1,13 @@
# ChangeLog for gnome-extra/gnome-boxes
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog,v 1.13 2015/03/14 18:37:23 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-boxes/ChangeLog,v 1.14 2015/06/09 23:34:39 eva Exp $
+
+*gnome-boxes-3.16.2 (09 Jun 2015)
+
+ 09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org>
+ -gnome-boxes-3.12.3.ebuild, -gnome-boxes-3.14.2.ebuild,
+ +gnome-boxes-3.16.2.ebuild:
+ Version bump for Gnome 3.16. Clean up old revisions.
14 Mar 2015; Pacho Ramos <pacho@gentoo.org> gnome-boxes-3.14.3.1.ebuild:
amd64 stable, bug 534012
1.1 gnome-extra/gnome-boxes/gnome-boxes-3.16.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-boxes/gnome-boxes-3.16.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-boxes/gnome-boxes-3.16.2.ebuild?rev=1.1&content-type=text/plain
Index: gnome-boxes-3.16.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-boxes/gnome-boxes-3.16.2.ebuild,v 1.1 2015/06/09 23:34:39 eva Exp $
EAPI="5"
GCONF_DEBUG="no"
VALA_USE_DEPEND="vapigen"
VALA_MIN_API_VERSION="0.26"
inherit linux-info gnome2 readme.gentoo vala
DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
LICENSE="LGPL-2"
SLOT="0"
# We force 'bindist' due to licenses from gnome-boxes-nonfree
IUSE="smartcard usbredir" #bindist
KEYWORDS="~amd64" # qemu-kvm[spice] is 64bit-only
# NOTE: sys-fs/* stuff is called via exec()
# FIXME: ovirt is not available in tree
# FIXME: use vala.eclass but only because of libgd not being able
# to use its pre-generated files so do not copy all the
# vala deps like live ebuild has.
RDEPEND="
>=app-arch/libarchive-3:=
>=dev-libs/glib-2.38:2
>=dev-libs/gobject-introspection-0.9.6
>=dev-libs/libxml2-2.7.8:2
>=sys-libs/libosinfo-0.2.11
>=app-emulation/qemu-1.3.1[spice,smartcard?,usbredir?]
>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
>=app-emulation/libvirt-glib-0.2
>=x11-libs/gtk+-3.13.2:3
>=net-libs/gtk-vnc-0.4.4[gtk3]
>=net-misc/spice-gtk-0.27[gtk3,smartcard?,usbredir?]
virtual/libusb:1
>=app-misc/tracker-0.16:0=[iso]
>=sys-apps/util-linux-2.20
>=net-libs/libsoup-2.38:2.4
sys-fs/fuse
sys-fs/fuseiso
sys-fs/mtools
virtual/libgudev:=
"
# !bindist? ( gnome-extra/gnome-boxes-nonfree )
DEPEND="${RDEPEND}
$(vala_depend)
app-text/yelp-tools
dev-util/desktop-file-utils
>=dev-util/intltool-0.40
>=sys-devel/gettext-0.17
virtual/pkgconfig
"
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="Before running gnome-boxes, you will need to load the KVM modules.
If you have an Intel Processor, run:
# modprobe kvm-intel
If you have an AMD Processor, run:
# modprobe kvm-amd"
pkg_pretend() {
linux-info_get_any_version
if linux_config_exists; then
if ! { linux_chkconfig_present KVM_AMD || \
linux_chkconfig_present KVM_INTEL; }; then
ewarn "You need KVM support in your kernel to use GNOME Boxes!"
fi
fi
}
src_prepare() {
# Do not change CFLAGS, wondering about VALA ones but appears to be
# needed as noted in configure comments below
sed 's/CFLAGS="$CFLAGS -O0 -ggdb3"//' -i configure{.ac,} || die
vala_src_prepare
gnome2_src_prepare
}
src_configure() {
# debug needed for splitdebug proper behavior (cardoe), bug #????
gnome2_src_configure \
--enable-debug \
--disable-strict-cc \
$(use_enable usbredir) \
$(use_enable smartcard) \
--enable-ovirt=no
}
src_install() {
gnome2_src_install
readme.gentoo_create_doc
}
pkg_postinst() {
gnome2_pkg_postinst
readme.gentoo_print_elog
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-09 23:34 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-09 23:34 [gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-boxes: gnome-boxes-3.16.2.ebuild ChangeLog gnome-boxes-3.14.2.ebuild gnome-boxes-3.12.3.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox