From: "Gilles Dartiguelongue (eva)" <eva@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in gnome-base/gnome-settings-daemon: ChangeLog gnome-settings-daemon-3.16.2-r1.ebuild gnome-settings-daemon-3.14.3.ebuild
Date: Tue, 9 Jun 2015 14:21:45 +0000 (UTC) [thread overview]
Message-ID: <20150609142145.879BCA28@oystercatcher.gentoo.org> (raw)
eva 15/06/09 14:21:45
Modified: ChangeLog
Added: gnome-settings-daemon-3.16.2-r1.ebuild
Removed: gnome-settings-daemon-3.14.3.ebuild
Log:
Version bump for Gnome 3.16. Clean up old revision.
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)
Revision Changes Path
1.157 gnome-base/gnome-settings-daemon/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog?rev=1.157&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog?rev=1.157&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog?r1=1.156&r2=1.157
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog,v
retrieving revision 1.156
retrieving revision 1.157
diff -u -r1.156 -r1.157
--- ChangeLog 1 May 2015 22:00:01 -0000 1.156
+++ ChangeLog 9 Jun 2015 14:21:45 -0000 1.157
@@ -1,6 +1,15 @@
# ChangeLog for gnome-base/gnome-settings-daemon
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog,v 1.156 2015/05/01 22:00:01 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog,v 1.157 2015/06/09 14:21:45 eva Exp $
+
+*gnome-settings-daemon-3.16.2-r1 (09 Jun 2015)
+
+ 09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org>
+ -gnome-settings-daemon-3.14.3.ebuild,
+ +gnome-settings-daemon-3.16.2-r1.ebuild,
+ +files/gnome-settings-daemon-3.16.0-optional.patch,
+ +files/gnome-settings-daemon-3.16.2-settings_set_display.patch:
+ Version bump for Gnome 3.16. Clean up old revision.
*gnome-settings-daemon-3.14.4 (01 May 2015)
1.1 gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.16.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.16.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.16.2-r1.ebuild?rev=1.1&content-type=text/plain
Index: gnome-settings-daemon-3.16.2-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.16.2-r1.ebuild,v 1.1 2015/06/09 14:21:45 eva Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
inherit autotools eutils gnome2 python-r1 systemd udev virtualx
DESCRIPTION="Gnome Settings Daemon"
HOMEPAGE="https://git.gnome.org/browse/gnome-settings-daemon"
LICENSE="GPL-2+"
SLOT="0"
IUSE="+colord +cups debug input_devices_wacom -openrc-force networkmanager policykit +short-touchpad-timeout smartcard test +udev wayland"
REQUIRED_USE="
input_devices_wacom? ( udev )
smartcard? ( udev )
test? ( ${PYTHON_REQUIRED_USE} )
"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
COMMON_DEPEND="
>=dev-libs/glib-2.37.7:2[dbus]
>=x11-libs/gtk+-3.15.3:3
>=gnome-base/gnome-desktop-3.11.1:3=
>=gnome-base/gsettings-desktop-schemas-3.15.4
>=gnome-base/librsvg-2.36.2
media-fonts/cantarell
media-libs/fontconfig
>=media-libs/lcms-2.2:2
media-libs/libcanberra[gtk3]
>=media-sound/pulseaudio-2
>=sys-power/upower-0.99:=
x11-libs/cairo
x11-libs/gdk-pixbuf:2
>=x11-libs/libnotify-0.7.3:=
x11-libs/libX11
x11-libs/libxkbfile
x11-libs/libXi
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXtst
x11-libs/libXxf86misc
x11-misc/xkeyboard-config
>=app-misc/geoclue-2.1.2:2.0
>=dev-libs/libgweather-3.9.5:2
>=sci-geosciences/geocode-glib-3.10
>=sys-auth/polkit-0.103
colord? ( >=x11-misc/colord-1.0.2:= )
cups? ( >=net-print/cups-1.4[dbus] )
input_devices_wacom? (
>=dev-libs/libwacom-0.7
>=x11-libs/pango-1.20
x11-drivers/xf86-input-wacom
virtual/libgudev:= )
networkmanager? ( >=net-misc/networkmanager-0.9.9.1 )
smartcard? ( >=dev-libs/nss-3.11.2 )
udev? ( virtual/libgudev:= )
wayland? ( dev-libs/wayland )
"
# Themes needed by g-s-d, gnome-shell, gtk+:3 apps to work properly
# <gnome-color-manager-3.1.1 has file collisions with g-s-d-3.1.x
# <gnome-power-manager-3.1.3 has file collisions with g-s-d-3.1.x
# systemd needed for power and session management, bug #464944
RDEPEND="${COMMON_DEPEND}
gnome-base/dconf
!openrc-force? ( sys-apps/systemd )
>=x11-themes/gnome-themes-standard-2.91
>=x11-themes/gnome-icon-theme-2.91
>=x11-themes/gnome-icon-theme-symbolic-2.91
!<gnome-base/gnome-control-center-2.22
!<gnome-extra/gnome-color-manager-3.1.1
!<gnome-extra/gnome-power-manager-3.1.3
"
# xproto-7.0.15 needed for power plugin
DEPEND="${COMMON_DEPEND}
cups? ( sys-apps/sed )
test? (
${PYTHON_DEPS}
dev-python/pygobject[${PYTHON_USEDEP}] )
dev-libs/libxml2:2
sys-devel/gettext
>=dev-util/intltool-0.40
virtual/pkgconfig
x11-proto/inputproto
x11-proto/xf86miscproto
>=x11-proto/xproto-7.0.15
"
src_prepare() {
# https://bugzilla.gnome.org/show_bug.cgi?id=621836
# Apparently this change severely affects touchpad usability for some
# people, so revert it if USE=short-touchpad-timeout.
# Revisit if/when upstream adds a setting for customizing the timeout.
use short-touchpad-timeout &&
epatch "${FILESDIR}"/${PN}-3.7.90-short-touchpad-timeout.patch
# Make colord and wacom optional; requires eautoreconf
epatch "${FILESDIR}"/${PN}-3.16.0-optional.patch
# Fix segfault, https://bugzilla.gnome.org/show_bug.cgi?id=749844
epatch "${FILESDIR}"/${PN}-3.16.2-settings_set_display.patch
epatch_user
eautoreconf
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
--disable-static \
--enable-man \
$(use_enable colord color) \
$(use_enable cups) \
$(use_enable debug) \
$(use_enable debug more-warnings) \
$(use_enable networkmanager network-manager) \
$(use_enable smartcard smartcard-support) \
$(use_enable udev gudev) \
$(use_enable input_devices_wacom wacom) \
$(use_enable wayland)
}
src_test() {
python_export_best
Xemake check
}
src_install() {
gnome2_src_install udevrulesdir="$(get_udevdir)"/rules.d #509484
}
pkg_postinst() {
gnome2_pkg_postinst
if ! systemd_is_booted; then
ewarn "${PN} needs Systemd to be *running* for working"
ewarn "properly. Please follow the this guide to migrate:"
ewarn "http://wiki.gentoo.org/wiki/Systemd"
fi
if use openrc-force; then
ewarn "You are enabling 'openrc-force' USE flag to skip systemd requirement,"
ewarn "this can lead to unexpected problems and is not supported neither by"
ewarn "upstream neither by Gnome Gentoo maintainers. If you suffer any problem,"
ewarn "you will need to disable this USE flag system wide and retest before"
ewarn "opening any bug report."
fi
}
reply other threads:[~2015-06-09 14:21 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20150609142145.879BCA28@oystercatcher.gentoo.org \
--to=eva@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox