[gentoo-commits] gentoo-x86 commit in net-libs/libtirpc: libtirpc-0.3.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-libs/libtirpc: libtirpc-0.3.1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/06/01 14:20:34

  Modified:             ChangeLog
  Added:                libtirpc-0.3.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.53                 net-libs/libtirpc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	30 May 2015 00:11:19 -0000	1.52
+++ ChangeLog	1 Jun 2015 14:20:34 -0000	1.53
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libtirpc
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v 1.52 2015/05/30 00:11:19 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/ChangeLog,v 1.53 2015/06/01 14:20:34 vapier Exp $
+
+*libtirpc-0.3.1 (01 Jun 2015)
+
+  01 Jun 2015; Mike Frysinger <vapier@gentoo.org> +libtirpc-0.3.1.ebuild:
+  Version bump.
 
   30 May 2015; Manuel Rüger <mrueg@gentoo.org> -libtirpc-0.2.1-r1.ebuild,
   -libtirpc-0.2.2-r1.ebuild, -libtirpc-0.2.3.ebuild, -libtirpc-0.2.4.ebuild:



1.1                  net-libs/libtirpc/libtirpc-0.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/libtirpc-0.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libtirpc/libtirpc-0.3.1.ebuild?rev=1.1&content-type=text/plain

Index: libtirpc-0.3.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/libtirpc-0.3.1.ebuild,v 1.1 2015/06/01 14:20:34 vapier Exp $

EAPI="4"

inherit multilib-minimal toolchain-funcs

DESCRIPTION="Transport Independent RPC library (SunRPC replacement)"
HOMEPAGE="http://libtirpc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}-glibc-nfs.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="ipv6 kerberos static-libs"

RDEPEND="kerberos? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
RDEPEND="${RDEPEND}
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140508-r7
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"

src_unpack() {
	unpack ${A}
	cp -r tirpc "${S}"/ || die
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	econf \
		$(use_enable ipv6) \
		$(use_enable kerberos gssapi) \
		$(use_enable static-libs static)
}

multilib_src_install() {
	default

	# libtirpc replaces rpc support in glibc, so we need it in /
	multilib_is_native_abi && gen_usr_ldscript -a tirpc
}

multilib_src_install_all() {
	einstalldocs

	insinto /etc
	doins doc/netconfig

	insinto /usr/include/tirpc
	doins -r "${WORKDIR}"/tirpc/*

	# makes sure that the linking order for nfs-utils is proper, as
	# libtool would inject a libgssglue dependency in the list.
	use static-libs || prune_libtool_files
}