[gentoo-commits] gentoo-x86 commit in kde-plasma/breeze: breeze-5.3.1.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-plasma/breeze: breeze-5.3.1.ebuild metadata.xml ChangeLog

[Johannes Huber (johu)]

johu        15/05/31 22:06:17

  Added:                breeze-5.3.1.ebuild metadata.xml ChangeLog
  Log:
  Initial commit for KDE Plasma 5. Imported from kde overlay. Ebuilds written by several people. Thank you all who worked on it in the overlay.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.1                  kde-plasma/breeze/breeze-5.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/breeze-5.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/breeze-5.3.1.ebuild?rev=1.1&content-type=text/plain

Index: breeze-5.3.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-plasma/breeze/breeze-5.3.1.ebuild,v 1.1 2015/05/31 22:06:17 johu Exp $

EAPI=5

inherit kde5 multibuild

DESCRIPTION="Breeze visual style for the Plasma desktop"
HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze"
KEYWORDS="~amd64"
IUSE="kde4"

DEPEND="
	$(add_frameworks_dep frameworkintegration)
	$(add_frameworks_dep kcmutils)
	$(add_frameworks_dep kconfig)
	$(add_frameworks_dep kconfigwidgets)
	$(add_frameworks_dep kcoreaddons)
	$(add_frameworks_dep kguiaddons)
	$(add_frameworks_dep ki18n)
	$(add_frameworks_dep kwindowsystem)
	$(add_plasma_dep kdecoration)
	dev-qt/qtdbus:5
	dev-qt/qtgui:5
	dev-qt/qtwidgets:5
	dev-qt/qtx11extras:5
	x11-libs/libxcb
	kde4? (
		kde-base/kdelibs:4
		x11-libs/libX11
	)
"
RDEPEND="${DEPEND}
	$(add_plasma_dep kde-cli-tools)
	!kde-base/breeze
"

pkg_setup() {
	kde5_pkg_setup
	MULTIBUILD_VARIANTS=( kf5 $(usev kde4) )
}

src_configure() {
	myconfigure() {
		local mycmakeargs=()

		if [[ ${MULTIBUILD_VARIANT} = kde4 ]] ; then
			mycmakeargs+=( -DUSE_KDE4=true )
		fi

		kde5_src_configure
	}

	multibuild_foreach_variant myconfigure
}

src_compile() {
	multibuild_foreach_variant kde5_src_compile
}

src_install() {
	multibuild_foreach_variant kde5_src_install
}



1.1                  kde-plasma/breeze/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>kde</herd>
	<use>
		<flag name="kde4">Build the Breeze style for KDE 4</flag>
	</use>
</pkgmetadata>



1.1                  kde-plasma/breeze/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/breeze/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for kde-plasma/breeze
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/kde-plasma/breeze/ChangeLog,v 1.1 2015/05/31 22:06:17 johu Exp $

*breeze-5.3.1 (31 May 2015)

  31 May 2015; Johannes Huber <johu@gentoo.org> +breeze-5.3.1.ebuild,
  +metadata.xml:
  Initial commit for KDE Plasma 5. Imported from kde overlay. Ebuilds written by
  several people. Thank you all who worked on it in the overlay.