[gentoo-commits] gentoo-x86 commit in dev-java/jrobin: jrobin-1.6.0-r1.ebuild ChangeLog jrobin-1.6.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-java/jrobin: jrobin-1.6.0-r1.ebuild ChangeLog jrobin-1.6.0.ebuild

[James Le Cuirot (chewi)]

chewi       15/05/29 22:34:16

  Modified:             ChangeLog
  Added:                jrobin-1.6.0-r1.ebuild
  Removed:              jrobin-1.6.0.ebuild
  Log:
  Install rrdtool wrapper as jrobin-rrdtool to avoid conflicting with
  net-analyzer/rrdtool. Closes bug #550522.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 9C6D7DE4)

Revision  Changes    Path
1.6                  dev-java/jrobin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/jrobin/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/jrobin/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/jrobin/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/jrobin/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	25 May 2015 20:58:14 -0000	1.5
+++ ChangeLog	29 May 2015 22:34:15 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/jrobin
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/jrobin/ChangeLog,v 1.5 2015/05/25 20:58:14 chewi Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jrobin/ChangeLog,v 1.6 2015/05/29 22:34:15 chewi Exp $
+
+*jrobin-1.6.0-r1 (29 May 2015)
+
+  29 May 2015; James Le Cuirot <chewi@gentoo.org> +jrobin-1.6.0-r1.ebuild,
+  -jrobin-1.6.0.ebuild:
+  Install rrdtool wrapper as jrobin-rrdtool to avoid conflicting with net-
+  analyzer/rrdtool. Closes bug #550522.
 
 *jrobin-1.6.0 (25 May 2015)
 



1.1                  dev-java/jrobin/jrobin-1.6.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/jrobin/jrobin-1.6.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/jrobin/jrobin-1.6.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: jrobin-1.6.0-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jrobin/jrobin-1.6.0-r1.ebuild,v 1.1 2015/05/29 22:34:15 chewi Exp $

EAPI="5"

JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-pkg-simple

DESCRIPTION="JRobin is a 100% pure Java alternative to RRDTool"
HOMEPAGE="http://www.jrobin.org/"
SRC_URI="https://github.com/OpenNMS/${PN}/archive/${P}-1.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND=">=virtual/jre-1.6"
DEPEND=">=virtual/jdk-1.6
	test? (	dev-java/asm:4
		>=dev-java/cglib-3.1:3
		dev-java/easymock:3.2
		dev-java/junit:4
		dev-java/objenesis:0 )"

S="${WORKDIR}/${PN}-${P}-1/src"
JAVA_SRC_DIR="main/java"

java_prepare() {
	find "${WORKDIR}" -name "*.jar" -delete || die

	# The tests need the resources in this directory for some reason.
	mkdir -p test/java/target/classes || die
	cd test/java/target/classes || die
	ln -snf ../../../../main/resources/* . || die
}

src_compile() {
	java-pkg-simple_src_compile
	jar uf "${PN}.jar" -C main/resources . || die
}

src_install() {
	java-pkg-simple_src_install
	java-pkg_dolauncher "${PN}-rrdtool" --main org.jrobin.cmd.RrdCommander
}

src_test() {
	cd test/java || die

	local CP=".:${S}/${PN}.jar:$(java-pkg_getjars asm-4,cglib-3,easymock-3.2,junit-4,objenesis)"
	local TESTS=$(find * -name "*Test.java")
	TESTS="${TESTS//.java}"
	TESTS="${TESTS//\//.}"

	ejavac -cp "${CP}" -d . $(find * -name "*.java")
	ejunit4 -classpath "${CP}" ${TESTS}
}

pkg_postinst() {
	elog "The rrdtool executable has been installed as ${PN}-rrdtool to"
	elog "avoid conflicting with net-analyzer/rrdtool."
}