[gentoo-commits] gentoo-x86 commit in dev-python/setuptools: setuptools-17.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/setuptools: setuptools-17.0.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/05/29 10:24:37

  Modified:             ChangeLog
  Added:                setuptools-17.0.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

Revision  Changes    Path
1.280                dev-python/setuptools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/setuptools/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/setuptools/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/setuptools/ChangeLog?r1=1.279&r2=1.280

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/setuptools/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog	19 May 2015 18:06:52 -0000	1.279
+++ ChangeLog	29 May 2015 10:24:37 -0000	1.280
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/setuptools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/ChangeLog,v 1.279 2015/05/19 18:06:52 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/ChangeLog,v 1.280 2015/05/29 10:24:37 jlec Exp $
+
+*setuptools-17.0 (29 May 2015)
+
+  29 May 2015; Justin Lecher <jlec@gentoo.org> +setuptools-17.0.ebuild:
+  Version Bump
 
 *setuptools-16.0 (19 May 2015)
 



1.1                  dev-python/setuptools/setuptools-17.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/setuptools/setuptools-17.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/setuptools/setuptools-17.0.ebuild?rev=1.1&content-type=text/plain

Index: setuptools-17.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/setuptools-17.0.ebuild,v 1.1 2015/05/29 10:24:37 jlec Exp $

EAPI="5"

PYTHON_COMPAT=( python2_7 python3_{3,4} pypy pypy3 )

inherit distutils-r1

DESCRIPTION="a collection of extensions to Distutils"
HOMEPAGE="http://pypi.python.org/pypi/setuptools"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="PSF-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="test"

DEPEND="
	test? (
		dev-python/pytest[${PYTHON_USEDEP}]
		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
	)
"

# Force in-source build because build system modifies sources.
DISTUTILS_IN_SOURCE_BUILD=1

DOCS=( README.txt docs/{easy_install.txt,pkg_resources.txt,setuptools.txt} )

python_prepare_all() {
	# disable tests requiring a network connection
	rm setuptools/tests/test_packageindex.py || die

	# don't run integration tests
	rm setuptools/tests/test_integration.py || die

	distutils-r1_python_prepare_all
}

python_test() {
	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
	# It tries to sandbox the test in a tempdir
	HOME="${PWD}" py.test ${PN} || die "Tests failed under ${EPYTHON}"
}

python_install() {
	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
	distutils-r1_python_install
}