[gentoo-commits] gentoo-x86 commit in net-libs/libssh: ChangeLog libssh-0.7.0-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/libssh: ChangeLog libssh-0.7.0-r1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/05/27 07:46:35

  Modified:             ChangeLog
  Added:                libssh-0.7.0-r1.ebuild
  Log:
  Added upstream patch to reintroduce a deprecated function (bug #549894)
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.134                net-libs/libssh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libssh/ChangeLog?rev=1.134&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libssh/ChangeLog?rev=1.134&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libssh/ChangeLog?r1=1.133&r2=1.134

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v
retrieving revision 1.133
retrieving revision 1.134
diff -u -r1.133 -r1.134
--- ChangeLog	19 May 2015 16:06:44 -0000	1.133
+++ ChangeLog	27 May 2015 07:46:35 -0000	1.134
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libssh
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.133 2015/05/19 16:06:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.134 2015/05/27 07:46:35 polynomial-c Exp $
+
+*libssh-0.7.0-r1 (27 May 2015)
+
+  27 May 2015; Lars Wendler <polynomial-c@gentoo.org> +libssh-0.7.0-r1.ebuild:
+  Added upstream patch to reintroduce a deprecated function (bug #549894).
 
   19 May 2015; Jeroen Roovers <jer@gentoo.org> -libssh-0.6.4.ebuild:
   Old.



1.1                  net-libs/libssh/libssh-0.7.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libssh/libssh-0.7.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libssh/libssh-0.7.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: libssh-0.7.0-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.7.0-r1.ebuild,v 1.1 2015/05/27 07:46:35 polynomial-c Exp $

EAPI=5

MY_P=${PN}-${PV/_rc/rc}
inherit eutils cmake-multilib multilib

DESCRIPTION="Access a working SSH implementation by means of a library"
HOMEPAGE="http://www.libssh.org/"
SRC_URI="https://red.libssh.org/attachments/download/140/${MY_P}.tar.xz -> ${P}.tar.xz
	https://projects.archlinux.org/svntogit/packages.git/plain/trunk/ssh_forward_listen.patch?h=packages/libssh&id=e7628675b7b5dec45371b67745ce786ee5b78d8c -> ${PN}-0.7.0-ssh_forward_listen.patch"

LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
SLOT="0/4" # subslot = soname major version
IUSE="debug doc examples gcrypt gssapi pcap +sftp ssh1 server static-libs test zlib"
# Maintainer: check IUSE-defaults at DefineOptions.cmake

RDEPEND="
	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
	!gcrypt? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] )
	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
	gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	test? ( >=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}] )
"

DOCS=( AUTHORS README ChangeLog )

S=${WORKDIR}/${MY_P}

PATCHES=(
	"${FILESDIR}"/${PN}-0.5.0-tests.patch
	"${DISTDIR}"/${P}-ssh_forward_listen.patch
)

src_prepare() {
	# just install the examples do not compile them
	sed -i \
		-e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
		CMakeLists.txt || die

	cmake-utils_src_prepare
}

multilib_src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
		$(cmake-utils_use_with debug DEBUG_CRYPTO)
		$(cmake-utils_use_with gcrypt)
		$(cmake-utils_use_with gssapi)
		$(cmake-utils_use_with pcap)
		$(cmake-utils_use_with server)
		$(cmake-utils_use_with sftp)
		$(cmake-utils_use_with ssh1)
		$(cmake-utils_use_with static-libs STATIC_LIB)
		$(cmake-utils_use_with test STATIC_LIB)
		$(cmake-utils_use_with test TESTING)
		$(cmake-utils_use_with zlib)
	)

	cmake-utils_src_configure
}

multilib_src_compile() {
	cmake-utils_src_compile
	multilib_is_native_abi && use doc && cmake-utils_src_compile doc
}

multilib_src_install() {
	cmake-utils_src_install

	multilib_is_native_abi && use doc && dohtml -r doc/html/.

	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libssh{,_threads}.a
}

multilib_src_install_all() {
	einstalldocs

	if use examples; then
		docinto examples
		dodoc examples/*.{c,h,cpp}
	fi
}