public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in app-text/poppler: ChangeLog poppler-9999.ebuild poppler-0.33.0-r1.ebuild
@ 2015-05-24 18:45 Andreas Huettel (dilfridge)
  0 siblings, 0 replies; only message in thread
From: Andreas Huettel (dilfridge) @ 2015-05-24 18:45 UTC (permalink / raw
  To: gentoo-commits

dilfridge    15/05/24 18:45:23

  Modified:             ChangeLog poppler-9999.ebuild
  Added:                poppler-0.33.0-r1.ebuild
  Log:
  Use libopenjpeg:2 and workaround broken slotting
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0B08240A96F66571)

Revision  Changes    Path
1.459                app-text/poppler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.459&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.459&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?r1=1.458&r2=1.459

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v
retrieving revision 1.458
retrieving revision 1.459
diff -u -r1.458 -r1.459
--- ChangeLog	18 May 2015 11:31:55 -0000	1.458
+++ ChangeLog	24 May 2015 18:45:23 -0000	1.459
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/poppler
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.458 2015/05/18 11:31:55 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.459 2015/05/24 18:45:23 dilfridge Exp $
+
+*poppler-0.33.0-r1 (24 May 2015)
+
+  24 May 2015; Andreas K. Huettel <dilfridge@gentoo.org>
+  +poppler-0.33.0-r1.ebuild, poppler-9999.ebuild,
+  +files/poppler-0.33.0-openjpeg2.patch:
+  Use libopenjpeg:2 and workaround broken slotting
 
 *poppler-0.33.0 (18 May 2015)
 



1.7                  app-text/poppler/poppler-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-9999.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-9999.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-9999.ebuild?r1=1.6&r2=1.7

Index: poppler-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-9999.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- poppler-9999.ebuild	18 May 2015 11:31:55 -0000	1.6
+++ poppler-9999.ebuild	24 May 2015 18:45:23 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-9999.ebuild,v 1.6 2015/05/18 11:31:55 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-9999.ebuild,v 1.7 2015/05/24 18:45:23 dilfridge Exp $
 
 EAPI=5
 
@@ -36,7 +36,7 @@
 	)
 	curl? ( net-misc/curl )
 	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( media-libs/openjpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2 )
 	lcms? ( media-libs/lcms:2 )
 	png? ( media-libs/libpng:0= )
 	qt4? (
@@ -63,6 +63,7 @@
 	"${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch"
 	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
 	"${FILESDIR}/${PN}-0.28.1-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.33.0-openjpeg2.patch"
 )
 
 src_configure() {
@@ -86,7 +87,7 @@
 		$(cmake-utils_use_with tiff)
 	)
 	if use jpeg2k; then
-		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg1)
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg2)
 	else
 		mycmakeargs+=(-DENABLE_LIBOPENJPEG=)
 	fi



1.1                  app-text/poppler/poppler-0.33.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.33.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.33.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: poppler-0.33.0-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.33.0-r1.ebuild,v 1.1 2015/05/24 18:45:23 dilfridge Exp $

EAPI=5

inherit cmake-utils toolchain-funcs

if [[ "${PV}" == "9999" ]] ; then
	inherit git-r3
	EGIT_REPO_URI="git://git.freedesktop.org/git/${PN}/${PN}"
	SLOT="0/9999"
else
	SRC_URI="http://poppler.freedesktop.org/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
	SLOT="0/52"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
fi

DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
HOMEPAGE="http://poppler.freedesktop.org/"

LICENSE="GPL-2"
IUSE="cairo cjk curl cxx debug doc +introspection +jpeg jpeg2k +lcms png qt4 qt5 tiff +utils"

# No test data provided
RESTRICT="test"

COMMON_DEPEND="
	>=media-libs/fontconfig-2.6.0
	>=media-libs/freetype-2.3.9
	sys-libs/zlib
	cairo? (
		dev-libs/glib:2
		>=x11-libs/cairo-1.10.0
		introspection? ( >=dev-libs/gobject-introspection-1.32.1 )
	)
	curl? ( net-misc/curl )
	jpeg? ( virtual/jpeg:0 )
	jpeg2k? ( media-libs/openjpeg:2 )
	lcms? ( media-libs/lcms:2 )
	png? ( media-libs/libpng:0= )
	qt4? (
		dev-qt/qtcore:4
		dev-qt/qtgui:4
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtxml:5
	)
	tiff? ( media-libs/tiff:0 )
"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
	cjk? ( >=app-text/poppler-data-0.4.4 )
"

DOCS=(AUTHORS NEWS README README-XPDF TODO)

PATCHES=(
	"${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch"
	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
	"${FILESDIR}/${PN}-0.28.1-respect-cflags.patch"
	"${FILESDIR}/${PN}-0.33.0-openjpeg2.patch"
)

src_configure() {
	local mycmakeargs=(
		-DBUILD_GTK_TESTS=OFF
		-DBUILD_QT4_TESTS=OFF
		-DBUILD_QT5_TESTS=OFF
		-DBUILD_CPP_TESTS=OFF
		-DENABLE_SPLASH=ON
		-DENABLE_ZLIB=ON
		-DENABLE_XPDF_HEADERS=ON
		$(cmake-utils_use_enable curl LIBCURL)
		$(cmake-utils_use_enable cxx CPP)
		$(cmake-utils_use_enable utils)
		$(cmake-utils_use_with cairo)
		$(cmake-utils_use_with introspection GObjectIntrospection)
		$(cmake-utils_use_with jpeg)
		$(cmake-utils_use_with png)
		$(cmake-utils_use_with qt4)
		$(cmake-utils_use_find_package qt5 Qt5Core)
		$(cmake-utils_use_with tiff)
	)
	if use jpeg2k; then
		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg2)
	else
		mycmakeargs+=(-DENABLE_LIBOPENJPEG=)
	fi
	if use lcms; then
		mycmakeargs+=(-DENABLE_CMS=lcms2)
	else
		mycmakeargs+=(-DENABLE_CMS=)
	fi

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use cairo && use doc; then
		# For now install gtk-doc there
		insinto /usr/share/gtk-doc/html/poppler
		# nonfatal, because live version doesn't provide html documentation.
		nonfatal doins -r "${S}"/glib/reference/html/*
	fi
}





^ permalink raw reply	[flat|nested] only message in thread
only message in thread, other threads:[~2015-05-24 18:45 UTC | newest]

Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-05-24 18:45 [gentoo-commits] gentoo-x86 commit in app-text/poppler: ChangeLog poppler-9999.ebuild poppler-0.33.0-r1.ebuild Andreas Huettel (dilfridge)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox