[gentoo-commits] gentoo-x86 commit in www-servers/tornado: tornado-4.2.0_beta1.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in www-servers/tornado: tornado-4.2.0_beta1.ebuild metadata.xml ChangeLog

[Alex Brandt (alunduil)]

alunduil    15/05/17 17:21:01

  Modified:             metadata.xml ChangeLog
  Added:                tornado-4.2.0_beta1.ebuild
  Log:
  add version 4.2.0_beta1
  
  (Portage version: 2.2.19/cvs/Linux x86_64, signed Manifest commit with key 11A8217C!)

Revision  Changes    Path
1.2                  www-servers/tornado/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-servers/tornado/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	21 Oct 2009 13:26:57 -0000	1.1
+++ metadata.xml	17 May 2015 17:21:01 -0000	1.2
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <herd>python</herd>
+  <maintainer>
+	<email>alunduil@genoo.org></email>
+	<name>Alex Brandt</name>
+  </maintainer>
 </pkgmetadata>



1.72                 www-servers/tornado/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-servers/tornado/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	17 May 2015 17:15:49 -0000	1.71
+++ ChangeLog	17 May 2015 17:21:01 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for www-servers/tornado
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/ChangeLog,v 1.71 2015/05/17 17:15:49 alunduil Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/ChangeLog,v 1.72 2015/05/17 17:21:01 alunduil Exp $
+
+*tornado-4.2.0_beta1 (17 May 2015)
+
+  17 May 2015; Alex Brandt <alunduil@gentoo.org> +tornado-4.2.0_beta1.ebuild,
+  files/drop-intersphinx.patch, metadata.xml:
+  add version 4.2.0_beta1
 
   17 May 2015; Alex Brandt <alunduil@gentoo.org>
   +files/4.1.0-drop-intersphinx.patch, tornado-4.1.0-r1.ebuild,



1.1                  www-servers/tornado/tornado-4.2.0_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/tornado-4.2.0_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-servers/tornado/tornado-4.2.0_beta1.ebuild?rev=1.1&content-type=text/plain

Index: tornado-4.2.0_beta1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/tornado-4.2.0_beta1.ebuild,v 1.1 2015/05/17 17:21:01 alunduil Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 python3_3 python3_4 )

inherit distutils-r1 vcs-snapshot

MY_PV=${PV/.0_beta/b}

DESCRIPTION="Tornado is a Python web framework and asynchronous networking library, ... ."
HOMEPAGE="http://www.tornadoweb.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${PN}-${MY_PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples test"

CDEPEND="
	dev-python/certifi[${PYTHON_USEDEP}]
	>=dev-python/pycurl-7.18.2[${PYTHON_USEDEP}]
	$(python_gen_cond_dep 'dev-python/asyncio[${PYTHON_USEDEP}]' 'python3_3')
	$(python_gen_cond_dep 'dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]' 'python2_7')
	$(python_gen_cond_dep 'dev-python/futures[${PYTHON_USEDEP}]' 'python2_7 pypy')
	$(python_gen_cond_dep 'dev-python/singledispatch[${PYTHON_USEDEP}]' 'python2_7 python3_3')
	$(python_gen_cond_dep 'dev-python/twisted-names[${PYTHON_USEDEP}]' 'python2_7')
	$(python_gen_cond_dep 'dev-python/twisted-web[${PYTHON_USEDEP}]' 'python2_7')
"
# dev-python/twisted-* only supports python2_7 currently
DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? (
		dev-python/sphinx[${PYTHON_USEDEP}]
		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
	)
	test? (
		${CDEPEND}
		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
	)
"
RDEPEND="${CDEPEND}"

python_prepare_all() {
	local PATCHES=(
		"${FILESDIR}"/drop-intersphinx.patch
	)

	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs sphinx
}

python_test() {
	"${PYTHON}" -m tornado.test.runtests || die "tests failed under ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html/. )
	use examples && local EXAMPLES=( demos/. )

	distutils-r1_python_install_all
}